SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::HTML::Util;
   8 use SL::Presenter::Tag qw(select_tag hidden_tag div_tag);
   9 use SL::Locale::String qw(t8);
  10 use SL::SessionFile::Random;
  11 use SL::PriceSource;
  12 use SL::Webdav;
  13 use SL::File;
  14 use SL::MIME;
  15 use SL::Util qw(trim);
  16 use SL::YAML;
  17 use SL::DB::AdditionalBillingAddress;
  18 use SL::DB::AuthUser;
  19 use SL::DB::History;
  20 use SL::DB::Order;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Part;
  24 use SL::DB::PartClassification;
  25 use SL::DB::PartsGroup;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28 use SL::DB::RecordLink;
  29 use SL::DB::RequirementSpec;
  30 use SL::DB::Shipto;
  31 use SL::DB::Translation;
  32
  33 use SL::Helper::CreatePDF qw(:all);
  34 use SL::Helper::PrintOptions;
  35 use SL::Helper::ShippedQty;
  36 use SL::Helper::UserPreferences::PositionsScrollbar;
  37 use SL::Helper::UserPreferences::UpdatePositions;
  38
  39 use SL::Controller::Helper::GetModels;
  40
  41 use List::Util qw(first sum0);
  42 use List::UtilsBy qw(sort_by uniq_by);
  43 use List::MoreUtils qw(any none pairwise first_index);
  44 use English qw(-no_match_vars);
  45 use File::Spec;
  46 use Cwd;
  47 use Sort::Naturally;
  48
  49 use Rose::Object::MakeMethods::Generic
  50 (
  51  scalar => [ qw(item_ids_to_delete is_custom_shipto_to_delete) ],
  52  'scalar --get_set_init' => [ qw(order valid_types type cv p all_price_factors search_cvpartnumber show_update_button part_picker_classification_ids) ],
  53 );
  54
  55
  56 # safety
  57 __PACKAGE__->run_before('check_auth');
  58
  59 __PACKAGE__->run_before('check_auth_for_edit',
  60                         except => [ qw(edit show_customer_vendor_details_dialog price_popup load_second_rows) ]);
  61
  62 __PACKAGE__->run_before('recalc',
  63                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  64                                      print send_email) ]);
  65
  66 __PACKAGE__->run_before('get_unalterable_data',
  67                         only => [ qw(save save_as_new save_and_delivery_order save_and_invoice save_and_invoice_for_advance_payment save_and_final_invoice save_and_ap_transaction
  68                                      print send_email) ]);
  69
  70 #
  71 # actions
  72 #
  73
  74 # add a new order
  75 sub action_add {
  76   my ($self) = @_;
  77
  78   $self->order->transdate(DateTime->now_local());
  79   my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
  80                    $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
  81
  82   if (   ($self->type eq sales_order_type()     &&  $::instance_conf->get_deliverydate_on)
  83       || ($self->type eq sales_quotation_type() &&  $::instance_conf->get_reqdate_on)
  84       && (!$self->order->reqdate)) {
  85     $self->order->reqdate(DateTime->today_local->next_workday(extra_days => $extra_days));
  86   }
  87
  88
  89   $self->pre_render();
  90   $self->render(
  91     'order/form',
  92     title => $self->get_title_for('add'),
  93     %{$self->{template_args}}
  94   );
  95 }
  96
  97 # edit an existing order
  98 sub action_edit {
  99   my ($self) = @_;
 100
 101   if ($::form->{id}) {
 102     $self->load_order;
 103
 104   } else {
 105     # this is to edit an order from an unsaved order object
 106
 107     # set item ids to new fake id, to identify them as new items
 108     foreach my $item (@{$self->order->items_sorted}) {
 109       $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 110     }
 111     # trigger rendering values for second row as hidden, because they
 112     # are loaded only on demand. So we need to keep the values from
 113     # the source.
 114     $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
 115   }
 116
 117   $self->recalc();
 118   $self->pre_render();
 119   $self->render(
 120     'order/form',
 121     title => $self->get_title_for('edit'),
 122     %{$self->{template_args}}
 123   );
 124 }
 125
 126 # edit a collective order (consisting of one or more existing orders)
 127 sub action_edit_collective {
 128   my ($self) = @_;
 129
 130   # collect order ids
 131   my @multi_ids = map {
 132     $_ =~ m{^multi_id_(\d+)$} && $::form->{'multi_id_' . $1} && $::form->{'trans_id_' . $1} && $::form->{'trans_id_' . $1}
 133   } grep { $_ =~ m{^multi_id_\d+$} } keys %$::form;
 134
 135   # fall back to add if no ids are given
 136   if (scalar @multi_ids == 0) {
 137     $self->action_add();
 138     return;
 139   }
 140
 141   # fall back to save as new if only one id is given
 142   if (scalar @multi_ids == 1) {
 143     $self->order(SL::DB::Order->new(id => $multi_ids[0])->load);
 144     $self->action_save_as_new();
 145     return;
 146   }
 147
 148   # make new order from given orders
 149   my @multi_orders = map { SL::DB::Order->new(id => $_)->load } @multi_ids;
 150   $self->{converted_from_oe_id} = join ' ', map { $_->id } @multi_orders;
 151   $self->order(SL::DB::Order->new_from_multi(\@multi_orders, sort_sources_by => 'transdate'));
 152
 153   $self->action_edit();
 154 }
 155
 156 # delete the order
 157 sub action_delete {
 158   my ($self) = @_;
 159
 160   my $errors = $self->delete();
 161
 162   if (scalar @{ $errors }) {
 163     $self->js->flash('error', $_) foreach @{ $errors };
 164     return $self->js->render();
 165   }
 166
 167   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been deleted')
 168            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been deleted')
 169            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been deleted')
 170            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been deleted')
 171            : '';
 172   flash_later('info', $text);
 173
 174   my @redirect_params = (
 175     action => 'add',
 176     type   => $self->type,
 177   );
 178
 179   $self->redirect_to(@redirect_params);
 180 }
 181
 182 # save the order
 183 sub action_save {
 184   my ($self) = @_;
 185
 186   my $errors = $self->save();
 187
 188   if (scalar @{ $errors }) {
 189     $self->js->flash('error', $_) foreach @{ $errors };
 190     return $self->js->render();
 191   }
 192
 193   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
 194            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
 195            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
 196            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
 197            : '';
 198   flash_later('info', $text);
 199
 200   my @redirect_params;
 201   if ($::form->{back_to_caller}) {
 202     @redirect_params = $::form->{callback} ? ($::form->{callback})
 203                                            : (controller => 'LoginScreen', action => 'user_login');
 204
 205   } else {
 206     @redirect_params = (
 207       action   => 'edit',
 208       type     => $self->type,
 209       id       => $self->order->id,
 210       callback => $::form->{callback},
 211     );
 212   }
 213
 214   $self->redirect_to(@redirect_params);
 215 }
 216
 217 # save the order as new document an open it for edit
 218 sub action_save_as_new {
 219   my ($self) = @_;
 220
 221   my $order = $self->order;
 222
 223   if (!$order->id) {
 224     $self->js->flash('error', t8('This object has not been saved yet.'));
 225     return $self->js->render();
 226   }
 227
 228   # load order from db to check if values changed
 229   my $saved_order = SL::DB::Order->new(id => $order->id)->load;
 230
 231   my %new_attrs;
 232   # Lets assign a new number if the user hasn't changed the previous one.
 233   # If it has been changed manually then use it as-is.
 234   $new_attrs{number}    = (trim($order->number) eq $saved_order->number)
 235                         ? ''
 236                         : trim($order->number);
 237
 238   # Clear transdate unless changed
 239   $new_attrs{transdate} = ($order->transdate == $saved_order->transdate)
 240                         ? DateTime->today_local
 241                         : $order->transdate;
 242
 243   # Set new reqdate unless changed if it is enabled in client config
 244   if ($order->reqdate == $saved_order->reqdate) {
 245     my $extra_days = $self->type eq sales_quotation_type() ? $::instance_conf->get_reqdate_interval       :
 246                      $self->type eq sales_order_type()     ? $::instance_conf->get_delivery_date_interval : 1;
 247
 248     if (   ($self->type eq sales_order_type()     &&  !$::instance_conf->get_deliverydate_on)
 249         || ($self->type eq sales_quotation_type() &&  !$::instance_conf->get_reqdate_on)) {
 250       $new_attrs{reqdate} = '';
 251     } else {
 252       $new_attrs{reqdate} = DateTime->today_local->next_workday(extra_days => $extra_days);
 253     }
 254   } else {
 255     $new_attrs{reqdate} = $order->reqdate;
 256   }
 257
 258   # Update employee
 259   $new_attrs{employee}  = SL::DB::Manager::Employee->current;
 260
 261   # Create new record from current one
 262   $self->order(SL::DB::Order->new_from($order, destination_type => $order->type, attributes => \%new_attrs));
 263
 264   # no linked records on save as new
 265   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
 266
 267   # save
 268   $self->action_save();
 269 }
 270
 271 # print the order
 272 #
 273 # This is called if "print" is pressed in the print dialog.
 274 # If PDF creation was requested and succeeded, the pdf is offered for download
 275 # via send_file (which uses ajax in this case).
 276 sub action_print {
 277   my ($self) = @_;
 278
 279   my $errors = $self->save();
 280
 281   if (scalar @{ $errors }) {
 282     $self->js->flash('error', $_) foreach @{ $errors };
 283     return $self->js->render();
 284   }
 285
 286   $self->js_reset_order_and_item_ids_after_save;
 287
 288   my $format      = $::form->{print_options}->{format};
 289   my $media       = $::form->{print_options}->{media};
 290   my $formname    = $::form->{print_options}->{formname};
 291   my $copies      = $::form->{print_options}->{copies};
 292   my $groupitems  = $::form->{print_options}->{groupitems};
 293   my $printer_id  = $::form->{print_options}->{printer_id};
 294
 295   # only PDF, OpenDocument & HTML for now
 296   if (none { $format eq $_ } qw(pdf opendocument opendocument_pdf html)) {
 297     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 298   }
 299
 300   # only screen or printer by now
 301   if (none { $media eq $_ } qw(screen printer)) {
 302     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 303   }
 304
 305   # create a form for generate_attachment_filename
 306   my $form   = Form->new;
 307   $form->{$self->nr_key()}  = $self->order->number;
 308   $form->{type}             = $self->type;
 309   $form->{format}           = $format;
 310   $form->{formname}         = $formname;
 311   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 312   my $doc_filename          = $form->generate_attachment_filename();
 313
 314   my $doc;
 315   my @errors = $self->generate_doc(\$doc, { media      => $media,
 316                                             format     => $format,
 317                                             formname   => $formname,
 318                                             language   => $self->order->language,
 319                                             printer_id => $printer_id,
 320                                             groupitems => $groupitems });
 321   if (scalar @errors) {
 322     return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render;
 323   }
 324
 325   if ($media eq 'screen') {
 326     # screen/download
 327     $self->js->flash('info', t8('The document has been created.'));
 328     $self->send_file(
 329       \$doc,
 330       type         => SL::MIME->mime_type_from_ext($doc_filename),
 331       name         => $doc_filename,
 332       js_no_render => 1,
 333     );
 334
 335   } elsif ($media eq 'printer') {
 336     # printer
 337     my $printer_id = $::form->{print_options}->{printer_id};
 338     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 339       copies  => $copies,
 340       content => $doc,
 341     );
 342
 343     $self->js->flash('info', t8('The document has been printed.'));
 344   }
 345
 346   my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $doc_filename, $formname);
 347   if (scalar @warnings) {
 348     $self->js->flash('warning', $_) for @warnings;
 349   }
 350
 351   $self->save_history('PRINTED');
 352
 353   $self->js
 354     ->run('kivi.ActionBar.setEnabled', '#save_and_email_action')
 355     ->render;
 356 }
 357 sub action_preview_pdf {
 358   my ($self) = @_;
 359
 360   my $errors = $self->save();
 361   if (scalar @{ $errors }) {
 362     $self->js->flash('error', $_) foreach @{ $errors };
 363     return $self->js->render();
 364   }
 365
 366   $self->js_reset_order_and_item_ids_after_save;
 367
 368   my $format      = 'pdf';
 369   my $media       = 'screen';
 370   my $formname    = $self->type;
 371
 372   # only pdf
 373   # create a form for generate_attachment_filename
 374   my $form   = Form->new;
 375   $form->{$self->nr_key()}  = $self->order->number;
 376   $form->{type}             = $self->type;
 377   $form->{format}           = $format;
 378   $form->{formname}         = $formname;
 379   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 380   my $pdf_filename          = $form->generate_attachment_filename();
 381
 382   my $pdf;
 383   my @errors = $self->generate_doc(\$pdf, { media      => $media,
 384                                             format     => $format,
 385                                             formname   => $formname,
 386                                             language   => $self->order->language,
 387                                           });
 388   if (scalar @errors) {
 389     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 390   }
 391   $self->save_history('PREVIEWED');
 392   $self->js->flash('info', t8('The PDF has been previewed'));
 393   # screen/download
 394   $self->send_file(
 395     \$pdf,
 396     type         => SL::MIME->mime_type_from_ext($pdf_filename),
 397     name         => $pdf_filename,
 398     js_no_render => 0,
 399   );
 400 }
 401
 402 # open the email dialog
 403 sub action_save_and_show_email_dialog {
 404   my ($self) = @_;
 405
 406   my $errors = $self->save();
 407
 408   if (scalar @{ $errors }) {
 409     $self->js->flash('error', $_) foreach @{ $errors };
 410     return $self->js->render();
 411   }
 412
 413   my $cv_method = $self->cv;
 414
 415   if (!$self->order->$cv_method) {
 416     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 417                     ->render($self);
 418   }
 419
 420   my $email_form;
 421   $email_form->{to}   = $self->order->contact->cp_email if $self->order->contact;
 422   $email_form->{to} ||= $self->order->$cv_method->email;
 423   $email_form->{cc}   = $self->order->$cv_method->cc;
 424   $email_form->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 425   # Todo: get addresses from shipto, if any
 426
 427   my $form = Form->new;
 428   $form->{$self->nr_key()}  = $self->order->number;
 429   $form->{cusordnumber}     = $self->order->cusordnumber;
 430   $form->{formname}         = $self->type;
 431   $form->{type}             = $self->type;
 432   $form->{language}         = '_' . $self->order->language->template_code if $self->order->language;
 433   $form->{language_id}      = $self->order->language->id                  if $self->order->language;
 434   $form->{format}           = 'pdf';
 435   $form->{cp_id}            = $self->order->contact->cp_id if $self->order->contact;
 436
 437   $email_form->{subject}             = $form->generate_email_subject();
 438   $email_form->{attachment_filename} = $form->generate_attachment_filename();
 439   $email_form->{message}             = $form->generate_email_body();
 440   $email_form->{js_send_function}    = 'kivi.Order.send_email()';
 441
 442   my %files = $self->get_files_for_email_dialog();
 443
 444   my @employees_with_email = grep {
 445     my $user = SL::DB::Manager::AuthUser->find_by(login => $_->login);
 446     $user && !!trim($user->get_config_value('email'));
 447   } @{ SL::DB::Manager::Employee->get_all_sorted(query => [ deleted => 0 ]) };
 448
 449   my $dialog_html = $self->render('common/_send_email_dialog', { output => 0 },
 450                                   email_form    => $email_form,
 451                                   show_bcc      => $::auth->assert('email_bcc', 'may fail'),
 452                                   FILES         => \%files,
 453                                   is_customer   => $self->cv eq 'customer',
 454                                   ALL_EMPLOYEES => \@employees_with_email,
 455   );
 456
 457   $self->js
 458       ->run('kivi.Order.show_email_dialog', $dialog_html)
 459       ->reinit_widgets
 460       ->render($self);
 461 }
 462
 463 # send email
 464 #
 465 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 466 sub action_send_email {
 467   my ($self) = @_;
 468
 469   my $errors = $self->save();
 470
 471   if (scalar @{ $errors }) {
 472     $self->js->run('kivi.Order.close_email_dialog');
 473     $self->js->flash('error', $_) foreach @{ $errors };
 474     return $self->js->render();
 475   }
 476
 477   $self->js_reset_order_and_item_ids_after_save;
 478
 479   my $email_form  = delete $::form->{email_form};
 480   my %field_names = (to => 'email');
 481
 482   $::form->{ $field_names{$_} // $_ } = $email_form->{$_} for keys %{ $email_form };
 483
 484   # for Form::cleanup which may be called in Form::send_email
 485   $::form->{cwd}    = getcwd();
 486   $::form->{tmpdir} = $::lx_office_conf{paths}->{userspath};
 487
 488   $::form->{$_}     = $::form->{print_options}->{$_} for keys %{ $::form->{print_options} };
 489   $::form->{media}  = 'email';
 490
 491   $::form->{attachment_policy} //= '';
 492
 493   # Is an old file version available?
 494   my $attfile;
 495   if ($::form->{attachment_policy} eq 'old_file') {
 496     $attfile = SL::File->get_all(object_id     => $self->order->id,
 497                                  object_type   => $self->type,
 498                                  file_type     => 'document',
 499                                  print_variant => $::form->{formname});
 500   }
 501
 502   if ($::form->{attachment_policy} ne 'no_file' && !($::form->{attachment_policy} eq 'old_file' && $attfile)) {
 503     my $doc;
 504     my @errors = $self->generate_doc(\$doc, {media      => $::form->{media},
 505                                              format     => $::form->{print_options}->{format},
 506                                              formname   => $::form->{print_options}->{formname},
 507                                              language   => $self->order->language,
 508                                              printer_id => $::form->{print_options}->{printer_id},
 509                                              groupitems => $::form->{print_options}->{groupitems}});
 510     if (scalar @errors) {
 511       return $self->js->flash('error', t8('Generating the document failed: #1', $errors[0]))->render($self);
 512     }
 513
 514     my @warnings = $self->store_doc_to_webdav_and_filemanagement($doc, $::form->{attachment_filename}, $::form->{formname});
 515     if (scalar @warnings) {
 516       flash_later('warning', $_) for @warnings;
 517     }
 518
 519     my $sfile = SL::SessionFile::Random->new(mode => "w");
 520     $sfile->fh->print($doc);
 521     $sfile->fh->close;
 522
 523     $::form->{tmpfile} = $sfile->file_name;
 524     $::form->{tmpdir}  = $sfile->get_path; # for Form::cleanup which may be called in Form::send_email
 525   }
 526
 527   $::form->{id} = $self->order->id; # this is used in SL::Mailer to create a linked record to the mail
 528   $::form->send_email(\%::myconfig, $::form->{print_options}->{format});
 529
 530   # internal notes unless no email journal
 531   unless ($::instance_conf->get_email_journal) {
 532     my $intnotes = $self->order->intnotes;
 533     $intnotes   .= "\n\n" if $self->order->intnotes;
 534     $intnotes   .= t8('[email]')                                                                                        . "\n";
 535     $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 536     $intnotes   .= t8('To (email)') . ": " . $::form->{email}                                                           . "\n";
 537     $intnotes   .= t8('Cc')         . ": " . $::form->{cc}                                                              . "\n"    if $::form->{cc};
 538     $intnotes   .= t8('Bcc')        . ": " . $::form->{bcc}                                                             . "\n"    if $::form->{bcc};
 539     $intnotes   .= t8('Subject')    . ": " . $::form->{subject}                                                         . "\n\n";
 540     $intnotes   .= t8('Message')    . ": " . SL::HTML::Util->strip($::form->{message});
 541
 542     $self->order->update_attributes(intnotes => $intnotes);
 543   }
 544
 545   $self->save_history('MAILED');
 546
 547   flash_later('info', t8('The email has been sent.'));
 548
 549   my @redirect_params = (
 550     action => 'edit',
 551     type   => $self->type,
 552     id     => $self->order->id,
 553   );
 554
 555   $self->redirect_to(@redirect_params);
 556 }
 557
 558 # open the periodic invoices config dialog
 559 #
 560 # If there are values in the form (i.e. dialog was opened before),
 561 # then use this values. Create new ones, else.
 562 sub action_show_periodic_invoices_config_dialog {
 563   my ($self) = @_;
 564
 565   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 566   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 567   $config  ||= SL::DB::PeriodicInvoicesConfig->new(periodicity             => 'm',
 568                                                    order_value_periodicity => 'p', # = same as periodicity
 569                                                    start_date_as_date      => $::form->{transdate_as_date} || $::form->current_date,
 570                                                    extend_automatically_by => 12,
 571                                                    active                  => 1,
 572                                                    email_subject           => GenericTranslations->get(
 573                                                                                 language_id      => $::form->{language_id},
 574                                                                                 translation_type =>"preset_text_periodic_invoices_email_subject"),
 575                                                    email_body              => GenericTranslations->get(
 576                                                                                 language_id      => $::form->{language_id},
 577                                                                                 translation_type => "salutation_general")
 578                                                                             . GenericTranslations->get(
 579                                                                                 language_id      => $::form->{language_id},
 580                                                                                 translation_type => "salutation_punctuation_mark") . "\n\n"
 581                                                                             . GenericTranslations->get(
 582                                                                                 language_id      => $::form->{language_id},
 583                                                                                 translation_type =>"preset_text_periodic_invoices_email_body"),
 584   );
 585   # for older configs, replace email preset text if not yet set.
 586   $config->email_subject(GenericTranslations->get(
 587                                               language_id      => $::form->{language_id},
 588                                               translation_type =>"preset_text_periodic_invoices_email_subject")
 589                         ) unless $config->email_subject;
 590
 591   $config->email_body(GenericTranslations->get(
 592                                               language_id      => $::form->{language_id},
 593                                               translation_type => "salutation_general")
 594                     . GenericTranslations->get(
 595                                               language_id      => $::form->{language_id},
 596                                               translation_type => "salutation_punctuation_mark") . "\n\n"
 597                     . GenericTranslations->get(
 598                                               language_id      => $::form->{language_id},
 599                                               translation_type =>"preset_text_periodic_invoices_email_body")
 600                      ) unless $config->email_body;
 601
 602   $config->periodicity('m')             if none { $_ eq $config->periodicity             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES;
 603   $config->order_value_periodicity('p') if none { $_ eq $config->order_value_periodicity } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES);
 604
 605   $::form->get_lists(printers => "ALL_PRINTERS",
 606                      charts   => { key       => 'ALL_CHARTS',
 607                                    transdate => 'current_date' });
 608
 609   $::form->{AR} = [ grep { $_->{link} =~ m/(?:^|:)AR(?::|$)/ } @{ $::form->{ALL_CHARTS} } ];
 610
 611   if ($::form->{customer_id}) {
 612     $::form->{ALL_CONTACTS} = SL::DB::Manager::Contact->get_all_sorted(where => [ cp_cv_id => $::form->{customer_id} ]);
 613     my $customer_object = SL::DB::Manager::Customer->find_by(id => $::form->{customer_id});
 614     $::form->{postal_invoice}                  = $customer_object->postal_invoice;
 615     $::form->{email_recipient_invoice_address} = $::form->{postal_invoice} ? '' : $customer_object->invoice_mail;
 616     $config->send_email(0) if $::form->{postal_invoice};
 617   }
 618
 619   $self->render('oe/edit_periodic_invoices_config', { layout => 0 },
 620                 popup_dialog             => 1,
 621                 popup_js_close_function  => 'kivi.Order.close_periodic_invoices_config_dialog()',
 622                 popup_js_assign_function => 'kivi.Order.assign_periodic_invoices_config()',
 623                 config                   => $config,
 624                 %$::form);
 625 }
 626
 627 # assign the values of the periodic invoices config dialog
 628 # as yaml in the hidden tag and set the status.
 629 sub action_assign_periodic_invoices_config {
 630   my ($self) = @_;
 631
 632   $::form->isblank('start_date_as_date', $::locale->text('The start date is missing.'));
 633
 634   my $config = { active                     => $::form->{active}       ? 1 : 0,
 635                  terminated                 => $::form->{terminated}   ? 1 : 0,
 636                  direct_debit               => $::form->{direct_debit} ? 1 : 0,
 637                  periodicity                => (any { $_ eq $::form->{periodicity}             }       @SL::DB::PeriodicInvoicesConfig::PERIODICITIES)              ? $::form->{periodicity}             : 'm',
 638                  order_value_periodicity    => (any { $_ eq $::form->{order_value_periodicity} } ('p', @SL::DB::PeriodicInvoicesConfig::ORDER_VALUE_PERIODICITIES)) ? $::form->{order_value_periodicity} : 'p',
 639                  start_date_as_date         => $::form->{start_date_as_date},
 640                  end_date_as_date           => $::form->{end_date_as_date},
 641                  first_billing_date_as_date => $::form->{first_billing_date_as_date},
 642                  print                      => $::form->{print}      ? 1                         : 0,
 643                  printer_id                 => $::form->{print}      ? $::form->{printer_id} * 1 : undef,
 644                  copies                     => $::form->{copies} * 1 ? $::form->{copies}         : 1,
 645                  extend_automatically_by    => $::form->{extend_automatically_by}    * 1 || undef,
 646                  ar_chart_id                => $::form->{ar_chart_id} * 1,
 647                  send_email                 => $::form->{send_email} ? 1 : 0,
 648                  email_recipient_contact_id => $::form->{email_recipient_contact_id} * 1 || undef,
 649                  email_recipient_address    => $::form->{email_recipient_address},
 650                  email_sender               => $::form->{email_sender},
 651                  email_subject              => $::form->{email_subject},
 652                  email_body                 => $::form->{email_body},
 653                };
 654
 655   my $periodic_invoices_config = SL::YAML::Dump($config);
 656
 657   my $status = $self->get_periodic_invoices_status($config);
 658
 659   $self->js
 660     ->remove('#order_periodic_invoices_config')
 661     ->insertAfter(hidden_tag('order.periodic_invoices_config', $periodic_invoices_config), '#periodic_invoices_status')
 662     ->run('kivi.Order.close_periodic_invoices_config_dialog')
 663     ->html('#periodic_invoices_status', $status)
 664     ->flash('info', t8('The periodic invoices config has been assigned.'))
 665     ->render($self);
 666 }
 667
 668 sub action_get_has_active_periodic_invoices {
 669   my ($self) = @_;
 670
 671   my $config = make_periodic_invoices_config_from_yaml(delete $::form->{config});
 672   $config  ||= SL::DB::Manager::PeriodicInvoicesConfig->find_by(oe_id => $::form->{id}) if $::form->{id};
 673
 674   my $has_active_periodic_invoices =
 675        $self->type eq sales_order_type()
 676     && $config
 677     && $config->active
 678     && (!$config->end_date || ($config->end_date > DateTime->today_local))
 679     && $config->get_previous_billed_period_start_date;
 680
 681   $_[0]->render(\ !!$has_active_periodic_invoices, { type => 'text' });
 682 }
 683
 684 # save the order and redirect to the frontend subroutine for a new
 685 # delivery order
 686 sub action_save_and_delivery_order {
 687   my ($self) = @_;
 688
 689   $self->save_and_redirect_to(
 690     controller => 'oe.pl',
 691     action     => 'oe_delivery_order_from_order',
 692   );
 693 }
 694
 695 sub action_save_and_supplier_delivery_order {
 696   my ($self) = @_;
 697
 698   $self->save_and_redirect_to(
 699     controller => 'controller.pl',
 700     action     => 'DeliveryOrder/add_from_order',
 701     type       => 'supplier_delivery_order',
 702   );
 703 }
 704
 705 # save the order and redirect to the frontend subroutine for a new
 706 # invoice
 707 sub action_save_and_invoice {
 708   my ($self) = @_;
 709
 710   $self->save_and_redirect_to(
 711     controller => 'oe.pl',
 712     action     => 'oe_invoice_from_order',
 713   );
 714 }
 715
 716 sub action_save_and_invoice_for_advance_payment {
 717   my ($self) = @_;
 718
 719   $self->save_and_redirect_to(
 720     controller       => 'oe.pl',
 721     action           => 'oe_invoice_from_order',
 722     new_invoice_type => 'invoice_for_advance_payment',
 723   );
 724 }
 725
 726 sub action_save_and_final_invoice {
 727   my ($self) = @_;
 728
 729   $self->save_and_redirect_to(
 730     controller       => 'oe.pl',
 731     action           => 'oe_invoice_from_order',
 732     new_invoice_type => 'final_invoice',
 733   );
 734 }
 735
 736 # workflow from sales order to sales quotation
 737 sub action_sales_quotation {
 738   $_[0]->workflow_sales_or_request_for_quotation();
 739 }
 740
 741 # workflow from sales order to sales quotation
 742 sub action_request_for_quotation {
 743   $_[0]->workflow_sales_or_request_for_quotation();
 744 }
 745
 746 # workflow from sales quotation to sales order
 747 sub action_sales_order {
 748   $_[0]->workflow_sales_or_purchase_order();
 749 }
 750
 751 # workflow from rfq to purchase order
 752 sub action_purchase_order {
 753   $_[0]->workflow_sales_or_purchase_order();
 754 }
 755
 756 # workflow from purchase order to ap transaction
 757 sub action_save_and_ap_transaction {
 758   my ($self) = @_;
 759
 760   $self->save_and_redirect_to(
 761     controller => 'ap.pl',
 762     action     => 'add_from_purchase_order',
 763   );
 764 }
 765
 766 # set form elements in respect to a changed customer or vendor
 767 #
 768 # This action is called on an change of the customer/vendor picker.
 769 sub action_customer_vendor_changed {
 770   my ($self) = @_;
 771
 772   setup_order_from_cv($self->order);
 773   $self->recalc();
 774
 775   my $cv_method = $self->cv;
 776
 777   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 778     $self->js->show('#cp_row');
 779   } else {
 780     $self->js->hide('#cp_row');
 781   }
 782
 783   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 784     $self->js->show('#shipto_selection');
 785   } else {
 786     $self->js->hide('#shipto_selection');
 787   }
 788
 789   if ($cv_method eq 'customer') {
 790     my $show_hide = scalar @{ $self->order->customer->additional_billing_addresses } > 0 ? 'show' : 'hide';
 791     $self->js->$show_hide('#billing_address_row');
 792   }
 793
 794   $self->js->val( '#order_salesman_id',      $self->order->salesman_id)        if $self->order->is_sales;
 795
 796   $self->js
 797     ->replaceWith('#order_cp_id',              $self->build_contact_select)
 798     ->replaceWith('#order_shipto_id',          $self->build_shipto_select)
 799     ->replaceWith('#shipto_inputs  ',          $self->build_shipto_inputs)
 800     ->replaceWith('#order_billing_address_id', $self->build_billing_address_select)
 801     ->replaceWith('#business_info_row',        $self->build_business_info_row)
 802     ->val(        '#order_taxzone_id',         $self->order->taxzone_id)
 803     ->val(        '#order_taxincluded',        $self->order->taxincluded)
 804     ->val(        '#order_currency_id',        $self->order->currency_id)
 805     ->val(        '#order_payment_id',         $self->order->payment_id)
 806     ->val(        '#order_delivery_term_id',   $self->order->delivery_term_id)
 807     ->val(        '#order_intnotes',           $self->order->intnotes)
 808     ->val(        '#order_language_id',        $self->order->$cv_method->language_id)
 809     ->focus(      '#order_' . $self->cv . '_id')
 810     ->run('kivi.Order.update_exchangerate');
 811
 812   $self->js_redisplay_amounts_and_taxes;
 813   $self->js_redisplay_cvpartnumbers;
 814   $self->js->render();
 815 }
 816
 817 # open the dialog for customer/vendor details
 818 sub action_show_customer_vendor_details_dialog {
 819   my ($self) = @_;
 820
 821   my $is_customer = 'customer' eq $::form->{vc};
 822   my $cv;
 823   if ($is_customer) {
 824     $cv = SL::DB::Customer->new(id => $::form->{vc_id})->load;
 825   } else {
 826     $cv = SL::DB::Vendor->new(id => $::form->{vc_id})->load;
 827   }
 828
 829   my %details = map { $_ => $cv->$_ } @{$cv->meta->columns};
 830   $details{discount_as_percent} = $cv->discount_as_percent;
 831   $details{creditlimt}          = $cv->creditlimit_as_number;
 832   $details{business}            = $cv->business->description      if $cv->business;
 833   $details{language}            = $cv->language_obj->description  if $cv->language_obj;
 834   $details{delivery_terms}      = $cv->delivery_term->description if $cv->delivery_term;
 835   $details{payment_terms}       = $cv->payment->description       if $cv->payment;
 836   $details{pricegroup}          = $cv->pricegroup->pricegroup     if $is_customer && $cv->pricegroup;
 837
 838   if ($is_customer) {
 839     foreach my $entry (@{ $cv->additional_billing_addresses }) {
 840       push @{ $details{ADDITIONAL_BILLING_ADDRESSES} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 841     }
 842   }
 843   foreach my $entry (@{ $cv->shipto }) {
 844     push @{ $details{SHIPTO} },   { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 845   }
 846   foreach my $entry (@{ $cv->contacts }) {
 847     push @{ $details{CONTACTS} }, { map { $_ => $entry->$_ } @{$entry->meta->columns} };
 848   }
 849
 850   $_[0]->render('common/show_vc_details', { layout => 0 },
 851                 is_customer => $is_customer,
 852                 %details);
 853
 854 }
 855
 856 # called if a unit in an existing item row is changed
 857 sub action_unit_changed {
 858   my ($self) = @_;
 859
 860   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 861   my $item = $self->order->items_sorted->[$idx];
 862
 863   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 864   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 865
 866   $self->recalc();
 867
 868   $self->js
 869     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 870   $self->js_redisplay_line_values;
 871   $self->js_redisplay_amounts_and_taxes;
 872   $self->js->render();
 873 }
 874
 875 # add an item row for a new item entered in the input row
 876 sub action_add_item {
 877   my ($self) = @_;
 878
 879   delete $::form->{add_item}->{create_part_type};
 880
 881   my $form_attr = $::form->{add_item};
 882
 883   return unless $form_attr->{parts_id};
 884
 885   my $item = new_item($self->order, $form_attr);
 886
 887   $self->order->add_items($item);
 888
 889   $self->recalc();
 890
 891   $self->get_item_cvpartnumber($item);
 892
 893   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 894   my $row_as_html = $self->p->render('order/tabs/_row',
 895                                      ITEM => $item,
 896                                      ID   => $item_id,
 897                                      SELF => $self,
 898   );
 899
 900   if ($::form->{insert_before_item_id}) {
 901     $self->js
 902       ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 903   } else {
 904     $self->js
 905       ->append('#row_table_id', $row_as_html);
 906   }
 907
 908   if ( $item->part->is_assortment ) {
 909     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 910     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 911       my $attr = { parts_id => $assortment_item->parts_id,
 912                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 913                    unit     => $assortment_item->unit,
 914                    description => $assortment_item->part->description,
 915                  };
 916       my $item = new_item($self->order, $attr);
 917
 918       # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 919       $item->discount(1) unless $assortment_item->charge;
 920
 921       $self->order->add_items( $item );
 922       $self->recalc();
 923       $self->get_item_cvpartnumber($item);
 924       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 925       my $row_as_html = $self->p->render('order/tabs/_row',
 926                                          ITEM => $item,
 927                                          ID   => $item_id,
 928                                          SELF => $self,
 929       );
 930       if ($::form->{insert_before_item_id}) {
 931         $self->js
 932           ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 933       } else {
 934         $self->js
 935           ->append('#row_table_id', $row_as_html);
 936       }
 937     };
 938   };
 939
 940   $self->js
 941     ->val('.add_item_input', '')
 942     ->run('kivi.Order.init_row_handlers')
 943     ->run('kivi.Order.renumber_positions')
 944     ->focus('#add_item_parts_id_name');
 945
 946   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
 947
 948   $self->js_redisplay_amounts_and_taxes;
 949   $self->js->render();
 950 }
 951
 952 # add item rows for multiple items at once
 953 sub action_add_multi_items {
 954   my ($self) = @_;
 955
 956   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_items} };
 957   return $self->js->render() unless scalar @form_attr;
 958
 959   my @items;
 960   foreach my $attr (@form_attr) {
 961     my $item = new_item($self->order, $attr);
 962     push @items, $item;
 963     if ( $item->part->is_assortment ) {
 964       foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 965         my $attr = { parts_id => $assortment_item->parts_id,
 966                      qty      => $assortment_item->qty * $item->qty, # TODO $form_attr->{unit}
 967                      unit     => $assortment_item->unit,
 968                      description => $assortment_item->part->description,
 969                    };
 970         my $item = new_item($self->order, $attr);
 971
 972         # set discount to 100% if item isn't supposed to be charged, overwriting any customer discount
 973         $item->discount(1) unless $assortment_item->charge;
 974         push @items, $item;
 975       }
 976     }
 977   }
 978   $self->order->add_items(@items);
 979
 980   $self->recalc();
 981
 982   foreach my $item (@items) {
 983     $self->get_item_cvpartnumber($item);
 984     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 985     my $row_as_html = $self->p->render('order/tabs/_row',
 986                                        ITEM => $item,
 987                                        ID   => $item_id,
 988                                        SELF => $self,
 989     );
 990
 991     if ($::form->{insert_before_item_id}) {
 992       $self->js
 993         ->before ('.row_entry:has(#item_' . $::form->{insert_before_item_id} . ')', $row_as_html);
 994     } else {
 995       $self->js
 996         ->append('#row_table_id', $row_as_html);
 997     }
 998   }
 999
1000   $self->js
1001     ->run('kivi.Part.close_picker_dialogs')
1002     ->run('kivi.Order.init_row_handlers')
1003     ->run('kivi.Order.renumber_positions')
1004     ->focus('#add_item_parts_id_name');
1005
1006   $self->js->run('kivi.Order.row_table_scroll_down') if !$::form->{insert_before_item_id};
1007
1008   $self->js_redisplay_amounts_and_taxes;
1009   $self->js->render();
1010 }
1011
1012 # recalculate all linetotals, amounts and taxes and redisplay them
1013 sub action_recalc_amounts_and_taxes {
1014   my ($self) = @_;
1015
1016   $self->recalc();
1017
1018   $self->js_redisplay_line_values;
1019   $self->js_redisplay_amounts_and_taxes;
1020   $self->js->render();
1021 }
1022
1023 sub action_update_exchangerate {
1024   my ($self) = @_;
1025
1026   my $data = {
1027     is_standard   => $self->order->currency_id == $::instance_conf->get_currency_id,
1028     currency_name => $self->order->currency->name,
1029     exchangerate  => $self->order->daily_exchangerate_as_null_number,
1030   };
1031
1032   $self->render(\SL::JSON::to_json($data), { type => 'json', process => 0 });
1033 }
1034
1035 # redisplay item rows if they are sorted by an attribute
1036 sub action_reorder_items {
1037   my ($self) = @_;
1038
1039   my %sort_keys = (
1040     partnumber   => sub { $_[0]->part->partnumber },
1041     description  => sub { $_[0]->description },
1042     qty          => sub { $_[0]->qty },
1043     sellprice    => sub { $_[0]->sellprice },
1044     discount     => sub { $_[0]->discount },
1045     cvpartnumber => sub { $_[0]->{cvpartnumber} },
1046   );
1047
1048   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1049
1050   my $method = $sort_keys{$::form->{order_by}};
1051   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
1052   if ($::form->{sort_dir}) {
1053     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1054       @to_sort = sort { $a->{order_by} <=> $b->{order_by} } @to_sort;
1055     } else {
1056       @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
1057     }
1058   } else {
1059     if ( $::form->{order_by} =~ m/qty|sellprice|discount/ ){
1060       @to_sort = sort { $b->{order_by} <=> $a->{order_by} } @to_sort;
1061     } else {
1062       @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
1063     }
1064   }
1065   $self->js
1066     ->run('kivi.Order.redisplay_items', \@to_sort)
1067     ->render;
1068 }
1069
1070 # show the popup to choose a price/discount source
1071 sub action_price_popup {
1072   my ($self) = @_;
1073
1074   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
1075   my $item = $self->order->items_sorted->[$idx];
1076
1077   $self->render_price_dialog($item);
1078 }
1079
1080 # save the order in a session variable and redirect to the part controller
1081 sub action_create_part {
1082   my ($self) = @_;
1083
1084   my $previousform = $::auth->save_form_in_session(non_scalars => 1);
1085
1086   my $callback     = $self->url_for(
1087     action       => 'return_from_create_part',
1088     type         => $self->type, # type is needed for check_auth on return
1089     previousform => $previousform,
1090   );
1091
1092   flash_later('info', t8('You are adding a new part while you are editing another document. You will be redirected to your document when saving the new part or aborting this form.'));
1093
1094   my @redirect_params = (
1095     controller => 'Part',
1096     action     => 'add',
1097     part_type  => $::form->{add_item}->{create_part_type},
1098     callback   => $callback,
1099     show_abort => 1,
1100   );
1101
1102   $self->redirect_to(@redirect_params);
1103 }
1104
1105 sub action_return_from_create_part {
1106   my ($self) = @_;
1107
1108   $self->{created_part} = SL::DB::Part->new(id => delete $::form->{new_parts_id})->load if $::form->{new_parts_id};
1109
1110   $::auth->restore_form_from_session(delete $::form->{previousform});
1111
1112   # set item ids to new fake id, to identify them as new items
1113   foreach my $item (@{$self->order->items_sorted}) {
1114     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1115   }
1116
1117   $self->recalc();
1118   $self->get_unalterable_data();
1119   $self->pre_render();
1120
1121   # trigger rendering values for second row/longdescription as hidden,
1122   # because they are loaded only on demand. So we need to keep the values
1123   # from the source.
1124   $_->{render_second_row}      = 1 for @{ $self->order->items_sorted };
1125   $_->{render_longdescription} = 1 for @{ $self->order->items_sorted };
1126
1127   $self->render(
1128     'order/form',
1129     title => $self->get_title_for('edit'),
1130     %{$self->{template_args}}
1131   );
1132
1133 }
1134
1135 # load the second row for one or more items
1136 #
1137 # This action gets the html code for all items second rows by rendering a template for
1138 # the second row and sets the html code via client js.
1139 sub action_load_second_rows {
1140   my ($self) = @_;
1141
1142   $self->recalc() if $self->order->is_sales; # for margin calculation
1143
1144   foreach my $item_id (@{ $::form->{item_ids} }) {
1145     my $idx  = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1146     my $item = $self->order->items_sorted->[$idx];
1147
1148     $self->js_load_second_row($item, $item_id, 0);
1149   }
1150
1151   $self->js->run('kivi.Order.init_row_handlers') if $self->order->is_sales; # for lastcosts change-callback
1152
1153   $self->js->render();
1154 }
1155
1156 # update description, notes and sellprice from master data
1157 sub action_update_row_from_master_data {
1158   my ($self) = @_;
1159
1160   foreach my $item_id (@{ $::form->{item_ids} }) {
1161     my $idx   = first_index { $_ eq $item_id } @{ $::form->{orderitem_ids} };
1162     my $item  = $self->order->items_sorted->[$idx];
1163     my $texts = get_part_texts($item->part, $self->order->language_id);
1164
1165     $item->description($texts->{description});
1166     $item->longdescription($texts->{longdescription});
1167
1168     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1169
1170     my $price_src;
1171     if ($item->part->is_assortment) {
1172     # add assortment items with price 0, as the components carry the price
1173       $price_src = $price_source->price_from_source("");
1174       $price_src->price(0);
1175     } else {
1176       $price_src = $price_source->best_price
1177                  ? $price_source->best_price
1178                  : $price_source->price_from_source("");
1179       $price_src->price($::form->round_amount($price_src->price / $self->order->exchangerate, 5)) if $self->order->exchangerate;
1180       $price_src->price(0) if !$price_source->best_price;
1181     }
1182
1183
1184     $item->sellprice($price_src->price);
1185     $item->active_price_source($price_src);
1186
1187     $self->js
1188       ->run('kivi.Order.update_sellprice', $item_id, $item->sellprice_as_number)
1189       ->html('.row_entry:has(#item_' . $item_id . ') [name = "partnumber"] a', $item->part->partnumber)
1190       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].description"]', $item->description)
1191       ->val ('.row_entry:has(#item_' . $item_id . ') [name = "order.orderitems[].longdescription"]', $item->longdescription);
1192
1193     if ($self->search_cvpartnumber) {
1194       $self->get_item_cvpartnumber($item);
1195       $self->js->html('.row_entry:has(#item_' . $item_id . ') [name = "cvpartnumber"]', $item->{cvpartnumber});
1196     }
1197   }
1198
1199   $self->recalc();
1200   $self->js_redisplay_line_values;
1201   $self->js_redisplay_amounts_and_taxes;
1202
1203   $self->js->render();
1204 }
1205
1206 sub js_load_second_row {
1207   my ($self, $item, $item_id, $do_parse) = @_;
1208
1209   if ($do_parse) {
1210     # Parse values from form (they are formated while rendering (template)).
1211     # Workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1212     # This parsing is not necessary at all, if we assure that the second row/cvars are only loaded once.
1213     foreach my $var (@{ $item->cvars_by_config }) {
1214       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1215     }
1216     $item->parse_custom_variable_values;
1217   }
1218
1219   my $row_as_html = $self->p->render('order/tabs/_second_row', ITEM => $item, TYPE => $self->type);
1220
1221   $self->js
1222     ->html('#second_row_' . $item_id, $row_as_html)
1223     ->data('#second_row_' . $item_id, 'loaded', 1);
1224 }
1225
1226 sub js_redisplay_line_values {
1227   my ($self) = @_;
1228
1229   my $is_sales = $self->order->is_sales;
1230
1231   # sales orders with margins
1232   my @data;
1233   if ($is_sales) {
1234     @data = map {
1235       [
1236        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1237        $::form->format_amount(\%::myconfig, $_->{marge_total},   2, 0),
1238        $::form->format_amount(\%::myconfig, $_->{marge_percent}, 2, 0),
1239       ]} @{ $self->order->items_sorted };
1240   } else {
1241     @data = map {
1242       [
1243        $::form->format_amount(\%::myconfig, $_->{linetotal},     2, 0),
1244       ]} @{ $self->order->items_sorted };
1245   }
1246
1247   $self->js
1248     ->run('kivi.Order.redisplay_line_values', $is_sales, \@data);
1249 }
1250
1251 sub js_redisplay_amounts_and_taxes {
1252   my ($self) = @_;
1253
1254   if (scalar @{ $self->{taxes} }) {
1255     $self->js->show('#taxincluded_row_id');
1256   } else {
1257     $self->js->hide('#taxincluded_row_id');
1258   }
1259
1260   if ($self->order->taxincluded) {
1261     $self->js->hide('#subtotal_row_id');
1262   } else {
1263     $self->js->show('#subtotal_row_id');
1264   }
1265
1266   if ($self->order->is_sales) {
1267     my $is_neg = $self->order->marge_total < 0;
1268     $self->js
1269       ->html('#marge_total_id',   $::form->format_amount(\%::myconfig, $self->order->marge_total,   2))
1270       ->html('#marge_percent_id', $::form->format_amount(\%::myconfig, $self->order->marge_percent, 2))
1271       ->action_if( $is_neg, 'addClass',    '#marge_total_id',        'plus0')
1272       ->action_if( $is_neg, 'addClass',    '#marge_percent_id',      'plus0')
1273       ->action_if( $is_neg, 'addClass',    '#marge_percent_sign_id', 'plus0')
1274       ->action_if(!$is_neg, 'removeClass', '#marge_total_id',        'plus0')
1275       ->action_if(!$is_neg, 'removeClass', '#marge_percent_id',      'plus0')
1276       ->action_if(!$is_neg, 'removeClass', '#marge_percent_sign_id', 'plus0');
1277   }
1278
1279   $self->js
1280     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
1281     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
1282     ->remove('.tax_row')
1283     ->insertBefore($self->build_tax_rows, '#amount_row_id');
1284 }
1285
1286 sub js_redisplay_cvpartnumbers {
1287   my ($self) = @_;
1288
1289   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
1290
1291   my @data = map {[$_->{cvpartnumber}]} @{ $self->order->items_sorted };
1292
1293   $self->js
1294     ->run('kivi.Order.redisplay_cvpartnumbers', \@data);
1295 }
1296
1297 sub js_reset_order_and_item_ids_after_save {
1298   my ($self) = @_;
1299
1300   $self->js
1301     ->val('#id', $self->order->id)
1302     ->val('#converted_from_oe_id', '')
1303     ->val('#order_' . $self->nr_key(), $self->order->number);
1304
1305   my $idx = 0;
1306   foreach my $form_item_id (@{ $::form->{orderitem_ids} }) {
1307     next if !$self->order->items_sorted->[$idx]->id;
1308     next if $form_item_id !~ m{^new};
1309     $self->js
1310       ->val ('[name="orderitem_ids[+]"][value="' . $form_item_id . '"]', $self->order->items_sorted->[$idx]->id)
1311       ->val ('#item_' . $form_item_id, $self->order->items_sorted->[$idx]->id)
1312       ->attr('#item_' . $form_item_id, "id", 'item_' . $self->order->items_sorted->[$idx]->id);
1313   } continue {
1314     $idx++;
1315   }
1316   $self->js->val('[name="converted_from_orderitems_ids[+]"]', '');
1317 }
1318
1319 #
1320 # helpers
1321 #
1322
1323 sub init_valid_types {
1324   [ sales_order_type(), purchase_order_type(), sales_quotation_type(), request_quotation_type() ];
1325 }
1326
1327 sub init_type {
1328   my ($self) = @_;
1329
1330   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
1331     die "Not a valid type for order";
1332   }
1333
1334   $self->type($::form->{type});
1335 }
1336
1337 sub init_cv {
1338   my ($self) = @_;
1339
1340   my $cv = (any { $self->type eq $_ } (sales_order_type(),    sales_quotation_type()))   ? 'customer'
1341          : (any { $self->type eq $_ } (purchase_order_type(), request_quotation_type())) ? 'vendor'
1342          : die "Not a valid type for order";
1343
1344   return $cv;
1345 }
1346
1347 sub init_search_cvpartnumber {
1348   my ($self) = @_;
1349
1350   my $user_prefs = SL::Helper::UserPreferences::PartPickerSearch->new();
1351   my $search_cvpartnumber;
1352   $search_cvpartnumber = !!$user_prefs->get_sales_search_customer_partnumber() if $self->cv eq 'customer';
1353   $search_cvpartnumber = !!$user_prefs->get_purchase_search_makemodel()        if $self->cv eq 'vendor';
1354
1355   return $search_cvpartnumber;
1356 }
1357
1358 sub init_show_update_button {
1359   my ($self) = @_;
1360
1361   !!SL::Helper::UserPreferences::UpdatePositions->new()->get_show_update_button();
1362 }
1363
1364 sub init_p {
1365   SL::Presenter->get;
1366 }
1367
1368 sub init_order {
1369   $_[0]->make_order;
1370 }
1371
1372 sub init_all_price_factors {
1373   SL::DB::Manager::PriceFactor->get_all;
1374 }
1375
1376 sub init_part_picker_classification_ids {
1377   my ($self)    = @_;
1378   my $attribute = 'used_for_' . ($self->type =~ m{sales} ? 'sale' : 'purchase');
1379
1380   return [ map { $_->id } @{ SL::DB::Manager::PartClassification->get_all(where => [ $attribute => 1 ]) } ];
1381 }
1382
1383 sub check_auth {
1384   my ($self) = @_;
1385
1386   my $right_for = { map { $_ => $_.'_edit' . ' | ' . $_.'_view' } @{$self->valid_types} };
1387
1388   my $right   = $right_for->{ $self->type };
1389   $right    ||= 'DOES_NOT_EXIST';
1390
1391   $::auth->assert($right);
1392 }
1393
1394 sub check_auth_for_edit {
1395   my ($self) = @_;
1396
1397   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
1398
1399   my $right   = $right_for->{ $self->type };
1400   $right    ||= 'DOES_NOT_EXIST';
1401
1402   $::auth->assert($right);
1403 }
1404
1405 # build the selection box for contacts
1406 #
1407 # Needed, if customer/vendor changed.
1408 sub build_contact_select {
1409   my ($self) = @_;
1410
1411   select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
1412     value_key  => 'cp_id',
1413     title_key  => 'full_name_dep',
1414     default    => $self->order->cp_id,
1415     with_empty => 1,
1416     style      => 'width: 300px',
1417   );
1418 }
1419
1420 # build the selection box for the additional billing address
1421 #
1422 # Needed, if customer/vendor changed.
1423 sub build_billing_address_select {
1424   my ($self) = @_;
1425
1426   return '' if $self->cv ne 'customer';
1427
1428   select_tag('order.billing_address_id',
1429              [ {displayable_id => '', id => ''}, $self->order->{$self->cv}->additional_billing_addresses ],
1430              value_key  => 'id',
1431              title_key  => 'displayable_id',
1432              default    => $self->order->billing_address_id,
1433              with_empty => 0,
1434              style      => 'width: 300px',
1435   );
1436 }
1437
1438 # build the selection box for shiptos
1439 #
1440 # Needed, if customer/vendor changed.
1441 sub build_shipto_select {
1442   my ($self) = @_;
1443
1444   select_tag('order.shipto_id',
1445              [ {displayable_id => t8("No/individual shipping address"), shipto_id => ''}, $self->order->{$self->cv}->shipto ],
1446              value_key  => 'shipto_id',
1447              title_key  => 'displayable_id',
1448              default    => $self->order->shipto_id,
1449              with_empty => 0,
1450              style      => 'width: 300px',
1451   );
1452 }
1453
1454 # build the inputs for the cusom shipto dialog
1455 #
1456 # Needed, if customer/vendor changed.
1457 sub build_shipto_inputs {
1458   my ($self) = @_;
1459
1460   my $content = $self->p->render('common/_ship_to_dialog',
1461                                  vc_obj      => $self->order->customervendor,
1462                                  cs_obj      => $self->order->custom_shipto,
1463                                  cvars       => $self->order->custom_shipto->cvars_by_config,
1464                                  id_selector => '#order_shipto_id');
1465
1466   div_tag($content, id => 'shipto_inputs');
1467 }
1468
1469 # render the info line for business
1470 #
1471 # Needed, if customer/vendor changed.
1472 sub build_business_info_row
1473 {
1474   $_[0]->p->render('order/tabs/_business_info_row', SELF => $_[0]);
1475 }
1476
1477 # build the rows for displaying taxes
1478 #
1479 # Called if amounts where recalculated and redisplayed.
1480 sub build_tax_rows {
1481   my ($self) = @_;
1482
1483   my $rows_as_html;
1484   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
1485     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
1486   }
1487   return $rows_as_html;
1488 }
1489
1490
1491 sub render_price_dialog {
1492   my ($self, $record_item) = @_;
1493
1494   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
1495
1496   $self->js
1497     ->run(
1498       'kivi.io.price_chooser_dialog',
1499       t8('Available Prices'),
1500       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
1501     )
1502     ->reinit_widgets;
1503
1504 #   if (@errors) {
1505 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
1506 #     $self->js->show('#dialog_flash_error');
1507 #   }
1508
1509   $self->js->render;
1510 }
1511
1512 sub load_order {
1513   my ($self) = @_;
1514
1515   return if !$::form->{id};
1516
1517   $self->order(SL::DB::Order->new(id => $::form->{id})->load);
1518
1519   # Add an empty custom shipto to the order, so that the dialog can render the cvar inputs.
1520   # You need a custom shipto object to call cvars_by_config to get the cvars.
1521   $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => [])) if !$self->order->custom_shipto;
1522
1523   return $self->order;
1524 }
1525
1526 # load or create a new order object
1527 #
1528 # And assign changes from the form to this object.
1529 # If the order is loaded from db, check if items are deleted in the form,
1530 # remove them form the object and collect them for removing from db on saving.
1531 # Then create/update items from form (via make_item) and add them.
1532 sub make_order {
1533   my ($self) = @_;
1534
1535   # add_items adds items to an order with no items for saving, but they cannot
1536   # be retrieved via items until the order is saved. Adding empty items to new
1537   # order here solves this problem.
1538   my $order;
1539   $order   = SL::DB::Order->new(id => $::form->{id})->load(with => [ 'orderitems', 'orderitems.part' ]) if $::form->{id};
1540   $order ||= SL::DB::Order->new(orderitems  => [],
1541                                 quotation   => (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type())),
1542                                 currency_id => $::instance_conf->get_currency_id(),);
1543
1544   my $cv_id_method = $self->cv . '_id';
1545   if (!$::form->{id} && $::form->{$cv_id_method}) {
1546     $order->$cv_id_method($::form->{$cv_id_method});
1547     setup_order_from_cv($order);
1548   }
1549
1550   my $form_orderitems                  = delete $::form->{order}->{orderitems};
1551   my $form_periodic_invoices_config    = delete $::form->{order}->{periodic_invoices_config};
1552
1553   $order->assign_attributes(%{$::form->{order}});
1554
1555   $self->setup_custom_shipto_from_form($order, $::form);
1556
1557   if (my $periodic_invoices_config_attrs = $form_periodic_invoices_config ? SL::YAML::Load($form_periodic_invoices_config) : undef) {
1558     my $periodic_invoices_config = $order->periodic_invoices_config || $order->periodic_invoices_config(SL::DB::PeriodicInvoicesConfig->new);
1559     $periodic_invoices_config->assign_attributes(%$periodic_invoices_config_attrs);
1560   }
1561
1562   # remove deleted items
1563   $self->item_ids_to_delete([]);
1564   foreach my $idx (reverse 0..$#{$order->orderitems}) {
1565     my $item = $order->orderitems->[$idx];
1566     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
1567       splice @{$order->orderitems}, $idx, 1;
1568       push @{$self->item_ids_to_delete}, $item->id;
1569     }
1570   }
1571
1572   my @items;
1573   my $pos = 1;
1574   foreach my $form_attr (@{$form_orderitems}) {
1575     my $item = make_item($order, $form_attr);
1576     $item->position($pos);
1577     push @items, $item;
1578     $pos++;
1579   }
1580   $order->add_items(grep {!$_->id} @items);
1581
1582   return $order;
1583 }
1584
1585 # create or update items from form
1586 #
1587 # Make item objects from form values. For items already existing read from db.
1588 # Create a new item else. And assign attributes.
1589 sub make_item {
1590   my ($record, $attr) = @_;
1591
1592   my $item;
1593   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
1594
1595   my $is_new = !$item;
1596
1597   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1598   # they cannot be retrieved via custom_variables until the order/orderitem is
1599   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1600   $item ||= SL::DB::OrderItem->new(custom_variables => []);
1601
1602   $item->assign_attributes(%$attr);
1603
1604   if ($is_new) {
1605     my $texts = get_part_texts($item->part, $record->language_id);
1606     $item->longdescription($texts->{longdescription})              if !defined $attr->{longdescription};
1607     $item->project_id($record->globalproject_id)                   if !defined $attr->{project_id};
1608     $item->lastcost($record->is_sales ? $item->part->lastcost : 0) if !defined $attr->{lastcost_as_number};
1609   }
1610
1611   return $item;
1612 }
1613
1614 # create a new item
1615 #
1616 # This is used to add one item
1617 sub new_item {
1618   my ($record, $attr) = @_;
1619
1620   my $item = SL::DB::OrderItem->new;
1621
1622   # Remove attributes where the user left or set the inputs empty.
1623   # So these attributes will be undefined and we can distinguish them
1624   # from zero later on.
1625   for (qw(qty_as_number sellprice_as_number discount_as_percent)) {
1626     delete $attr->{$_} if $attr->{$_} eq '';
1627   }
1628
1629   $item->assign_attributes(%$attr);
1630
1631   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
1632   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
1633
1634   $item->unit($part->unit) if !$item->unit;
1635
1636   my $price_src;
1637   if ( $part->is_assortment ) {
1638     # add assortment items with price 0, as the components carry the price
1639     $price_src = $price_source->price_from_source("");
1640     $price_src->price(0);
1641   } elsif (defined $item->sellprice) {
1642     $price_src = $price_source->price_from_source("");
1643     $price_src->price($item->sellprice);
1644   } else {
1645     $price_src = $price_source->best_price
1646                ? $price_source->best_price
1647                : $price_source->price_from_source("");
1648     $price_src->price($::form->round_amount($price_src->price / $record->exchangerate, 5)) if $record->exchangerate;
1649     $price_src->price(0) if !$price_source->best_price;
1650   }
1651
1652   my $discount_src;
1653   if (defined $item->discount) {
1654     $discount_src = $price_source->discount_from_source("");
1655     $discount_src->discount($item->discount);
1656   } else {
1657     $discount_src = $price_source->best_discount
1658                   ? $price_source->best_discount
1659                   : $price_source->discount_from_source("");
1660     $discount_src->discount(0) if !$price_source->best_discount;
1661   }
1662
1663   my %new_attr;
1664   $new_attr{part}                   = $part;
1665   $new_attr{description}            = $part->description     if ! $item->description;
1666   $new_attr{qty}                    = 1.0                    if ! $item->qty;
1667   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
1668   $new_attr{sellprice}              = $price_src->price;
1669   $new_attr{discount}               = $discount_src->discount;
1670   $new_attr{active_price_source}    = $price_src;
1671   $new_attr{active_discount_source} = $discount_src;
1672   $new_attr{longdescription}        = $part->notes           if ! defined $attr->{longdescription};
1673   $new_attr{project_id}             = $record->globalproject_id;
1674   $new_attr{lastcost}               = $record->is_sales ? $part->lastcost : 0;
1675
1676   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
1677   # they cannot be retrieved via custom_variables until the order/orderitem is
1678   # saved. Adding empty custom_variables to new orderitem here solves this problem.
1679   $new_attr{custom_variables} = [];
1680
1681   my $texts = get_part_texts($part, $record->language_id, description => $new_attr{description}, longdescription => $new_attr{longdescription});
1682
1683   $item->assign_attributes(%new_attr, %{ $texts });
1684
1685   return $item;
1686 }
1687
1688 sub setup_order_from_cv {
1689   my ($order) = @_;
1690
1691   $order->$_($order->customervendor->$_) for (qw(taxzone_id payment_id delivery_term_id currency_id language_id));
1692
1693   $order->intnotes($order->customervendor->notes);
1694
1695   return if !$order->is_sales;
1696
1697   $order->salesman_id($order->customer->salesman_id || SL::DB::Manager::Employee->current->id);
1698   $order->taxincluded(defined($order->customer->taxincluded_checked)
1699                       ? $order->customer->taxincluded_checked
1700                       : $::myconfig{taxincluded_checked});
1701
1702   my $address = $order->customer->default_billing_address;;
1703   $order->billing_address_id($address ? $address->id : undef);
1704 }
1705
1706 # setup custom shipto from form
1707 #
1708 # The dialog returns form variables starting with 'shipto' and cvars starting
1709 # with 'shiptocvar_'.
1710 # Mark it to be deleted if a shipto from master data is selected
1711 # (i.e. order has a shipto).
1712 # Else, update or create a new custom shipto. If the fields are empty, it
1713 # will not be saved on save.
1714 sub setup_custom_shipto_from_form {
1715   my ($self, $order, $form) = @_;
1716
1717   if ($order->shipto) {
1718     $self->is_custom_shipto_to_delete(1);
1719   } else {
1720     my $custom_shipto = $order->custom_shipto || $order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1721
1722     my $shipto_cvars  = {map { my ($key) = m{^shiptocvar_(.+)}; $key => delete $form->{$_}} grep { m{^shiptocvar_} } keys %$form};
1723     my $shipto_attrs  = {map {                                  $_   => delete $form->{$_}} grep { m{^shipto}      } keys %$form};
1724
1725     $custom_shipto->assign_attributes(%$shipto_attrs);
1726     $custom_shipto->cvar_by_name($_)->value($shipto_cvars->{$_}) for keys %$shipto_cvars;
1727   }
1728 }
1729
1730 # recalculate prices and taxes
1731 #
1732 # Using the PriceTaxCalculator. Store linetotals in the item objects.
1733 sub recalc {
1734   my ($self) = @_;
1735
1736   my %pat = $self->order->calculate_prices_and_taxes();
1737
1738   $self->{taxes} = [];
1739   foreach my $tax_id (keys %{ $pat{taxes_by_tax_id} }) {
1740     my $netamount = sum0 map { $pat{amounts}->{$_}->{amount} } grep { $pat{amounts}->{$_}->{tax_id} == $tax_id } keys %{ $pat{amounts} };
1741
1742     push(@{ $self->{taxes} }, { amount    => $pat{taxes_by_tax_id}->{$tax_id},
1743                                 netamount => $netamount,
1744                                 tax       => SL::DB::Tax->new(id => $tax_id)->load });
1745   }
1746   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items_sorted}, @{$pat{items}};
1747 }
1748
1749 # get data for saving, printing, ..., that is not changed in the form
1750 #
1751 # Only cvars for now.
1752 sub get_unalterable_data {
1753   my ($self) = @_;
1754
1755   foreach my $item (@{ $self->order->items }) {
1756     # autovivify all cvars that are not in the form (cvars_by_config can do it).
1757     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
1758     foreach my $var (@{ $item->cvars_by_config }) {
1759       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
1760     }
1761     $item->parse_custom_variable_values;
1762   }
1763 }
1764
1765 # delete the order
1766 #
1767 # And remove related files in the spool directory
1768 sub delete {
1769   my ($self) = @_;
1770
1771   my $errors = [];
1772   my $db     = $self->order->db;
1773
1774   $db->with_transaction(
1775     sub {
1776       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
1777       $self->order->delete;
1778       my $spool = $::lx_office_conf{paths}->{spool};
1779       unlink map { "$spool/$_" } @spoolfiles if $spool;
1780
1781       $self->save_history('DELETED');
1782
1783       1;
1784   }) || push(@{$errors}, $db->error);
1785
1786   return $errors;
1787 }
1788
1789 # save the order
1790 #
1791 # And delete items that are deleted in the form.
1792 sub save {
1793   my ($self) = @_;
1794
1795   my $errors = [];
1796   my $db     = $self->order->db;
1797
1798   $db->with_transaction(sub {
1799     # delete custom shipto if it is to be deleted or if it is empty
1800     if ($self->order->custom_shipto && ($self->is_custom_shipto_to_delete || $self->order->custom_shipto->is_empty)) {
1801       $self->order->custom_shipto->delete if $self->order->custom_shipto->shipto_id;
1802       $self->order->custom_shipto(undef);
1803     }
1804
1805     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete || []};
1806     $self->order->save(cascade => 1);
1807
1808     # link records
1809     if ($::form->{converted_from_oe_id}) {
1810       my @converted_from_oe_ids = split ' ', $::form->{converted_from_oe_id};
1811
1812       foreach my $converted_from_oe_id (@converted_from_oe_ids) {
1813         my $src = SL::DB::Order->new(id => $converted_from_oe_id)->load;
1814         $src->update_attributes(closed => 1) if $src->type =~ /_quotation$/;
1815         $src->link_to_record($self->order);
1816       }
1817       if (scalar @{ $::form->{converted_from_orderitems_ids} || [] }) {
1818         my $idx = 0;
1819         foreach (@{ $self->order->items_sorted }) {
1820           my $from_id = $::form->{converted_from_orderitems_ids}->[$idx];
1821           next if !$from_id;
1822           SL::DB::RecordLink->new(from_table => 'orderitems',
1823                                   from_id    => $from_id,
1824                                   to_table   => 'orderitems',
1825                                   to_id      => $_->id
1826           )->save;
1827           $idx++;
1828         }
1829       }
1830
1831       $self->link_requirement_specs_linking_to_created_from_objects(@converted_from_oe_ids);
1832     }
1833
1834     $self->set_project_in_linked_requirement_specs if $self->order->globalproject_id;
1835
1836     $self->save_history('SAVED');
1837
1838     1;
1839   }) || push(@{$errors}, $db->error);
1840
1841   return $errors;
1842 }
1843
1844 sub workflow_sales_or_request_for_quotation {
1845   my ($self) = @_;
1846
1847   # always save
1848   my $errors = $self->save();
1849
1850   if (scalar @{ $errors }) {
1851     $self->js->flash('error', $_) for @{ $errors };
1852     return $self->js->render();
1853   }
1854
1855   my $destination_type = $::form->{type} eq sales_order_type() ? sales_quotation_type() : request_quotation_type();
1856
1857   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1858   delete $::form->{id};
1859
1860   # no linked records from order to quotations
1861   delete $::form->{$_} for qw(converted_from_oe_id converted_from_orderitems_ids);
1862
1863   # set item ids to new fake id, to identify them as new items
1864   foreach my $item (@{$self->order->items_sorted}) {
1865     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1866   }
1867
1868   # change form type
1869   $::form->{type} = $destination_type;
1870   $self->type($self->init_type);
1871   $self->cv  ($self->init_cv);
1872   $self->check_auth;
1873
1874   $self->recalc();
1875   $self->get_unalterable_data();
1876   $self->pre_render();
1877
1878   # trigger rendering values for second row as hidden, because they
1879   # are loaded only on demand. So we need to keep the values from the
1880   # source.
1881   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1882
1883   $self->render(
1884     'order/form',
1885     title => $self->get_title_for('edit'),
1886     %{$self->{template_args}}
1887   );
1888 }
1889
1890 sub workflow_sales_or_purchase_order {
1891   my ($self) = @_;
1892
1893   # always save
1894   my $errors = $self->save();
1895
1896   if (scalar @{ $errors }) {
1897     $self->js->flash('error', $_) foreach @{ $errors };
1898     return $self->js->render();
1899   }
1900
1901   my $destination_type = $::form->{type} eq sales_quotation_type()   ? sales_order_type()
1902                        : $::form->{type} eq request_quotation_type() ? purchase_order_type()
1903                        : $::form->{type} eq purchase_order_type()    ? sales_order_type()
1904                        : $::form->{type} eq sales_order_type()       ? purchase_order_type()
1905                        : '';
1906
1907   # check for direct delivery
1908   # copy shipto in custom shipto (custom shipto will be copied by new_from() in case)
1909   my $custom_shipto;
1910   if (   $::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()
1911       && $::form->{use_shipto} && $self->order->shipto) {
1912     $custom_shipto = $self->order->shipto->clone('SL::DB::Order');
1913   }
1914
1915   $self->order(SL::DB::Order->new_from($self->order, destination_type => $destination_type));
1916   $self->{converted_from_oe_id} = delete $::form->{id};
1917
1918   # set item ids to new fake id, to identify them as new items
1919   foreach my $item (@{$self->order->items_sorted}) {
1920     $item->{new_fake_id} = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
1921   }
1922
1923   if ($::form->{type} eq sales_order_type() && $destination_type eq purchase_order_type()) {
1924     if ($::form->{use_shipto}) {
1925       $self->order->custom_shipto($custom_shipto) if $custom_shipto;
1926     } else {
1927       # remove any custom shipto if not wanted
1928       $self->order->custom_shipto(SL::DB::Shipto->new(module => 'OE', custom_variables => []));
1929     }
1930   }
1931
1932   # change form type
1933   $::form->{type} = $destination_type;
1934   $self->type($self->init_type);
1935   $self->cv  ($self->init_cv);
1936   $self->check_auth;
1937
1938   $self->recalc();
1939   $self->get_unalterable_data();
1940   $self->pre_render();
1941
1942   # trigger rendering values for second row as hidden, because they
1943   # are loaded only on demand. So we need to keep the values from the
1944   # source.
1945   $_->{render_second_row} = 1 for @{ $self->order->items_sorted };
1946
1947   $self->render(
1948     'order/form',
1949     title => $self->get_title_for('edit'),
1950     %{$self->{template_args}}
1951   );
1952 }
1953
1954
1955 sub pre_render {
1956   my ($self) = @_;
1957
1958   $self->{all_taxzones}               = SL::DB::Manager::TaxZone->get_all_sorted();
1959   $self->{all_currencies}             = SL::DB::Manager::Currency->get_all_sorted();
1960   $self->{all_departments}            = SL::DB::Manager::Department->get_all_sorted();
1961   $self->{all_languages}              = SL::DB::Manager::Language->get_all_sorted( query => [ or => [ obsolete => 0, id => $self->order->language_id ] ] );
1962   $self->{all_employees}              = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
1963                                                                                               deleted => 0 ] ],
1964                                                                            sort_by => 'name');
1965   $self->{all_salesmen}               = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
1966                                                                                               deleted => 0 ] ],
1967                                                                            sort_by => 'name');
1968   $self->{all_payment_terms}          = SL::DB::Manager::PaymentTerm->get_all_sorted(where => [ or => [ id => $self->order->payment_id,
1969                                                                                                         obsolete => 0 ] ]);
1970   $self->{all_delivery_terms}         = SL::DB::Manager::DeliveryTerm->get_all_sorted();
1971   $self->{current_employee_id}        = SL::DB::Manager::Employee->current->id;
1972   $self->{periodic_invoices_status}   = $self->get_periodic_invoices_status($self->order->periodic_invoices_config);
1973   $self->{order_probabilities}        = [ map { { title => ($_ * 10) . '%', id => $_ * 10 } } (0..10) ];
1974   $self->{positions_scrollbar_height} = SL::Helper::UserPreferences::PositionsScrollbar->new()->get_height();
1975
1976   my $print_form = Form->new('');
1977   $print_form->{type}        = $self->type;
1978   $print_form->{printers}    = SL::DB::Manager::Printer->get_all_sorted;
1979   $self->{print_options}     = SL::Helper::PrintOptions->get_print_options(
1980     form => $print_form,
1981     options => {dialog_name_prefix => 'print_options.',
1982                 show_headers       => 1,
1983                 no_queue           => 1,
1984                 no_postscript      => 1,
1985                 no_opendocument    => 0,
1986                 no_html            => 0},
1987   );
1988
1989   foreach my $item (@{$self->order->orderitems}) {
1990     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
1991     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
1992     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
1993   }
1994
1995   if (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())) {
1996     # Calculate shipped qtys here to prevent calling calculate for every item via the items method.
1997     # Do not use write_to_objects to prevent order->delivered to be set, because this should be
1998     # the value from db, which can be set manually or is set when linked delivery orders are saved.
1999     SL::Helper::ShippedQty->new->calculate($self->order)->write_to(\@{$self->order->items});
2000   }
2001
2002   if ($self->order->number && $::instance_conf->get_webdav) {
2003     my $webdav = SL::Webdav->new(
2004       type     => $self->type,
2005       number   => $self->order->number,
2006     );
2007     my @all_objects = $webdav->get_all_objects;
2008     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
2009                                                     type => t8('File'),
2010                                                     link => File::Spec->catfile($_->full_filedescriptor),
2011                                                 } } @all_objects;
2012   }
2013
2014   if (   (any { $self->type eq $_ } (sales_quotation_type(), sales_order_type()))
2015       && $::instance_conf->get_transport_cost_reminder_article_number_id ) {
2016     $self->{template_args}->{transport_cost_reminder_article} = SL::DB::Part->new(id => $::instance_conf->get_transport_cost_reminder_article_number_id)->load;
2017   }
2018
2019   $self->get_item_cvpartnumber($_) for @{$self->order->items_sorted};
2020
2021   $::request->{layout}->use_javascript("${_}.js") for qw(kivi.Validator kivi.SalesPurchase kivi.Order kivi.File ckeditor/ckeditor ckeditor/adapters/jquery
2022                                                          edit_periodic_invoices_config calculate_qty follow_up show_history);
2023   $self->setup_edit_action_bar;
2024 }
2025
2026 sub setup_edit_action_bar {
2027   my ($self, %params) = @_;
2028
2029   my $deletion_allowed = (any { $self->type eq $_ } (sales_quotation_type(), request_quotation_type()))
2030                       || (($self->type eq sales_order_type())    && $::instance_conf->get_sales_order_show_delete)
2031                       || (($self->type eq purchase_order_type()) && $::instance_conf->get_purchase_order_show_delete);
2032
2033   my @req_trans_cost_art = qw(kivi.Order.check_transport_cost_article_presence) x!!$::instance_conf->get_transport_cost_reminder_article_number_id;
2034   my @req_cusordnumber   = qw(kivi.Order.check_cusordnumber_presence)           x($self->type eq sales_order_type() && $::instance_conf->get_order_warn_no_cusordnumber);
2035
2036   my $has_invoice_for_advance_payment;
2037   if ($self->order->id && $self->type eq sales_order_type()) {
2038     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2039     $has_invoice_for_advance_payment = any {'SL::DB::Invoice' eq ref $_ && "invoice_for_advance_payment" eq $_->type} @$lr;
2040   }
2041
2042   my $has_final_invoice;
2043   if ($self->order->id && $self->type eq sales_order_type()) {
2044     my $lr = $self->order->linked_records(direction => 'to', to => ['Invoice']);
2045     $has_final_invoice               = any {'SL::DB::Invoice' eq ref $_ && "final_invoice" eq $_->type} @$lr;
2046   }
2047
2048   my $right_for         = { map { $_ => $_.'_edit' } @{$self->valid_types} };
2049   my $right             = $right_for->{ $self->type };
2050   $right              ||= 'DOES_NOT_EXIST';
2051   my $may_edit_create   = $::auth->assert($right, 'may fail');
2052
2053   for my $bar ($::request->layout->get('actionbar')) {
2054     $bar->add(
2055       combobox => [
2056         action => [
2057           t8('Save'),
2058           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2059                                                     $::instance_conf->get_order_warn_no_deliverydate,
2060           ],
2061           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2062                          @req_trans_cost_art, @req_cusordnumber,
2063           ],
2064           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2065         ],
2066         action => [
2067           t8('Save and Close'),
2068           call      => [ 'kivi.Order.save', 'save', $::instance_conf->get_order_warn_duplicate_parts,
2069                                                     $::instance_conf->get_order_warn_no_deliverydate,
2070                                                     1
2071           ],
2072           checks    => [ 'kivi.Order.check_save_active_periodic_invoices', ['kivi.validate_form','#order_form'],
2073                          @req_trans_cost_art, @req_cusordnumber,
2074           ],
2075           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2076         ],
2077         action => [
2078           t8('Save as new'),
2079           call      => [ 'kivi.Order.save', 'save_as_new', $::instance_conf->get_order_warn_duplicate_parts ],
2080           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2081                          @req_trans_cost_art, @req_cusordnumber,
2082           ],
2083           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.')
2084                      : !$self->order->id ? t8('This object has not been saved yet.')
2085                      :                     undef,
2086         ],
2087       ], # end of combobox "Save"
2088
2089       combobox => [
2090         action => [
2091           t8('Workflow'),
2092         ],
2093         action => [
2094           t8('Save and Quotation'),
2095           submit   => [ '#order_form', { action => "Order/sales_quotation" } ],
2096           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2097           only_if  => (any { $self->type eq $_ } (sales_order_type())),
2098           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2099         ],
2100         action => [
2101           t8('Save and RFQ'),
2102           submit   => [ '#order_form', { action => "Order/request_for_quotation" } ],
2103           only_if  => (any { $self->type eq $_ } (purchase_order_type())),
2104           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2105         ],
2106         action => [
2107           t8('Save and Sales Order'),
2108           submit   => [ '#order_form', { action => "Order/sales_order" } ],
2109           checks   => [ @req_trans_cost_art ],
2110           only_if  => (any { $self->type eq $_ } (sales_quotation_type(), purchase_order_type())),
2111           disabled => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2112         ],
2113         action => [
2114           t8('Save and Purchase Order'),
2115           call      => [ 'kivi.Order.purchase_order_check_for_direct_delivery' ],
2116           checks    => [ @req_trans_cost_art, @req_cusordnumber ],
2117           only_if   => (any { $self->type eq $_ } (sales_order_type(), request_quotation_type())),
2118           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2119         ],
2120         action => [
2121           t8('Save and Delivery Order'),
2122           call      => [ 'kivi.Order.save', 'save_and_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2123                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2124                                                                                                                         ],
2125           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2126                          @req_trans_cost_art, @req_cusordnumber,
2127           ],
2128           only_if   => (any { $self->type eq $_ } (sales_order_type(), purchase_order_type())),
2129           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2130         ],
2131         action => [
2132           t8('Save and Supplier Delivery Order'),
2133           call      => [ 'kivi.Order.save', 'save_and_supplier_delivery_order', $::instance_conf->get_order_warn_duplicate_parts,
2134                                                                        $::instance_conf->get_order_warn_no_deliverydate,
2135                                                                                                                         ],
2136           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2137                          @req_trans_cost_art, @req_cusordnumber,
2138           ],
2139           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2140           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2141         ],
2142         action => [
2143           t8('Save and Invoice'),
2144           call      => [ 'kivi.Order.save', 'save_and_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2145           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2146                          @req_trans_cost_art, @req_cusordnumber,
2147           ],
2148           disabled  => !$may_edit_create ? t8('You do not have the permissions to access this function.') : undef,
2149         ],
2150         action => [
2151           ($has_invoice_for_advance_payment ? t8('Save and Further Invoice for Advance Payment') : t8('Save and Invoice for Advance Payment')),
2152           call      => [ 'kivi.Order.save', 'save_and_invoice_for_advance_payment', $::instance_conf->get_order_warn_duplicate_parts ],
2153           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2154                          @req_trans_cost_art, @req_cusordnumber,
2155           ],
2156           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2157                      : $has_final_invoice ? t8('This order has already a final invoice.')
2158                      :                      undef,
2159           only_if   => (any { $self->type eq $_ } (sales_order_type())),
2160         ],
2161         action => [
2162           t8('Save and Final Invoice'),
2163           call      => [ 'kivi.Order.save', 'save_and_final_invoice', $::instance_conf->get_order_warn_duplicate_parts ],
2164           checks    => [ 'kivi.Order.check_save_active_periodic_invoices',
2165                          @req_trans_cost_art, @req_cusordnumber,
2166           ],
2167           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2168                      : $has_final_invoice ? t8('This order has already a final invoice.')
2169                      :                      undef,
2170           only_if   => (any { $self->type eq $_ } (sales_order_type())) && $has_invoice_for_advance_payment,
2171         ],
2172         action => [
2173           t8('Save and AP Transaction'),
2174           call      => [ 'kivi.Order.save', 'save_and_ap_transaction', $::instance_conf->get_order_warn_duplicate_parts ],
2175           only_if   => (any { $self->type eq $_ } (purchase_order_type())),
2176           disabled  => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2177         ],
2178
2179       ], # end of combobox "Workflow"
2180
2181       combobox => [
2182         action => [
2183           t8('Export'),
2184         ],
2185         action => [
2186           t8('Save and preview PDF'),
2187           call     => [ 'kivi.Order.save', 'preview_pdf', $::instance_conf->get_order_warn_duplicate_parts,
2188                                                           $::instance_conf->get_order_warn_no_deliverydate,
2189                       ],
2190           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2191           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2192         ],
2193         action => [
2194           t8('Save and print'),
2195           call     => [ 'kivi.Order.show_print_options', $::instance_conf->get_order_warn_duplicate_parts,
2196                                                          $::instance_conf->get_order_warn_no_deliverydate,
2197                       ],
2198           checks   => [ @req_trans_cost_art, @req_cusordnumber ],
2199           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.') : undef,
2200         ],
2201         action => [
2202           t8('Save and E-mail'),
2203           id       => 'save_and_email_action',
2204           call     => [ 'kivi.Order.save', 'save_and_show_email_dialog', $::instance_conf->get_order_warn_duplicate_parts,
2205                                                                          $::instance_conf->get_order_warn_no_deliverydate,
2206                       ],
2207           disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2208                     : !$self->order->id  ? t8('This object has not been saved yet.')
2209                     :                      undef,
2210         ],
2211         action => [
2212           t8('Download attachments of all parts'),
2213           call     => [ 'kivi.File.downloadOrderitemsFiles', $::form->{type}, $::form->{id} ],
2214           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2215           only_if  => $::instance_conf->get_doc_storage,
2216         ],
2217       ], # end of combobox "Export"
2218
2219       action => [
2220         t8('Delete'),
2221         call     => [ 'kivi.Order.delete_order' ],
2222         confirm  => $::locale->text('Do you really want to delete this object?'),
2223         disabled => !$may_edit_create  ? t8('You do not have the permissions to access this function.')
2224                   : !$self->order->id  ? t8('This object has not been saved yet.')
2225                   :                      undef,
2226         only_if  => $deletion_allowed,
2227       ],
2228
2229       combobox => [
2230         action => [
2231           t8('more')
2232         ],
2233         action => [
2234           t8('History'),
2235           call     => [ 'set_history_window', $self->order->id, 'id' ],
2236           disabled => !$self->order->id ? t8('This record has not been saved yet.') : undef,
2237         ],
2238         action => [
2239           t8('Follow-Up'),
2240           call     => [ 'kivi.Order.follow_up_window' ],
2241           disabled => !$self->order->id ? t8('This object has not been saved yet.') : undef,
2242           only_if  => $::auth->assert('productivity', 1),
2243         ],
2244       ], # end of combobox "more"
2245     );
2246   }
2247 }
2248
2249 sub generate_doc {
2250   my ($self, $doc_ref, $params) = @_;
2251
2252   my $order  = $self->order;
2253   my @errors = ();
2254
2255   my $print_form = Form->new('');
2256   $print_form->{type}        = $order->type;
2257   $print_form->{formname}    = $params->{formname} || $order->type;
2258   $print_form->{format}      = $params->{format}   || 'pdf';
2259   $print_form->{media}       = $params->{media}    || 'file';
2260   $print_form->{groupitems}  = $params->{groupitems};
2261   $print_form->{printer_id}  = $params->{printer_id};
2262   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
2263
2264   $order->language($params->{language});
2265   $order->flatten_to_form($print_form, format_amounts => 1);
2266
2267   my $template_ext;
2268   my $template_type;
2269   if ($print_form->{format} =~ /(opendocument|oasis)/i) {
2270     $template_ext  = 'odt';
2271     $template_type = 'OpenDocument';
2272   } elsif ($print_form->{format} =~ m{html}i) {
2273     $template_ext  = 'html';
2274     $template_type = 'HTML';
2275   }
2276
2277   # search for the template
2278   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
2279     name        => $print_form->{formname},
2280     extension   => $template_ext,
2281     email       => $print_form->{media} eq 'email',
2282     language    => $params->{language},
2283     printer_id  => $print_form->{printer_id},
2284   );
2285
2286   if (!defined $template_file) {
2287     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
2288   }
2289
2290   return @errors if scalar @errors;
2291
2292   $print_form->throw_on_error(sub {
2293     eval {
2294       $print_form->prepare_for_printing;
2295
2296       $$doc_ref = SL::Helper::CreatePDF->create_pdf(
2297         format        => $print_form->{format},
2298         template_type => $template_type,
2299         template      => $template_file,
2300         variables     => $print_form,
2301         variable_content_types => {
2302           longdescription => 'html',
2303           partnotes       => 'html',
2304           notes           => 'html',
2305           $::form->get_variable_content_types_for_cvars,
2306         },
2307       );
2308       1;
2309     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->error : $EVAL_ERROR;
2310   });
2311
2312   return @errors;
2313 }
2314
2315 sub get_files_for_email_dialog {
2316   my ($self) = @_;
2317
2318   my %files = map { ($_ => []) } qw(versions files vc_files part_files);
2319
2320   return %files if !$::instance_conf->get_doc_storage;
2321
2322   if ($self->order->id) {
2323     $files{versions} = [ SL::File->get_all_versions(object_id => $self->order->id,              object_type => $self->order->type, file_type => 'document') ];
2324     $files{files}    = [ SL::File->get_all(         object_id => $self->order->id,              object_type => $self->order->type, file_type => 'attachment') ];
2325     $files{vc_files} = [ SL::File->get_all(         object_id => $self->order->{$self->cv}->id, object_type => $self->cv,          file_type => 'attachment') ];
2326     $files{project_files} = [ SL::File->get_all(    object_id => $self->order->globalproject_id, object_type => 'project',         file_type => 'attachment') ];
2327   }
2328
2329   my @parts =
2330     uniq_by { $_->{id} }
2331     map {
2332       +{ id         => $_->part->id,
2333          partnumber => $_->part->partnumber }
2334     } @{$self->order->items_sorted};
2335
2336   foreach my $part (@parts) {
2337     my @pfiles = SL::File->get_all(object_id => $part->{id}, object_type => 'part');
2338     push @{ $files{part_files} }, map { +{ %{ $_ }, partnumber => $part->{partnumber} } } @pfiles;
2339   }
2340
2341   foreach my $key (keys %files) {
2342     $files{$key} = [ sort_by { lc $_->{db_file}->{file_name} } @{ $files{$key} } ];
2343   }
2344
2345   return %files;
2346 }
2347
2348 sub make_periodic_invoices_config_from_yaml {
2349   my ($yaml_config) = @_;
2350
2351   return if !$yaml_config;
2352   my $attr = SL::YAML::Load($yaml_config);
2353   return if 'HASH' ne ref $attr;
2354   return SL::DB::PeriodicInvoicesConfig->new(%$attr);
2355 }
2356
2357
2358 sub get_periodic_invoices_status {
2359   my ($self, $config) = @_;
2360
2361   return                      if $self->type ne sales_order_type();
2362   return t8('not configured') if !$config;
2363
2364   my $active = ('HASH' eq ref $config)                           ? $config->{active}
2365              : ('SL::DB::PeriodicInvoicesConfig' eq ref $config) ? $config->active
2366              :                                                     die "Cannot get status of periodic invoices config";
2367
2368   return $active ? t8('active') : t8('inactive');
2369 }
2370
2371 sub get_title_for {
2372   my ($self, $action) = @_;
2373
2374   return '' if none { lc($action)} qw(add edit);
2375
2376   # for locales:
2377   # $::locale->text("Add Sales Order");
2378   # $::locale->text("Add Purchase Order");
2379   # $::locale->text("Add Quotation");
2380   # $::locale->text("Add Request for Quotation");
2381   # $::locale->text("Edit Sales Order");
2382   # $::locale->text("Edit Purchase Order");
2383   # $::locale->text("Edit Quotation");
2384   # $::locale->text("Edit Request for Quotation");
2385
2386   $action = ucfirst(lc($action));
2387   return $self->type eq sales_order_type()       ? $::locale->text("$action Sales Order")
2388        : $self->type eq purchase_order_type()    ? $::locale->text("$action Purchase Order")
2389        : $self->type eq sales_quotation_type()   ? $::locale->text("$action Quotation")
2390        : $self->type eq request_quotation_type() ? $::locale->text("$action Request for Quotation")
2391        : '';
2392 }
2393
2394 sub get_item_cvpartnumber {
2395   my ($self, $item) = @_;
2396
2397   return if !$self->search_cvpartnumber;
2398   return if !$self->order->customervendor;
2399
2400   if ($self->cv eq 'vendor') {
2401     my @mms = grep { $_->make eq $self->order->customervendor->id } @{$item->part->makemodels};
2402     $item->{cvpartnumber} = $mms[0]->model if scalar @mms;
2403   } elsif ($self->cv eq 'customer') {
2404     my @cps = grep { $_->customer_id eq $self->order->customervendor->id } @{$item->part->customerprices};
2405     $item->{cvpartnumber} = $cps[0]->customer_partnumber if scalar @cps;
2406   }
2407 }
2408
2409 sub get_part_texts {
2410   my ($part_or_id, $language_or_id, %defaults) = @_;
2411
2412   my $part        = ref($part_or_id)     ? $part_or_id         : SL::DB::Part->load_cached($part_or_id);
2413   my $language_id = ref($language_or_id) ? $language_or_id->id : $language_or_id;
2414   my $texts       = {
2415     description     => $defaults{description}     // $part->description,
2416     longdescription => $defaults{longdescription} // $part->notes,
2417   };
2418
2419   return $texts unless $language_id;
2420
2421   my $translation = SL::DB::Manager::Translation->get_first(
2422     where => [
2423       parts_id    => $part->id,
2424       language_id => $language_id,
2425     ]);
2426
2427   $texts->{description}     = $translation->translation     if $translation && $translation->translation;
2428   $texts->{longdescription} = $translation->longdescription if $translation && $translation->longdescription;
2429
2430   return $texts;
2431 }
2432
2433 sub sales_order_type {
2434   'sales_order';
2435 }
2436
2437 sub purchase_order_type {
2438   'purchase_order';
2439 }
2440
2441 sub sales_quotation_type {
2442   'sales_quotation';
2443 }
2444
2445 sub request_quotation_type {
2446   'request_quotation';
2447 }
2448
2449 sub nr_key {
2450   return $_[0]->type eq sales_order_type()       ? 'ordnumber'
2451        : $_[0]->type eq purchase_order_type()    ? 'ordnumber'
2452        : $_[0]->type eq sales_quotation_type()   ? 'quonumber'
2453        : $_[0]->type eq request_quotation_type() ? 'quonumber'
2454        : '';
2455 }
2456
2457 sub save_and_redirect_to {
2458   my ($self, %params) = @_;
2459
2460   my $errors = $self->save();
2461
2462   if (scalar @{ $errors }) {
2463     $self->js->flash('error', $_) foreach @{ $errors };
2464     return $self->js->render();
2465   }
2466
2467   my $text = $self->type eq sales_order_type()       ? $::locale->text('The order has been saved')
2468            : $self->type eq purchase_order_type()    ? $::locale->text('The order has been saved')
2469            : $self->type eq sales_quotation_type()   ? $::locale->text('The quotation has been saved')
2470            : $self->type eq request_quotation_type() ? $::locale->text('The rfq has been saved')
2471            : '';
2472   flash_later('info', $text);
2473
2474   $self->redirect_to(%params, id => $self->order->id);
2475 }
2476
2477 sub save_history {
2478   my ($self, $addition) = @_;
2479
2480   my $number_type = $self->order->type =~ m{order} ? 'ordnumber' : 'quonumber';
2481   my $snumbers    = $number_type . '_' . $self->order->$number_type;
2482
2483   SL::DB::History->new(
2484     trans_id    => $self->order->id,
2485     employee_id => SL::DB::Manager::Employee->current->id,
2486     what_done   => $self->order->type,
2487     snumbers    => $snumbers,
2488     addition    => $addition,
2489   )->save;
2490 }
2491
2492 sub store_doc_to_webdav_and_filemanagement {
2493   my ($self, $content, $filename, $variant) = @_;
2494
2495   my $order = $self->order;
2496   my @errors;
2497
2498   # copy file to webdav folder
2499   if ($order->number && $::instance_conf->get_webdav_documents) {
2500     my $webdav = SL::Webdav->new(
2501       type     => $order->type,
2502       number   => $order->number,
2503     );
2504     my $webdav_file = SL::Webdav::File->new(
2505       webdav   => $webdav,
2506       filename => $filename,
2507     );
2508     eval {
2509       $webdav_file->store(data => \$content);
2510       1;
2511     } or do {
2512       push @errors, t8('Storing the document to the WebDAV folder failed: #1', $@);
2513     };
2514   }
2515   if ($order->id && $::instance_conf->get_doc_storage) {
2516     eval {
2517       SL::File->save(object_id     => $order->id,
2518                      object_type   => $order->type,
2519                      mime_type     => SL::MIME->mime_type_from_ext($filename),
2520                      source        => 'created',
2521                      file_type     => 'document',
2522                      file_name     => $filename,
2523                      file_contents => $content,
2524                      print_variant => $variant);
2525       1;
2526     } or do {
2527       push @errors, t8('Storing the document in the storage backend failed: #1', $@);
2528     };
2529   }
2530
2531   return @errors;
2532 }
2533
2534 sub link_requirement_specs_linking_to_created_from_objects {
2535   my ($self, @converted_from_oe_ids) = @_;
2536
2537   return unless @converted_from_oe_ids;
2538
2539   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => \@converted_from_oe_ids ]);
2540   foreach my $rs_order (@{ $rs_orders }) {
2541     SL::DB::RequirementSpecOrder->new(
2542       order_id            => $self->order->id,
2543       requirement_spec_id => $rs_order->requirement_spec_id,
2544       version_id          => $rs_order->version_id,
2545     )->save;
2546   }
2547 }
2548
2549 sub set_project_in_linked_requirement_specs {
2550   my ($self) = @_;
2551
2552   my $rs_orders = SL::DB::Manager::RequirementSpecOrder->get_all(where => [ order_id => $self->order->id ]);
2553   foreach my $rs_order (@{ $rs_orders }) {
2554     next if $rs_order->requirement_spec->project_id == $self->order->globalproject_id;
2555
2556     $rs_order->requirement_spec->update_attributes(project_id => $self->order->globalproject_id);
2557   }
2558 }
2559
2560 1;
2561
2562 __END__
2563
2564 =encoding utf-8
2565
2566 =head1 NAME
2567
2568 SL::Controller::Order - controller for orders
2569
2570 =head1 SYNOPSIS
2571
2572 This is a new form to enter orders, completely rewritten with the use
2573 of controller and java script techniques.
2574
2575 The aim is to provide the user a better experience and a faster workflow. Also
2576 the code should be more readable, more reliable and better to maintain.
2577
2578 =head2 Key Features
2579
2580 =over 4
2581
2582 =item *
2583
2584 One input row, so that input happens every time at the same place.
2585
2586 =item *
2587
2588 Use of pickers where possible.
2589
2590 =item *
2591
2592 Possibility to enter more than one item at once.
2593
2594 =item *
2595
2596 Item list in a scrollable area, so that the workflow buttons stay at
2597 the bottom.
2598
2599 =item *
2600
2601 Reordering item rows with drag and drop is possible. Sorting item rows is
2602 possible (by partnumber, description, qty, sellprice and discount for now).
2603
2604 =item *
2605
2606 No C<update> is necessary. All entries and calculations are managed
2607 with ajax-calls and the page only reloads on C<save>.
2608
2609 =item *
2610
2611 User can see changes immediately, because of the use of java script
2612 and ajax.
2613
2614 =back
2615
2616 =head1 CODE
2617
2618 =head2 Layout
2619
2620 =over 4
2621
2622 =item * C<SL/Controller/Order.pm>
2623
2624 the controller
2625
2626 =item * C<template/webpages/order/form.html>
2627
2628 main form
2629
2630 =item * C<template/webpages/order/tabs/basic_data.html>
2631
2632 Main tab for basic_data.
2633
2634 This is the only tab here for now. "linked records" and "webdav" tabs are
2635 reused from generic code.
2636
2637 =over 4
2638
2639 =item * C<template/webpages/order/tabs/_business_info_row.html>
2640
2641 For displaying information on business type
2642
2643 =item * C<template/webpages/order/tabs/_item_input.html>
2644
2645 The input line for items
2646
2647 =item * C<template/webpages/order/tabs/_row.html>
2648
2649 One row for already entered items
2650
2651 =item * C<template/webpages/order/tabs/_tax_row.html>
2652
2653 Displaying tax information
2654
2655 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
2656
2657 Dialog for selecting price and discount sources
2658
2659 =back
2660
2661 =item * C<js/kivi.Order.js>
2662
2663 java script functions
2664
2665 =back
2666
2667 =head1 TODO
2668
2669 =over 4
2670
2671 =item * testing
2672
2673 =item * price sources: little symbols showing better price / better discount
2674
2675 =item * select units in input row?
2676
2677 =item * check for direct delivery (workflow sales order -> purchase order)
2678
2679 =item * access rights
2680
2681 =item * display weights
2682
2683 =item * mtime check
2684
2685 =item * optional client/user behaviour
2686
2687 (transactions has to be set - department has to be set -
2688  force project if enabled in client config)
2689
2690 =back
2691
2692 =head1 KNOWN BUGS AND CAVEATS
2693
2694 =over 4
2695
2696 =item *
2697
2698 Customer discount is not displayed as a valid discount in price source popup
2699 (this might be a bug in price sources)
2700
2701 (I cannot reproduce this (Bernd))
2702
2703 =item *
2704
2705 No indication that <shift>-up/down expands/collapses second row.
2706
2707 =item *
2708
2709 Inline creation of parts is not currently supported
2710
2711 =item *
2712
2713 Table header is not sticky in the scrolling area.
2714
2715 =item *
2716
2717 Sorting does not include C<position>, neither does reordering.
2718
2719 This behavior was implemented intentionally. But we can discuss, which behavior
2720 should be implemented.
2721
2722 =back
2723
2724 =head1 To discuss / Nice to have
2725
2726 =over 4
2727
2728 =item *
2729
2730 How to expand/collapse second row. Now it can be done clicking the icon or
2731 <shift>-up/down.
2732
2733 =item *
2734
2735 Possibility to select PriceSources in input row?
2736
2737 =item *
2738
2739 This controller uses a (changed) copy of the template for the PriceSource
2740 dialog. Maybe there could be used one code source.
2741
2742 =item *
2743
2744 Rounding-differences between this controller (PriceTaxCalculator) and the old
2745 form. This is not only a problem here, but also in all parts using the PTC.
2746 There exists a ticket and a patch. This patch should be testet.
2747
2748 =item *
2749
2750 An indicator, if the actual inputs are saved (like in an
2751 editor or on text processing application).
2752
2753 =item *
2754
2755 A warning when leaving the page without saveing unchanged inputs.
2756
2757
2758 =back
2759
2760 =head1 AUTHOR
2761
2762 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
2763
2764 =cut