SL/Controller/CustomerVendor.pm

   1 package SL::Controller::CustomerVendor;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::JSON;
   7 use SL::DBUtils;
   8 use SL::Helper::Flash;
   9
  10 use SL::DB::Customer;
  11 use SL::DB::Vendor;
  12 use SL::DB::Business;
  13 use SL::DB::Employee;
  14 use SL::DB::Language;
  15 use SL::DB::TaxZone;
  16 use SL::DB::Note;
  17 use SL::DB::PaymentTerm;
  18 use SL::DB::Pricegroup;
  19 use SL::DB::Contact;
  20 use SL::DB::FollowUp;
  21 use SL::DB::FollowUpLink;
  22 use SL::DB::History;
  23 use SL::DB::Currency;
  24
  25 # safety
  26 __PACKAGE__->run_before(
  27   sub {
  28     $::auth->assert('customer_vendor_edit');
  29   }
  30 );
  31
  32 __PACKAGE__->run_before(
  33   '_instantiate_args',
  34   only => [
  35     'save',
  36     'save_and_ap_transaction',
  37     'save_and_ar_transaction',
  38     'save_and_close',
  39     'save_and_invoice',
  40     'save_and_order',
  41     'save_and_quotation',
  42     'save_and_rfq',
  43     'delete',
  44     'delete_contact',
  45     'delete_shipto',
  46   ]
  47 );
  48
  49 __PACKAGE__->run_before(
  50   '_load_customer_vendor',
  51   only => [
  52     'edit',
  53     'update',
  54     'ajaj_get_shipto',
  55     'ajaj_get_contact',
  56   ]
  57 );
  58 __PACKAGE__->run_before(
  59   '_create_customer_vendor',
  60   only => [
  61     'add',
  62   ]
  63 );
  64
  65 sub action_add {
  66   my ($self) = @_;
  67
  68   $self->_pre_render();
  69   $self->render(
  70     'customer_vendor/form',
  71     title => ($self->is_vendor() ? $::locale->text('Add Vendor') : $::locale->text('Add Customer')),
  72     %{$self->{template_args}}
  73   );
  74 }
  75
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   $self->_pre_render();
  80   $self->render(
  81     'customer_vendor/form',
  82     title => ($self->is_vendor() ? $::locale->text('Edit Vendor') : $::locale->text('Edit Customer')),
  83     %{$self->{template_args}}
  84   );
  85 }
  86
  87 sub _save {
  88   my ($self) = @_;
  89
  90   my $db = $self->{cv}->db;
  91
  92   $db->do_transaction(sub {
  93     my $cvs_by_nr;
  94     if ( $self->is_vendor() ) {
  95       if ( $self->{cv}->vendornumber ) {
  96         $cvs_by_nr = SL::DB::Manager::Vendor->get_all(query => [vendornumber => $self->{cv}->vendornumber]);
  97       }
  98     } else {
  99       if ( $self->{cv}->customernumber ) {
 100         $cvs_by_nr = SL::DB::Manager::Customer->get_all(query => [customernumber => $self->{cv}->customernumber]);
 101       }
 102     }
 103
 104     foreach my $entry (@{$cvs_by_nr}) {
 105       if( $entry->id != $self->{cv}->id ) {
 106         my $msg =
 107           $self->is_vendor() ? $::locale->text('This vendor number is already in use.') : $::locale->text('This customer number is already in use.');
 108
 109         $::form->error($msg);
 110       }
 111     }
 112
 113     $self->{cv}->save(cascade => 1);
 114
 115     $self->{contact}->cp_cv_id($self->{cv}->id);
 116     if( $self->{contact}->cp_name ne '' || $self->{contact}->cp_givenname ne '' ) {
 117       $self->{contact}->save();
 118     }
 119
 120     if( $self->{note}->subject ne '' && $self->{note}->body ne '' ) {
 121
 122       if ( !$self->{note_followup}->follow_up_date ) {
 123         $::form->error($::locale->text('Date missing!'));
 124       }
 125
 126       $self->{note}->trans_id($self->{cv}->id);
 127       $self->{note}->save();
 128
 129       $self->{note_followup}->save();
 130
 131       $self->{note_followup_link}->follow_up_id($self->{note_followup}->id);
 132       $self->{note_followup_link}->trans_id($self->{cv}->id);
 133       $self->{note_followup_link}->save();
 134
 135       SL::Helper::Flash::flash_later('info', $::locale->text('Follow-Up saved.'));
 136     }
 137
 138     $self->{shipto}->trans_id($self->{cv}->id);
 139     if( $self->{shipto}->shiptoname ne '' ) {
 140       $self->{shipto}->save();
 141     }
 142
 143     my $snumbers = $self->is_vendor() ? 'vendornumber_'. $self->{cv}->vendornumber : 'customernumber_'. $self->{cv}->customernumber;
 144     SL::DB::History->new(
 145       trans_id => $self->{cv}->id,
 146       snumbers => $snumbers,
 147       employee_id => SL::DB::Manager::Employee->current->id,
 148       addition => 'SAVED',
 149     )->save();
 150
 151     if ( $::form->{delete_notes} ) {
 152       foreach my $note_id (@{ $::form->{delete_notes} }) {
 153         my $note = SL::DB::Note->new(id => $note_id)->load();
 154         if ( $note->follow_up ) {
 155           if ( $note->follow_up->follow_up_link ) {
 156             $note->follow_up->follow_up_link->delete(cascade => 'delete');
 157           }
 158           $note->follow_up->delete(cascade => 'delete');
 159         }
 160         $note->delete(cascade => 'delete');
 161       }
 162     }
 163   }) || die($db->error);
 164
 165 }
 166
 167 sub action_save {
 168   my ($self) = @_;
 169
 170   $self->_save();
 171
 172   my @redirect_params = (
 173     action => 'edit',
 174     id     => $self->{cv}->id,
 175     db     => ($self->is_vendor() ? 'vendor' : 'customer'),
 176   );
 177
 178   if ( $self->{contact}->cp_id ) {
 179     push(@redirect_params, contact_id => $self->{contact}->cp_id);
 180   }
 181
 182   if ( $self->{shipto}->shipto_id ) {
 183     push(@redirect_params, shipto_id => $self->{shipto}->shipto_id);
 184   }
 185
 186   $self->redirect_to(@redirect_params);
 187 }
 188
 189 sub action_save_and_close {
 190   my ($self) = @_;
 191
 192   $self->_save();
 193
 194   my $msg = $self->is_vendor() ? $::locale->text('Vendor saved') : $::locale->text('Customer saved');
 195   $::form->redirect($msg);
 196 }
 197
 198 sub _transaction {
 199   my ($self, $script) = @_;
 200
 201   $::auth->assert('general_ledger         | invoice_edit         | vendor_invoice_edit | ' .
 202                  ' request_quotation_edit | sales_quotation_edit | sales_order_edit    | purchase_order_edit');
 203
 204   $self->_save();
 205
 206   my $callback = $::form->escape($::form->{callback}, 1);
 207   my $name = $::form->escape($self->{cv}->name, 1);
 208   my $db = $self->is_vendor() ? 'vendor' : 'customer';
 209
 210   my $url = $self->url_for(
 211     controller => $script,
 212     action     => 'add',
 213     vc         => $db,
 214     $db .'_id' => $self->{cv}->id,
 215     $db        => $name,
 216     type       => $::form->{type},
 217     callback   => $callback,
 218   );
 219
 220   print $::form->redirect_header($url);
 221 }
 222
 223 sub action_save_and_ar_transaction {
 224   my ($self) = @_;
 225
 226   $main::auth->assert('general_ledger');
 227
 228   $self->_transaction('ar.pl');
 229 }
 230
 231 sub action_save_and_ap_transaction {
 232   my ($self) = @_;
 233
 234   $main::auth->assert('general_ledger');
 235
 236   $self->_transaction('ap.pl');
 237 }
 238
 239 sub action_save_and_invoice {
 240   my ($self) = @_;
 241
 242   if ( $self->is_vendor() ) {
 243     $::auth->assert('vendor_invoice_edit');
 244   } else {
 245     $::auth->assert('invoice_edit');
 246   }
 247
 248   $::form->{type} = 'invoice';
 249   $self->_transaction($self->is_vendor() ? 'ir.pl' : 'is.pl');
 250 }
 251
 252 sub action_save_and_order {
 253   my ($self) = @_;
 254
 255   if ( $self->is_vendor() ) {
 256     $::auth->assert('purchase_order_edit');
 257   } else {
 258     $::auth->assert('sales_order_edit');
 259   }
 260
 261   $::form->{type} = $self->is_vendor() ? 'purchase_order' : 'sales_order';
 262   $self->_transaction('oe.pl');
 263 }
 264
 265 sub action_save_and_rfq {
 266   my ($self) = @_;
 267
 268   $::auth->assert('request_quotation_edit');
 269
 270   $::form->{type} = 'request_quotation';
 271   $self->_transaction('oe.pl');
 272 }
 273
 274 sub action_save_and_quotation {
 275   my ($self) = @_;
 276
 277   $::auth->assert('sales_quotation_edit');
 278
 279   $::form->{type} = 'sales_quotation';
 280   $self->_transaction('oe.pl');
 281 }
 282
 283 sub action_delete {
 284   my ($self) = @_;
 285
 286   my $db = $self->{cv}->db;
 287
 288   if( !$self->is_orphaned() ) {
 289     $self->action_edit();
 290   } else {
 291
 292     $db->do_transaction(sub {
 293       $self->{cv}->delete(cascade => 1);
 294
 295       my $snumbers = $self->is_vendor() ? 'vendornumber_'. $self->{cv}->vendornumber : 'customernumber_'. $self->{cv}->customernumber;
 296       SL::DB::History->new(
 297         trans_id => $self->{cv}->id,
 298         snumbers => $snumbers,
 299         employee_id => SL::DB::Manager::Employee->current->id,
 300         addition => 'DELETED',
 301       )->save();
 302     }) || die($db->error);
 303
 304     my $msg = $self->is_vendor() ? $::locale->text('Vendor deleted!') : $::locale->text('Customer deleted!');
 305     $::form->redirect($msg);
 306   }
 307
 308 }
 309
 310
 311 sub action_delete_contact {
 312   my ($self) = @_;
 313
 314   my $db = $self->{contact}->db;
 315
 316   if ( !$self->{contact}->cp_id ) {
 317     SL::Helper::Flash::flash('error', $::locale->text('No contact selected to delete'));
 318   } else {
 319
 320     $db->do_transaction(sub {
 321       if ( $self->{contact}->used ) {
 322         $self->{contact}->detach();
 323         $self->{contact}->save();
 324         SL::Helper::Flash::flash('info', $::locale->text('Contact is in use and was flagged invalid.'));
 325       } else {
 326         $self->{contact}->delete(cascade => 1);
 327         SL::Helper::Flash::flash('info', $::locale->text('Contact deleted.'));
 328       }
 329     }) || die($db->error);
 330
 331     $self->{contact} = SL::DB::Contact->new();
 332   }
 333
 334   $self->action_edit();
 335 }
 336
 337 sub action_delete_shipto {
 338   my ($self) = @_;
 339
 340   my $db = $self->{shipto}->db;
 341
 342   if ( !$self->{shipto}->shipto_id ) {
 343     SL::Helper::Flash::flash('error', $::locale->text('No shipto selected to delete'));
 344   } else {
 345
 346     $db->do_transaction(sub {
 347       if ( $self->{shipto}->used ) {
 348         $self->{shipto}->detach();
 349         $self->{shipto}->save(cascade => 1);
 350         SL::Helper::Flash::flash('info', $::locale->text('Shipto is in use and was flagged invalid.'));
 351       } else {
 352         $self->{shipto}->delete(cascade => 1);
 353         SL::Helper::Flash::flash('info', $::locale->text('Shipto deleted.'));
 354       }
 355     }) || die($db->error);
 356
 357     $self->{shipto} = SL::DB::Shipto->new();
 358   }
 359
 360   $self->action_edit();
 361 }
 362
 363
 364 sub action_search {
 365   my ($self) = @_;
 366
 367   my @url_params = (
 368     controller => 'ct.pl',
 369     action => 'search',
 370     db => $self->is_vendor() ? 'vendor' : 'customer',
 371   );
 372
 373   if ( $::form->{callback} ) {
 374     push(@url_params, callback => $::form->{callback});
 375   }
 376
 377   $self->redirect_to(@url_params);
 378 }
 379
 380
 381 sub action_search_contact {
 382   my ($self) = @_;
 383
 384   my $url = 'ct.pl?action=search_contact&db=customer';
 385
 386   if ( $::form->{callback} ) {
 387     $url .= '&callback='. $::form->escape($::form->{callback});
 388   }
 389
 390   print $::form->redirect_header($url);
 391 }
 392
 393
 394 sub action_get_delivery {
 395   my ($self) = @_;
 396
 397   my $dbh = $::form->get_standard_dbh();
 398
 399   my ($arap, $db, $qty_sign);
 400   if ( $self->is_vendor() ) {
 401     $arap = 'ap';
 402     $db = 'vendor';
 403     $qty_sign = ' * -1 AS qty';
 404   } else {
 405     $arap = 'ar';
 406     $db = 'customer';
 407     $qty_sign = '';
 408   }
 409
 410   my $where = ' WHERE 1=1 ';
 411   my @values;
 412
 413   if ( !$self->is_vendor() && $::form->{shipto_id} && $::form->{shipto_id} ne 'all' ) {
 414     $where .= "AND ${arap}.shipto_id = ?";
 415     push(@values, $::form->{shipto_id});
 416   }
 417
 418   if ( $::form->{delivery_from} ) {
 419     $where .= "AND ${arap}.transdate >= ?";
 420     push(@values, conv_date($::form->{delivery_from}));
 421   }
 422
 423   if ( $::form->{delivery_to} ) {
 424     $where .= "AND ${arap}.transdate <= ?";
 425     push(@values, conv_date($::form->{delivery_to}));
 426   }
 427
 428   my $query =
 429     "SELECT
 430        s.shiptoname,
 431        i.qty ${qty_sign},
 432        ${arap}.id,
 433        ${arap}.transdate,
 434        ${arap}.invnumber,
 435        ${arap}.ordnumber,
 436        i.description,
 437        i.unit,
 438        i.sellprice,
 439        oe.id AS oe_id,
 440        invoice
 441      FROM ${arap}
 442
 443      LEFT JOIN shipto s
 444       ON ". ($arap eq 'ar' ? '(ar.shipto_id = s.shipto_id) ' : '(ap.id = s.trans_id) ') ."
 445
 446      LEFT JOIN invoice i
 447        ON ${arap}.id = i.trans_id
 448
 449      LEFT JOIN parts p
 450        ON p.id = i.parts_id
 451
 452      LEFT JOIN oe
 453        ON (oe.ordnumber = ${arap}.ordnumber AND NOT ${arap}.ordnumber = '')
 454
 455      ${where}
 456      ORDER BY ${arap}.transdate DESC LIMIT 15";
 457
 458   $self->{delivery} = selectall_hashref_query($::form, $dbh, $query, @values);
 459
 460   $self->render('customer_vendor/get_delivery', { layout => 0 });
 461 }
 462
 463 sub action_ajaj_get_shipto {
 464   my ($self) = @_;
 465
 466   my $data = {
 467     map(
 468       {
 469         my $name = 'shipto'. $_;
 470         $name => $self->{shipto}->$name;
 471       }
 472       qw(_id name department_1 department_2 street zipcode city country contact phone fax email)
 473     )
 474   };
 475
 476   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 477 }
 478
 479 sub action_ajaj_get_contact {
 480   my ($self) = @_;
 481
 482   my $data;
 483
 484   $data->{contact} = {
 485     map(
 486       {
 487         my $name = 'cp_'. $_;
 488
 489         if ( $_ eq 'birthday' && $self->{contact}->$name ) {
 490           $name => $self->{contact}->$name->to_lxoffice;
 491         } else {
 492           $name => $self->{contact}->$name;
 493         }
 494       }
 495       qw(
 496         id gender abteilung title position givenname name email phone1 phone2 fax mobile1 mobile2
 497         satphone satfax project street zipcode city privatphone privatemail birthday
 498       )
 499     )
 500   };
 501
 502   $data->{contact_cvars} = {
 503     map(
 504       {
 505         if ( $_->config->type eq 'number' ) {
 506           $_->config->name => $::form->format_amount(\%::myconfig, $_->value, -2);
 507         } else {
 508           $_->config->name => $_->value;
 509         }
 510       }
 511       grep(
 512         { $_->is_valid; }
 513         @{$self->{contact}->cvars_by_config}
 514       )
 515     )
 516   };
 517
 518   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
 519 }
 520
 521 sub action_ajaj_customer_autocomplete {
 522   my ($self, %params) = @_;
 523
 524   my $limit = $::form->{limit} || 20;
 525   my $type  = $::form->{type}  || {};
 526   my $query = { ilike => '%'. $::form->{term} .'%' };
 527
 528   my @filter;
 529   push(
 530     @filter,
 531     $::form->{column} ? ($::form->{column} => $query) : (or => [ customernumber => $query, name => $query ])
 532   );
 533
 534   my $customers = SL::DB::Manager::Customer->get_all(query => [ @filter ], limit => $limit);
 535   my $value_col = $::form->{column} || 'name';
 536
 537   my $data = [
 538     map(
 539       {
 540         {
 541           value => $_->can($value_col)->($_),
 542           label => $_->displayable_name,
 543           id    => $_->id,
 544           customernumber => $_->customernumber,
 545           name  => $_->name,
 546         }
 547       }
 548       @{$customers}
 549     )
 550   ];
 551
 552   $self->render(\SL::JSON::to_json($data), { layout => 0, type => 'json' });
 553 }
 554
 555 sub is_vendor {
 556   return $::form->{db} eq 'vendor';
 557 }
 558
 559 sub is_customer {
 560   return $::form->{db} eq 'customer';
 561 }
 562
 563 sub is_orphaned {
 564   my ($self) = @_;
 565
 566   if ( defined($self->{_is_orphaned}) ) {
 567     return $self->{_is_orphaned};
 568   }
 569
 570   my $arap      = $self->is_vendor ? 'ap' : 'ar';
 571   my $num_args  = 2;
 572
 573   my $cv = $self->is_vendor ? 'vendor' : 'customer';
 574
 575   my $query =
 576    'SELECT a.id
 577     FROM '. $arap .' AS a
 578     JOIN '. $cv .' ct ON (a.'. $cv .'_id = ct.id)
 579     WHERE ct.id = ?
 580
 581     UNION
 582
 583     SELECT a.id
 584     FROM oe a
 585     JOIN '. $cv .' ct ON (a.'. $cv .'_id = ct.id)
 586     WHERE ct.id = ?';
 587
 588
 589   if ( $self->is_vendor ) {
 590     $query .=
 591      ' UNION
 592       SELECT 1 FROM makemodel mm WHERE mm.make = ?';
 593     $num_args++;
 594   }
 595
 596   my ($dummy) = selectrow_query($::form, $::form->get_standard_dbh(), $query, (conv_i($self->{cv}->id)) x $num_args);
 597
 598   return $self->{_is_orphaned} = !$dummy;
 599 }
 600
 601 sub _instantiate_args {
 602   my ($self) = @_;
 603
 604   my $curr_employee = SL::DB::Manager::Employee->current;
 605
 606   if ( $::form->{cv}->{id} ) {
 607     if ( $self->is_vendor() ) {
 608       $self->{cv} = SL::DB::Vendor->new(id => $::form->{cv}->{id})->load();
 609     } else {
 610       $self->{cv} = SL::DB::Customer->new(id => $::form->{cv}->{id})->load();
 611     }
 612   } else {
 613     if ( $self->is_vendor() ) {
 614       $self->{cv} = SL::DB::Vendor->new();
 615     } else {
 616       $self->{cv} = SL::DB::Customer->new();
 617     }
 618   }
 619   $self->{cv}->assign_attributes(%{$::form->{cv}});
 620
 621   if ( $self->is_customer() && $::form->{cv}->{taxincluded_checked} eq '' ) {
 622     $self->{cv}->taxincluded_checked(undef);
 623   }
 624
 625
 626   foreach my $cvar (@{$self->{cv}->cvars_by_config()}) {
 627     my $value = $::form->{cv_cvars}->{$cvar->config->name};
 628
 629     if ( $cvar->config->type eq 'number' ) {
 630       $value = $::form->parse_amount(\%::myconfig, $value);
 631     }
 632
 633     $cvar->value($value);
 634   }
 635
 636   if ( $::form->{note}->{id} ) {
 637     $self->{note} = SL::DB::Note->new(id => $::form->{note}->{id})->load();
 638     $self->{note_followup} = $self->{note}->follow_up;
 639     $self->{note_followup_link} = $self->{note_followup}->follow_up_link;
 640   } else {
 641     $self->{note} = SL::DB::Note->new();
 642     $self->{note_followup} = SL::DB::FollowUp->new();
 643     $self->{note_followup_link} = SL::DB::FollowUpLink->new();
 644   }
 645
 646   $self->{note}->assign_attributes(%{$::form->{note}});
 647   $self->{note}->created_by($curr_employee->id);
 648   $self->{note}->trans_module('ct');
 649
 650   $self->{note_followup}->assign_attributes(%{$::form->{note_followup}});
 651   $self->{note_followup}->note($self->{note});
 652   $self->{note_followup}->created_by($curr_employee->id);
 653
 654   $self->{note_followup_link}->trans_type($self->is_vendor() ? 'vendor' : 'customer');
 655   $self->{note_followup_link}->trans_info($self->{cv}->name);
 656
 657   if ( $::form->{shipto}->{shipto_id} ) {
 658     $self->{shipto} = SL::DB::Shipto->new(shipto_id => $::form->{shipto}->{shipto_id})->load();
 659   } else {
 660     $self->{shipto} = SL::DB::Shipto->new();
 661   }
 662   $self->{shipto}->assign_attributes(%{$::form->{shipto}});
 663   $self->{shipto}->module('CT');
 664
 665   if ( $::form->{contact}->{cp_id} ) {
 666     $self->{contact} = SL::DB::Contact->new(cp_id => $::form->{contact}->{cp_id})->load();
 667   } else {
 668     $self->{contact} = SL::DB::Contact->new();
 669   }
 670   $self->{contact}->assign_attributes(%{$::form->{contact}});
 671
 672   foreach my $cvar (@{$self->{contact}->cvars_by_config()}) {
 673     my $value = $::form->{contact_cvars}->{$cvar->config->name};
 674
 675     if ( $cvar->config->type eq 'number' ) {
 676       $value = $::form->parse_amount(\%::myconfig, $value);
 677     }
 678
 679     $cvar->value($value);
 680   }
 681 }
 682
 683 sub _load_customer_vendor {
 684   my ($self) = @_;
 685
 686   if ( $self->is_vendor() ) {
 687     $self->{cv} = SL::DB::Vendor->new(id => $::form->{id})->load();
 688   } else {
 689     $self->{cv} = SL::DB::Customer->new(id => $::form->{id})->load();
 690   }
 691
 692   if ( $::form->{note_id} ) {
 693     $self->{note} = SL::DB::Note->new(id => $::form->{note_id})->load();
 694     $self->{note_followup} = $self->{note}->follow_up;
 695     $self->{note_followup_link} = $self->{note_followup}->follow_up_link;
 696   } else {
 697     $self->{note} = SL::DB::Note->new();
 698     $self->{note_followup} = SL::DB::FollowUp->new();
 699     $self->{note_followup_link} = SL::DB::FollowUpLink->new();
 700   }
 701
 702   if ( $::form->{shipto_id} ) {
 703     $self->{shipto} = SL::DB::Shipto->new(shipto_id => $::form->{shipto_id})->load();
 704
 705     if ( $self->{shipto}->trans_id != $self->{cv}->id ) {
 706       die($::locale->text('Error'));
 707     }
 708   } else {
 709     $self->{shipto} = SL::DB::Shipto->new();
 710   }
 711
 712   if ( $::form->{contact_id} ) {
 713     $self->{contact} = SL::DB::Contact->new(cp_id => $::form->{contact_id})->load();
 714
 715     if ( $self->{contact}->cp_cv_id != $self->{cv}->id ) {
 716       die($::locale->text('Error'));
 717     }
 718   } else {
 719     $self->{contact} = SL::DB::Contact->new();
 720   }
 721 }
 722
 723 sub _create_customer_vendor {
 724   my ($self) = @_;
 725
 726   if ( $self->is_vendor() ) {
 727     $self->{cv} = SL::DB::Vendor->new();
 728   } else {
 729     $self->{cv} = SL::DB::Customer->new();
 730   }
 731   $self->{cv}->currency_id($::instance_conf->get_currency_id());
 732
 733   $self->{note} = SL::DB::Note->new();
 734
 735   $self->{note_followup} = SL::DB::FollowUp->new();
 736
 737   $self->{shipto} = SL::DB::Shipto->new();
 738
 739   $self->{contact} = SL::DB::Contact->new();
 740 }
 741
 742 sub _pre_render {
 743   my ($self) = @_;
 744
 745   my $dbh = $::form->get_standard_dbh();
 746
 747   my $query;
 748
 749   $self->{all_business} = SL::DB::Manager::Business->get_all();
 750
 751   $self->{all_employees} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 752
 753   $query =
 754     'SELECT DISTINCT(greeting)
 755      FROM customer
 756      WHERE greeting IS NOT NULL AND greeting != \'\'
 757      UNION
 758        SELECT DISTINCT(greeting)
 759        FROM vendor
 760        WHERE greeting IS NOT NULL AND greeting != \'\'
 761      ORDER BY greeting';
 762   $self->{all_greetings} = [
 763     map(
 764       { $_->{greeting}; }
 765       selectall_hashref_query($::form, $dbh, $query)
 766     )
 767   ];
 768
 769   $query =
 770     'SELECT DISTINCT(cp_title) AS title
 771      FROM contacts
 772      WHERE cp_title IS NOT NULL AND cp_title != \'\'
 773      ORDER BY cp_title';
 774   $self->{all_titles} = [
 775     map(
 776       { $_->{title}; }
 777       selectall_hashref_query($::form, $dbh, $query)
 778     )
 779   ];
 780
 781   $self->{all_currencies} = SL::DB::Manager::Currency->get_all();
 782
 783   $self->{all_languages} = SL::DB::Manager::Language->get_all();
 784
 785   $self->{all_taxzones} = SL::DB::Manager::TaxZone->get_all();
 786
 787   if ( $::instance_conf->get_vertreter() ) {
 788     $query =
 789       'SELECT id
 790        FROM business
 791        WHERE salesman';
 792     my $business_ids = [
 793       map(
 794         { $_->{id}; }
 795         selectall_hashref_query($::form, $dbh, $query)
 796       )
 797     ];
 798
 799     if ( $business_ids->[0] ) {
 800       $self->{all_salesman_customers} = SL::DB::Manager::Customer->get_all(query => [business_id => $business_ids]);
 801     } else {
 802       $self->{all_salesman_customers} = [];
 803     }
 804   } else {
 805     $self->{all_salesmen} = SL::DB::Manager::Employee->get_all(query => [ or => [ id => $self->{cv}->salesman_id,  deleted => 0 ] ]);
 806   }
 807
 808   $self->{all_payment_terms} = SL::DB::Manager::PaymentTerm->get_all();
 809
 810   $self->{all_pricegroups} = SL::DB::Manager::Pricegroup->get_all();
 811
 812   $query =
 813     'SELECT DISTINCT(cp_abteilung) AS department
 814      FROM contacts
 815      WHERE cp_abteilung IS NOT NULL AND cp_abteilung != \'\'
 816      ORDER BY cp_abteilung';
 817   $self->{all_departments} = [
 818     map(
 819       { $_->{department}; }
 820       selectall_hashref_query($::form, $dbh, $query)
 821     )
 822   ];
 823
 824   $self->{contacts} = $self->{cv}->contacts;
 825   $self->{contacts} ||= [];
 826
 827   $self->{shiptos} = $self->{cv}->shipto;
 828   $self->{shiptos} ||= [];
 829
 830   $self->{notes} = SL::DB::Manager::Note->get_all(
 831     query => [
 832       trans_id => $self->{cv}->id,
 833       trans_module => 'ct',
 834     ],
 835     with_objects => ['follow_up'],
 836   );
 837
 838   $self->{template_args} ||= {};
 839
 840   $::request->{layout}->add_javascripts('autocomplete_customer.js');
 841   $::request->{layout}->add_javascripts('kivi.CustomerVendor.js');
 842 }
 843
 844 1;