bin/mozilla/dn.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2006
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 1998-2002
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # Dunning process module
  31 #
  32 #======================================================================
  33
  34 use POSIX;
  35
  36 use SL::IS;
  37 use SL::PE;
  38 use SL::DN;
  39 use SL::ReportGenerator;
  40
  41 require "bin/mozilla/common.pl";
  42 require "bin/mozilla/reportgenerator.pl";
  43 require "bin/mozilla/io.pl";
  44
  45 use strict;
  46
  47 1;
  48
  49 sub edit_config {
  50   $main::lxdebug->enter_sub();
  51
  52   my $form     = $main::form;
  53   my %myconfig = %main::myconfig;
  54   my $locale   = $main::locale;
  55
  56   $main::auth->assert('config');
  57
  58   DN->get_config(\%myconfig, \%$form);
  59   $form->get_lists('charts' => { 'key'       => 'ALL_CHARTS',
  60                                  'transdate' => 'current_date' });
  61
  62   $form->{SELECT_AR_AMOUNT} = [];
  63   $form->{SELECT_AR}        = [];
  64
  65   foreach my $chart (@{ $form->{ALL_CHARTS} }) {
  66     $chart->{LINKS} = { map { $_, 1 } split m/:/, $chart->{link} };
  67
  68     if ($chart->{LINKS}->{AR}) {
  69       $chart->{AR_selected} = "selected" if $chart->{id} == $form->{AR};
  70       push @{ $form->{SELECT_AR} }, $chart;
  71     }
  72
  73     if ($chart->{LINKS}->{AR_amount}) {
  74       $chart->{AR_amount_fee_selected}      = "selected" if $chart->{id} == $form->{AR_amount_fee};
  75       $chart->{AR_amount_interest_selected} = "selected" if $chart->{id} == $form->{AR_amount_interest};
  76       push @{ $form->{SELECT_AR_AMOUNT} }, $chart;
  77     }
  78   }
  79
  80   $form->{title}      = $locale->text('Edit Dunning Process Config');
  81   $form->{callback} ||= build_std_url("action=edit_config");
  82
  83   $form->header();
  84   print $form->parse_html_template("dunning/edit_config");
  85
  86   $main::lxdebug->leave_sub();
  87 }
  88
  89 sub add {
  90   $main::lxdebug->enter_sub();
  91
  92   my $form     = $main::form;
  93   my %myconfig = %main::myconfig;
  94   my $locale   = $main::locale;
  95
  96   $main::auth->assert('dunning_edit');
  97
  98   # setup customer selection
  99   $form->all_vc(\%myconfig, "customer", "AR");
 100
 101   DN->get_config(\%myconfig, \%$form);
 102
 103   $form->{SHOW_CUSTOMER_SELECTION}      = $form->{all_customer}    && scalar @{ $form->{all_customer} };
 104   $form->{SHOW_DUNNING_LEVEL_SELECTION} = $form->{DUNNING}         && scalar @{ $form->{DUNNING} };
 105   $form->{SHOW_DEPARTMENT_SELECTION}    = $form->{all_departments} && scalar @{ $form->{all_departments} || [] };
 106
 107   $form->{title}    = $locale->text('Start Dunning Process');
 108   $form->header();
 109
 110   print $form->parse_html_template("dunning/add");
 111
 112   $main::lxdebug->leave_sub();
 113 }
 114
 115 sub show_invoices {
 116   $main::lxdebug->enter_sub();
 117
 118   my $form     = $main::form;
 119   my %myconfig = %main::myconfig;
 120   my $locale   = $main::locale;
 121
 122   $main::auth->assert('dunning_edit');
 123
 124   DN->get_invoices(\%myconfig, \%$form);
 125   $form->{title} = $locale->text('Start Dunning Process');
 126
 127   foreach my $row (@{ $form->{DUNNINGS} }) {
 128     $row->{DUNNING_CONFIG} = [ map +{ %{ $_ } }, @{ $form->{DUNNING_CONFIG} } ];
 129
 130     if ($row->{next_dunning_config_id}) {
 131       map { $_->{SELECTED} = $_->{id} == $row->{next_dunning_config_id} } @{ $row->{DUNNING_CONFIG } };
 132     }
 133     map { $row->{$_} = $form->format_amount(\%myconfig, $row->{$_} * 1, -2) } qw(amount open_amount fee interest);
 134
 135     if ($row->{'language_id'}) {
 136       $row->{language} = SL::DB::Manager::Language->find_by_or_create('id' => $row->{'language_id'})->{'description'};
 137     }
 138   }
 139
 140   $form->get_lists('printers'  => 'printers',
 141                    'languages' => 'languages');
 142
 143   $form->{type}           = 'dunning';
 144   $form->{rowcount}       = scalar @{ $form->{DUNNINGS} };
 145   $form->{callback}     ||= build_std_url("action=show_invoices", qw(customer invnumber ordnumber groupinvoices minamount dunning_level notes));
 146
 147   $form->{PRINT_OPTIONS}  = print_options('inline'          => 1,
 148                                           'no_queue'        => 1,
 149                                           'no_postscript'   => 1,
 150                                           'no_html'         => 1,
 151                                           'no_opendocument' => 1,);
 152
 153   $form->header();
 154   print $form->parse_html_template("dunning/show_invoices");
 155
 156   $main::lxdebug->leave_sub();
 157 }
 158
 159 sub save {
 160   $main::lxdebug->enter_sub();
 161
 162   my $form     = $main::form;
 163   my %myconfig = %main::myconfig;
 164   my $locale   = $main::locale;
 165
 166   $main::auth->assert('config');
 167
 168   for my $i (1 .. $form->{rowcount}) {
 169     if ($form->{"dunning_description_$i"} ne "") {
 170       $form->isblank("dunning_level_$i", $locale->text('Dunning Level missing in row '). $i);
 171       $form->isblank("dunning_description_$i", $locale->text('Dunning Description missing in row '). $i);
 172       $form->isblank("terms_$i", $locale->text('Terms missing in row '). $i);
 173       $form->isblank("payment_terms_$i", $locale->text('Payment Terms missing in row '). $i);
 174     }
 175   }
 176
 177   DN->save_config(\%myconfig, \%$form);
 178   # saving the history
 179   if(!exists $form->{addition} && $form->{id} ne "") {
 180     $form->{snumbers} = qq|dunning_id_| . $form->{"dunning_id"};
 181     $form->{addition} = "SAVED FOR DUNNING";
 182     $form->save_history;
 183   }
 184   # /saving the history
 185   $form->redirect($locale->text('Dunning Process Config saved!'));
 186
 187   $main::lxdebug->leave_sub();
 188 }
 189
 190 sub save_dunning {
 191   $main::lxdebug->enter_sub();
 192
 193   my $form     = $main::form;
 194   my %myconfig = %main::myconfig;
 195   my $locale   = $main::locale;
 196
 197   $main::auth->assert('dunning_edit');
 198
 199   my $active=1;
 200   my @rows = ();
 201   undef($form->{DUNNING_PDFS});
 202
 203   my $saved_language_id = $form->{language_id};
 204
 205   if ($form->{groupinvoices}) {
 206     my %dunnings_for;
 207
 208     for my $i (1 .. $form->{rowcount}) {
 209       next unless ($form->{"active_$i"});
 210
 211       $dunnings_for{$form->{"customer_id_$i"}} ||= {};
 212       my $dunning_levels = $dunnings_for{$form->{"customer_id_$i"}};
 213
 214       $dunning_levels->{$form->{"next_dunning_config_id_$i"}} ||= [];
 215       my $level = $dunning_levels->{$form->{"next_dunning_config_id_$i"}};
 216
 217       push @{ $level }, { "row"                    => $i,
 218                           "invoice_id"             => $form->{"inv_id_$i"},
 219                           "customer_id"            => $form->{"customer_id_$i"},
 220                           "language_id"            => $form->{"language_id_$i"},
 221                           "next_dunning_config_id" => $form->{"next_dunning_config_id_$i"},
 222                           "email"                  => $form->{"email_$i"}, };
 223     }
 224
 225     foreach my $levels (values %dunnings_for) {
 226       foreach my $level (values %{ $levels }) {
 227         next unless scalar @{ $level };
 228         if (!$form->{force_lang}) {
 229           $form->{language_id} = @{$level}[0]->{language_id};
 230         }
 231         DN->save_dunning(\%myconfig, $form, $level);
 232       }
 233     }
 234
 235   } else {
 236     for my $i (1 .. $form->{rowcount}) {
 237       next unless $form->{"active_$i"};
 238
 239       my $level = [ { "row"                    => $i,
 240                       "invoice_id"             => $form->{"inv_id_$i"},
 241                       "customer_id"            => $form->{"customer_id_$i"},
 242                       "language_id"            => $form->{"language_id_$i"},
 243                       "next_dunning_config_id" => $form->{"next_dunning_config_id_$i"},
 244                       "email"                  => $form->{"email_$i"}, } ];
 245       if (!$form->{force_lang}) {
 246         $form->{language_id} = @{$level}[0]->{language_id};
 247       }
 248       DN->save_dunning(\%myconfig, $form, $level);
 249     }
 250   }
 251
 252   $form->{language_id} = $saved_language_id;
 253
 254   if($form->{DUNNING_PDFS}) {
 255     DN->melt_pdfs(\%myconfig, $form, $form->{copies});
 256   }
 257
 258   # saving the history
 259   if(!exists $form->{addition} && $form->{id} ne "") {
 260     $form->{snumbers} = qq|dunning_id_| . $form->{"dunning_id"};
 261     $form->{addition} = "DUNNING STARTED";
 262     $form->save_history;
 263   }
 264   # /saving the history
 265
 266   if ($form->{media} eq 'printer') {
 267     delete $form->{callback};
 268     $form->redirect($locale->text('Dunning Process started for selected invoices!'));
 269   }
 270
 271   $main::lxdebug->leave_sub();
 272 }
 273
 274 sub set_email {
 275   $main::lxdebug->enter_sub();
 276
 277   my $form     = $main::form;
 278   my $locale   = $main::locale;
 279
 280   $main::auth->assert('dunning_edit');
 281
 282   $form->{"title"} = $locale->text("Set eMail text");
 283   $form->header(no_layout => 1);
 284   print($form->parse_html_template("dunning/set_email"));
 285
 286   $main::lxdebug->leave_sub();
 287 }
 288
 289 sub search {
 290   $main::lxdebug->enter_sub();
 291
 292   my $form     = $main::form;
 293   my %myconfig = %main::myconfig;
 294   my $locale   = $main::locale;
 295
 296   $main::auth->assert('dunning_edit');
 297
 298   $form->get_lists("customers"   => "ALL_CUSTOMERS",
 299                    "departments" => "ALL_DEPARTMENTS");
 300   $form->{ALL_EMPLOYEES} = SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 301
 302   DN->get_config(\%myconfig, \%$form);
 303
 304   $form->{SHOW_CUSTOMER_DDBOX}   = scalar @{ $form->{ALL_CUSTOMERS} } <= $myconfig{vclimit};
 305   $form->{SHOW_DEPARTMENT_DDBOX} = scalar @{ $form->{ALL_CUSTOMERS} };
 306   $form->{SHOW_DUNNING_LEVELS}   = scalar @{ $form->{DUNNING} };
 307
 308   $form->{title}    = $locale->text('Dunnings');
 309
 310   $form->header();
 311
 312   print $form->parse_html_template("dunning/search");
 313
 314   $main::lxdebug->leave_sub();
 315
 316 }
 317
 318 sub show_dunning {
 319   $main::lxdebug->enter_sub();
 320
 321   my $form     = $main::form;
 322   my %myconfig = %main::myconfig;
 323   my $locale   = $main::locale;
 324   my $cgi      = $::request->{cgi};
 325
 326   $main::auth->assert('dunning_edit');
 327
 328   my @filter_field_list = qw(customer_id customer dunning_level department_id invnumber ordnumber
 329                              transdatefrom transdateto dunningfrom dunningto notes showold l_salesman salesman_id);
 330
 331   report_generator_set_default_sort('customername', 1);
 332
 333   DN->get_dunning(\%myconfig, \%$form);
 334
 335   if (!$form->{callback}) {
 336     $form->{callback} = build_std_url("action=show_dunning", @filter_field_list);
 337   }
 338
 339   $form->get_lists('printers'  => 'printers',
 340                    'languages' => 'languages');
 341
 342   $form->{type}          = 'dunning';
 343   $form->{PRINT_OPTIONS} = print_options('inline'          => 1,
 344                                          'no_queue'        => 1,
 345                                          'no_postscript'   => 1,
 346                                          'no_html'         => 1,
 347                                          'no_opendocument' => 1,);
 348   $form->{title}         = $locale->text('Dunning overview');
 349
 350   my $report = SL::ReportGenerator->new(\%myconfig, $form);
 351
 352   $report->set_options('std_column_visibility' => 1,
 353                        'title'                 => $form->{title});
 354   $report->set_export_options('show_dunning', @filter_field_list, qw(sort sortdir));
 355
 356   my %column_defs         =  (
 357     'checkbox'            => { 'text' => '', 'visible' => 'HTML' },
 358     'dunning_description' => { 'text' => $locale->text('Dunning Level') },
 359     'customername'        => { 'text' => $locale->text('Customername') },
 360     'language'            => { 'text' => $locale->text('Language') },
 361     'invnumber'           => { 'text' => $locale->text('Invnumber') },
 362     'transdate'           => { 'text' => $locale->text('Invdate') },
 363     'duedate'             => { 'text' => $locale->text('Invoice Duedate') },
 364     'amount'              => { 'text' => $locale->text('Amount') },
 365     'dunning_date'        => { 'text' => $locale->text('Dunning Date') },
 366     'dunning_duedate'     => { 'text' => $locale->text('Dunning Duedate') },
 367     'fee'                 => { 'text' => $locale->text('Total Fees') },
 368     'interest'            => { 'text' => $locale->text('Interest') },
 369     'salesman'            => { 'text' => $locale->text('Salesperson'), 'visible' => $form->{l_salesman} ? 1 : 0 },
 370   );
 371
 372   $report->set_columns(%column_defs);
 373   $report->set_column_order(qw(checkbox dunning_description customername language invnumber transdate
 374                                duedate amount dunning_date dunning_duedate fee interest salesman));
 375   $report->set_sort_indicator($form->{sort}, $form->{sortdir});
 376
 377   my $edit_url  = sub { build_std_url('script=' . ($_[0]->{invoice} ? 'is' : 'ar') . '.pl', 'action=edit', 'callback') . '&id=' . $::form->escape($_[0]->{id}) };
 378   my $print_url = sub { build_std_url('action=print_dunning', 'format=pdf', 'media=screen', 'dunning_id='.$_[0]->{dunning_id}, 'language_id=' . $_[0]->{language_id}) };
 379   my $sort_url  = build_std_url('action=show_dunning', grep { $form->{$_} } @filter_field_list);
 380
 381   foreach my $name (qw(dunning_description customername invnumber transdate duedate dunning_date dunning_duedate salesman)) {
 382     my $sortdir                 = $form->{sort} eq $name ? 1 - $form->{sortdir} : $form->{sortdir};
 383     $column_defs{$name}->{link} = $sort_url . "&sort=$name&sortdir=$sortdir";
 384   }
 385
 386   my %alignment = map { $_ => 'right' } qw(transdate duedate amount dunning_date dunning_duedate fee interest salesman);
 387
 388   my ($current_dunning_rows, $previous_dunning_id, $first_row_for_dunning);
 389
 390   $current_dunning_rows  = [];
 391   $first_row_for_dunning = 1;
 392   $form->{rowcount}      = scalar @{ $form->{DUNNINGS} };
 393
 394   my $i = 0;
 395
 396   foreach my $ref (@{ $form->{DUNNINGS} }) {
 397     $i++;
 398
 399     if ($previous_dunning_id != $ref->{dunning_id}) {
 400       $report->add_data($current_dunning_rows) if (scalar @{ $current_dunning_rows });
 401       $current_dunning_rows  = [];
 402       $first_row_for_dunning = 1;
 403     }
 404
 405     if ($ref->{'language_id'}) {
 406       $ref->{language} = SL::DB::Manager::Language->find_by('id' => $ref->{'language_id'})->{'description'};
 407     }
 408
 409     my $row = { };
 410     foreach my $column (keys %{ $ref }) {
 411       $row->{$column} = {
 412         'data'  => $first_row_for_dunning || (($column ne 'dunning_description') && ($column ne 'customername')) ? $ref->{$column} : '',
 413
 414         'align' => $alignment{$column},
 415
 416         'link'  => (  $column eq 'invnumber'           ? $edit_url->($ref)
 417                     : $column eq 'dunning_description' ? $print_url->($ref)
 418                     :                                    ''),
 419       };
 420     }
 421
 422     $row->{checkbox} = !$first_row_for_dunning ? { } : {
 423       'raw_data' =>   $cgi->hidden('-name' => "dunning_id_$i", '-value' => $ref->{dunning_id})
 424                     . $cgi->checkbox('-name' => "selected_$i", '-value' => 1, '-label' => ''),
 425       'valign'   => 'center',
 426       'align'    => 'center',
 427     };
 428
 429     if ($first_row_for_dunning) {
 430       $row->{language} = {'raw_data' => $cgi->hidden('-name' => "language_id_$i", '-value' => $ref->{language_id})
 431                                         . " $ref->{language}" };
 432     } else {
 433       $row->{language} = { };
 434     }
 435
 436     push @{ $current_dunning_rows }, $row;
 437
 438     $previous_dunning_id   = $ref->{dunning_id};
 439     $first_row_for_dunning = 0;
 440   }
 441
 442   $report->add_data($current_dunning_rows) if (scalar @{ $current_dunning_rows });
 443
 444   $report->set_options('raw_top_info_text'    => $form->parse_html_template('dunning/show_dunning_top'),
 445                        'raw_bottom_info_text' => $form->parse_html_template('dunning/show_dunning_bottom'),
 446                        'output_format'        => 'HTML',
 447                        'attachment_basename'  => $locale->text('dunning_list') . strftime('_%Y%m%d', localtime time),
 448     );
 449
 450   $report->set_options_from_form();
 451
 452   $report->generate_with_headers();
 453
 454   $main::lxdebug->leave_sub();
 455
 456 }
 457
 458 sub print_dunning {
 459   $main::lxdebug->enter_sub();
 460
 461   my $form     = $main::form;
 462
 463   $main::auth->assert('dunning_edit');
 464
 465   $form->{rowcount}     = 1;
 466   $form->{selected_1}   = 1;
 467   $form->{dunning_id_1} = $form->{dunning_id};
 468   $form->{language_id_1} = $form->{language_id};
 469
 470   print_multiple();
 471
 472   $main::lxdebug->leave_sub();
 473 }
 474
 475 sub print_multiple {
 476   $main::lxdebug->enter_sub();
 477
 478   my $form     = $main::form;
 479   my %myconfig = %main::myconfig;
 480   my $locale   = $main::locale;
 481
 482   $main::auth->assert('dunning_edit');
 483
 484   $form->{title} = $locale->text('Print dunnings');
 485
 486   my @dunning_ids = map { $form->{"dunning_id_$_"} } grep { $form->{"selected_$_"} } (1..$form->{rowcount});
 487   my @language_ids = map { $form->{"language_id_$_"} } grep { $form->{"selected_$_"} } (1..$form->{rowcount});
 488
 489   if (!scalar @dunning_ids) {
 490     $form->error($locale->text('No dunnings have been selected for printing.'));
 491   }
 492
 493   $form->{DUNNING_PDFS} = [];
 494
 495   my $saved_language_id = $form->{language_id};
 496   my $i = 0;
 497   foreach my $dunning_id (@dunning_ids) {
 498     if (!$form->{force_lang}) {
 499       $form->{language_id} = $language_ids[$i];
 500     }
 501     DN->print_invoice_for_fees(\%myconfig, $form, $dunning_id);
 502     DN->print_dunning(\%myconfig, $form, $dunning_id);
 503     $i++;
 504   }
 505   $form->{language_id} = $saved_language_id;
 506
 507   if (scalar @{ $form->{DUNNING_PDFS} }) {
 508     $form->{dunning_id} = strftime("%Y%m%d", localtime time);
 509     DN->melt_pdfs(\%myconfig, $form, $form->{copies});
 510
 511     if ($form->{media} eq 'printer') {
 512       $form->header();
 513       $form->info($locale->text('The dunnings have been printed.'));
 514     }
 515
 516   } else {
 517     $form->redirect($locale->text('Could not print dunning.'));
 518   }
 519
 520   $main::lxdebug->leave_sub();
 521 }
 522
 523 sub continue {
 524   call_sub($main::form->{nextsub});
 525 }
 526
 527 # end of main