SL/Dev/Part.pm

   1 package SL::Dev::Part;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT_OK = qw(new_part new_service new_assembly new_assortment);
   6 our %EXPORT_TAGS = (ALL => \@EXPORT_OK);
   7
   8 use SL::DB::Part;
   9 use SL::DB::Unit;
  10 use SL::DB::Buchungsgruppe;
  11
  12 sub new_part {
  13   my (%params) = @_;
  14
  15   my $part = SL::DB::Part->new_part(
  16     description        => 'Test part',
  17     sellprice          => '10',
  18     lastcost           => '5',
  19     buchungsgruppen_id => _default_buchungsgruppe()->id,
  20     unit               => _default_unit()->name
  21   );
  22   $part->assign_attributes( %params );
  23   return $part;
  24 }
  25
  26 sub new_service {
  27   my (%params) = @_;
  28
  29   my $part = SL::DB::Part->new_service(
  30     description        => 'Test service',
  31     sellprice          => '10',
  32     lastcost           => '5',
  33     buchungsgruppen_id => _default_buchungsgruppe()->id,
  34     unit               => _default_unit()->name
  35   );
  36   $part->assign_attributes( %params );
  37   return $part;
  38 }
  39
  40 sub new_assembly {
  41   my (%params) = @_;
  42
  43   my $assnumber       = delete $params{assnumber};
  44   my $base_partnumber = delete $params{partnumber} || 'ap';
  45
  46   my $assembly_items = [];
  47
  48   if ( $params{assembly_items} ) {
  49     $assembly_items = delete $params{assembly_items};
  50   } else {
  51     for my $i ( 1 .. delete $params{number_of_parts} || 3) {
  52       my $part = new_part(partnumber  => "$base_partnumber $i",
  53                           description => "Testpart $i",
  54                          )->save;
  55       push( @{$assembly_items}, SL::DB::Assembly->new(parts_id => $part->id,
  56                                                       qty      => 1,
  57                                                       position => $i,
  58                                                      ));
  59     }
  60   }
  61
  62   my $assembly = SL::DB::Part->new_assembly(
  63     partnumber         => $assnumber,
  64     description        => 'Test Assembly',
  65     sellprice          => '10',
  66     lastcost           => '5',
  67     assemblies         => $assembly_items,
  68     buchungsgruppen_id => _default_buchungsgruppe()->id,
  69     unit               => _default_unit()->name
  70   );
  71   $assembly->assign_attributes( %params );
  72   return $assembly;
  73 }
  74
  75 sub new_assortment {
  76   my (%params) = @_;
  77
  78   my $assnumber       = delete $params{assnumber};
  79   my $base_partnumber = delete $params{partnumber} || 'ap';
  80
  81   my $assortment_items = [];
  82
  83   if ( $params{assortment_items} ) {
  84     $assortment_items = delete $params{assortment_items};
  85   } else {
  86     for my $i ( 1 .. delete $params{number_of_parts} || 3) {
  87       my $part = new_part(partnumber  => "$base_partnumber $i",
  88                           description => "Testpart $i",
  89                          )->save;
  90       push( @{$assortment_items}, SL::DB::AssortmentItem->new(parts_id => $part->id,
  91                                                               qty      => 1,
  92                                                               position => $i,
  93                                                               unit     => $part->unit,
  94                                                              ));
  95     }
  96   }
  97
  98   my $assortment = SL::DB::Part->new_assortment(
  99     partnumber         => $assnumber,
 100     description        => 'Test Assortment',
 101     sellprice          => '10',
 102     lastcost           => '5',
 103     assortment_items   => $assortment_items,
 104     buchungsgruppen_id => _default_buchungsgruppe()->id,
 105     unit               => _default_unit()->name
 106   );
 107
 108   $assortment->assign_attributes( %params );
 109   return $assortment;
 110 }
 111
 112
 113 sub _default_buchungsgruppe {
 114   return SL::DB::Manager::Buchungsgruppe->find_by(description => 'Standard 19%') || die "No accounting group";
 115 }
 116
 117 sub _default_unit {
 118   return SL::DB::Manager::Unit->find_by(name => 'Stck') || die "No unit";
 119 }
 120
 121
 122 1;
 123
 124 __END__
 125
 126 =head1 NAME
 127
 128 SL::Dev::Part - create part objects for testing, with minimal defaults
 129
 130 =head1 SYNOPSIS
 131
 132   use SL::Dev::Part qw(new_part new_assembly new_service new_assortment);
 133
 134   # simple default objects
 135   my $part     = new_part()->save;
 136   my $assembly = new_assembly()->save;
 137   my $service  = new_service()->save;
 138   my $assortment = new_assortment()->save;
 139
 140   # pass additional params to the generated object
 141   # see individual functions for special parameters
 142   my $part     = new_part(
 143     partnumber   => 'Test 001',
 144     rop          => 20,
 145   );
 146
 147 =head1 FUNCTIONS
 148
 149 =head2 C<new_part %PARAMS>
 150
 151 Creates a new part (part_type = part).
 152
 153 =head2 C<new_service %PARAMS>
 154
 155 Creates a new service (part_type = service).
 156
 157 =head2 C<new_assembly %PARAMS>
 158
 159 Create a new assembly (part_type = assembly).
 160
 161 Special params:
 162
 163 =over 2
 164
 165 =item * C<number_of_parts>
 166
 167 The number of automatically created assembly parts.
 168
 169 =item * C<assnumber>
 170
 171 the partnumber of the assembly
 172
 173 =item * C<partnumber>
 174
 175 the partnumber of the first assembly part to be created
 176
 177 =back
 178
 179 By default 3 parts (p1, p2, p3) are created and saved as an assembly (as1).
 180
 181 Create a new assembly with 10 parts, the assembly gets partnumber 'Ass1' and the
 182 parts get partnumbers 'Testpart 1' to 'Testpart 10':
 183
 184   my $assembly = SL::Dev::Part::new_assembly(
 185     number_of_parts => 10,
 186     partnumber      => 'Testpart',
 187     assnumber       => 'Ass1'
 188   )->save;
 189
 190 Create an assembly with specific parts:
 191
 192   my $assembly_item_1 = SL::DB::Assembly->new( parts_id => $part1->id, qty => 3, position => 1);
 193   my $assembly_item_2 = SL::DB::Assembly->new( parts_id => $part2->id, qty => 3, position => 2);
 194   my $assembly_part   = new_assembly(
 195     assnumber      => 'Assembly 1',
 196     description    => 'Assembly test',
 197     sellprice      => $part1->sellprice + $part2->sellprice,
 198     assembly_items => [ $assembly_item_1, $assembly_item_2 ],
 199   );
 200
 201 =head2 C<new_assortment %PARAMS>
 202
 203 Create a new assortment (part_type = assortment).
 204
 205 Special params:
 206
 207 =over 2
 208
 209 =item * C<number_of_parts>
 210
 211 The number of automatically created assembly parts.
 212
 213 =item * C<assnumber>
 214
 215 the partnumber of the assortment
 216
 217 =item * C<partnumber>
 218
 219 the partnumber of the first assembly part to be created
 220
 221 =back
 222
 223 By default 3 parts (p1, p2, p3) are created and saved as an assortment.
 224
 225 Create a new assortment with 10 automatically created parts using the
 226 number_of_parts param:
 227
 228   my $assortment = new_assortment(number_of_parts => 10)->save;
 229
 230 Create an assortment with a certain name and pass some assortment_item Objects
 231 from newly created parts:
 232
 233   my $part1             = new_part(sellprice => 7.77)->save;
 234   my $part2             = new_part(sellprice => 6.66)->save;
 235   my $assortment_item_1 = SL::DB::AssortmentItem->new( parts_id => $part1->id, qty => 3, unit => $part1->unit, position => 1);
 236   my $assortment_item_2 = SL::DB::AssortmentItem->new( parts_id => $part2->id, qty => 3, unit => $part2->unit, position => 2);
 237   my $assortment_part   = SL::Dev::Part::new_assortment(
 238     assnumber        => 'Assortment 1',
 239     description      => 'assortment test',
 240     sellprice        => (3*$part1->sellprice + 3*$part2->sellprice),
 241     lastcost         => (3*$part1->lastcost  + 3*$part2->lastcost),
 242     assortment_items => [ $assortment_item_1, $assortment_item_2 ],
 243   )->save;
 244
 245 =head1 TODO
 246
 247 Nothing here yet.
 248
 249 =head1 BUGS
 250
 251 Nothing here yet.
 252
 253 =head1 AUTHOR
 254
 255 G. Richardson E<lt>grichardson@kivitendo-premium.deE<gt>
 256
 257 =cut