SL/Controller/Helper/GetModels.pm

   1 package SL::Controller::Helper::GetModels;
   2
   3 use strict;
   4
   5 use Exporter qw(import);
   6 our @EXPORT = qw(get_models_url_params get_callback get_models);
   7
   8 use constant PRIV => '__getmodelshelperpriv';
   9
  10 my %registered_handlers = ( callback => [], get_models => [] );
  11
  12 sub register_get_models_handlers {
  13   my ($class, %additional_handlers) = @_;
  14
  15   my $only        = delete($additional_handlers{ONLY}) || [];
  16   $only           = [ $only ] if !ref $only;
  17   my %hook_params = @{ $only } ? ( only => $only ) : ();
  18
  19   $class->run_before(sub { $_[0]->{PRIV()} = { current_action => $_[1] }; }, %hook_params);
  20
  21   map { push @{ $registered_handlers{$_} }, $additional_handlers{$_} if $additional_handlers{$_} } keys %registered_handlers;
  22 }
  23
  24 sub get_models_url_params {
  25   my ($class, $sub_name_or_code) = @_;
  26
  27   my $code     = (ref($sub_name_or_code) || '') eq 'CODE' ? $sub_name_or_code : sub { shift->$sub_name_or_code(@_) };
  28   my $callback = sub {
  29     my ($self, %params)   = @_;
  30     my @additional_params = $code->($self);
  31     return (
  32       %params,
  33       (scalar(@additional_params) == 1) && (ref($additional_params[0]) eq 'HASH') ? %{ $additional_params[0] } : @additional_params,
  34     );
  35   };
  36
  37   push @{ $registered_handlers{callback} }, $callback;
  38 }
  39
  40 sub get_callback {
  41   my ($self, %override_params) = @_;
  42
  43   my %default_params = _run_handlers($self, 'callback', action => ($self->{PRIV()} || {})->{current_action});
  44
  45   return $self->url_for(%default_params, %override_params);
  46 }
  47
  48 sub get_models {
  49   my ($self, %override_params) = @_;
  50
  51   my %default_params           = _run_handlers($self, 'get_models');
  52
  53   my %params                   = (%default_params, %override_params);
  54   my $model                    = delete($params{model}) || die "No 'model' to work on";
  55
  56   return "SL::DB::Manager::${model}"->get_all(%params);
  57 }
  58
  59 #
  60 # private/internal functions
  61 #
  62
  63 sub _run_handlers {
  64   my ($self, $handler_type, %params) = @_;
  65
  66   foreach my $sub (@{ $registered_handlers{$handler_type} }) {
  67     if (ref $sub eq 'CODE') {
  68       %params = $sub->($self, %params);
  69     } elsif ($self->can($sub)) {
  70       %params = $self->$sub(%params);
  71     } else {
  72       die "SL::Controller::Helper::GetModels::get_callback: Cannot call $sub on " . ref($self) . ")";
  73     }
  74   }
  75
  76   return %params;
  77 }
  78
  79 1;
  80 __END__
  81
  82 =pod
  83
  84 =encoding utf8
  85
  86 =head1 NAME
  87
  88 SL::Controller::Helper::GetModels - Base mixin for controller helpers
  89 dealing with semi-automatic handling of sorting and paginating lists
  90
  91 =head1 SYNOPSIS
  92
  93 For a proper synopsis see L<SL::Controller::Helper::Sorted>.
  94
  95 =head1 OVERVIEW
  96
  97 For a generic overview see L<SL::Controller::Helper::Sorted>.
  98
  99 This base module is the interface between a controller and specialized
 100 helper modules that handle things like sorting and paginating. The
 101 specialized helpers register themselves with this module via a call to
 102 L<register_get_models_handlers> during compilation time (e.g. in the
 103 case of C<Sorted> this happens when the controller calls
 104 L<SL::Controller::Helper::Sorted::make_sorted>).
 105
 106 A controller will later usually call the L<get_models>
 107 function. Templates will call the L<get_callback> function. Both
 108 functions run the registered handlers handing over control to the
 109 specialized helpers so that they may inject their parameters into the
 110 call chain.
 111
 112 The C<GetModels> helper hooks into the controller call to the action
 113 via a C<run_before> hook. This is done so that it can remember the
 114 action called by the user. This is used for constructing the callback
 115 in L<get_callback>.
 116
 117 =head1 PACKAGE FUNCTIONS
 118
 119 =over 4
 120
 121 =item C<get_models_url_params $class, $sub>
 122
 123 Register one of the controller's subs to be called whenever an URL has
 124 to be generated (e.g. for sort and pagination links). This is a way
 125 for the controller to add additional parameters to the URL (e.g. for
 126 filter parameters).
 127
 128 The C<$sub> parameter can be either a code reference or the name of
 129 one of the controller's functions.
 130
 131 The value returned by this C<$sub> must be either a single hash
 132 reference or a hash of key/value pairs to add to the URL.
 133
 134 =item C<register_get_models_handlers $class, %handlers>
 135
 136 This function should only be called from other controller helpers like
 137 C<Sorted> or C<Paginated>. It is not exported and must therefore be
 138 called its full name. The first parameter C<$class> must be the actual
 139 controller's class name.
 140
 141 If C<%handlers> contains a key C<ONLY> then it is passed to the hook
 142 registration in L<SL::Controller::Base::run_before>.
 143
 144 The C<%handlers> register callback functions in the specialized
 145 controller helpers that are called during invocation of
 146 L<get_callback> or L<get_models>. Possible keys are C<callback> and
 147 C<models>.
 148
 149 Each handler (the value in the hash) can be either a code reference
 150 (in which case it is called directly) or the name of an instance
 151 function callable on a controller instance. In both cases the handler
 152 receives a hash of parameters built during this very call to
 153 L<get_callback> or L<get_models> respectively. The handler's return
 154 value must be the new hash to be used in calls to further handlers and
 155 to the actual database model functions later on.
 156
 157 =back
 158
 159 =head1 INSTANCE FUNCTIONS
 160
 161 =over 4
 162
 163 =item C<get_callback [%params]>
 164
 165 Return an URL suitable for use as a callback parameter. It maps to the
 166 current controller and action. All registered handlers of type
 167 'callback' (e.g. the ones by C<Sorted> and C<Paginated>) can inject
 168 the parameters they need so that the same list view as is currently
 169 visible can be re-rendered.
 170
 171 Optional C<%params> passed to this function may override any parameter
 172 set by the registered handlers.
 173
 174 =item C<get_models [%params]>
 175
 176 Query the model manager via C<get_all> and return its result. The
 177 parameters to C<get_all> are constructed by calling all registered
 178 handlers of type 'models' (e.g. the ones by C<Sorted> and
 179 C<Paginated>).
 180
 181 Optional C<%params> passed to this function may override any parameter
 182 set by the registered handlers.
 183
 184 The return value is the an array reference of C<Rose> models.
 185
 186 =back
 187
 188 =head1 BUGS
 189
 190 Nothing here yet.
 191
 192 =head1 AUTHOR
 193
 194 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 195
 196 =cut