SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::DB::Business;
   7 use SL::DB::CustomVariable;
   8 use SL::DB::CustomVariableConfig;
   9 use SL::DB::PaymentTerm;
  10
  11 use parent qw(SL::Controller::CsvImport::Base);
  12
  13 use Rose::Object::MakeMethods::Generic
  14 (
  15  'scalar --get_set_init' => [ qw(table languages_by businesses_by) ],
  16 );
  17
  18 sub init_table {
  19   my ($self) = @_;
  20   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  21 }
  22
  23 sub init_class {
  24   my ($self) = @_;
  25   $self->class('SL::DB::' . ucfirst($self->table));
  26 }
  27
  28 sub init_all_cvar_configs {
  29   my ($self) = @_;
  30
  31   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  32 }
  33
  34 sub init_businesses_by {
  35   my ($self) = @_;
  36
  37   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  38 }
  39
  40 sub init_languages_by {
  41   my ($self) = @_;
  42
  43   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  44 }
  45
  46 sub check_objects {
  47   my ($self) = @_;
  48
  49   my $numbercolumn  = $self->controller->profile->get('table') . "number";
  50   my %vcs_by_number = map { ( $_->$numbercolumn => 1 ) } @{ $self->existing_objects };
  51
  52   foreach my $entry (@{ $self->controller->data }) {
  53     my $object = $entry->{object};
  54
  55     $self->check_name($entry);
  56     $self->check_language($entry);
  57     $self->check_business($entry);
  58     $self->check_payment($entry);
  59     $self->handle_cvars($entry);
  60
  61     next if @{ $entry->{errors} };
  62
  63     if ($vcs_by_number{ $object->$numbercolumn }) {
  64       $entry->{object}->$numbercolumn('####');
  65     } else {
  66       $vcs_by_number{ $object->$numbercolumn } = $object;
  67     }
  68   }
  69
  70   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment));
  71   $self->add_cvar_raw_data_columns;
  72 }
  73
  74 sub check_duplicates {
  75   my ($self, %params) = @_;
  76
  77   my $normalizer = sub { my $name = $_[0]; $name =~ s/[\s,\.\-]//g; return $name; };
  78
  79   my %by_name;
  80   if ('check_db' eq $self->controller->profile->get('duplicates')) {
  81     %by_name = map { ( $normalizer->($_->name) => 'db' ) } @{ $self->existing_objects };
  82   }
  83
  84   foreach my $entry (@{ $self->controller->data }) {
  85     next if @{ $entry->{errors} };
  86
  87     my $name = $normalizer->($entry->{object}->name);
  88     if (!$by_name{$name}) {
  89       $by_name{$name} = 'csv';
  90
  91     } else {
  92       push @{ $entry->{errors} }, $by_name{$name} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file');
  93     }
  94   }
  95 }
  96
  97 sub check_name {
  98   my ($self, $entry) = @_;
  99
 100   my $name =  $entry->{object}->name;
 101   $name    =~ s/^\s+//;
 102   $name    =~ s/\s+$//;
 103
 104   return 1 if $name;
 105
 106   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 107   return 0;
 108 }
 109
 110 sub check_language {
 111   my ($self, $entry) = @_;
 112
 113   my $object = $entry->{object};
 114
 115   # Check whether or not language ID is valid.
 116   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 117     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 118     return 0;
 119   }
 120
 121   # Map name to ID if given.
 122   if (!$object->language_id && $entry->{raw_data}->{language}) {
 123     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 124                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 125
 126     if (!$language) {
 127       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 128       return 0;
 129     }
 130
 131     $object->language_id($language->id);
 132   }
 133
 134   return 1;
 135 }
 136
 137 sub check_business {
 138   my ($self, $entry) = @_;
 139
 140   my $object = $entry->{object};
 141
 142   # Check whether or not business ID is valid.
 143   if ($object->business_id && !$self->businesss_by->{id}->{ $object->business_id }) {
 144     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 145     return 0;
 146   }
 147
 148   # Map name to ID if given.
 149   if (!$object->business_id && $entry->{raw_data}->{business}) {
 150     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 151
 152     if (!$business) {
 153       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 154       return 0;
 155     }
 156
 157     $object->business_id($business->id);
 158   }
 159
 160   return 1;
 161 }
 162
 163 sub save_objects {
 164   my ($self, %params) = @_;
 165
 166   my $numbercolumn   = $self->table . 'number';
 167   my $with_number    = [ grep { $_->{object}->$numbercolumn ne '####' } @{ $self->controller->data } ];
 168   my $without_number = [ grep { $_->{object}->$numbercolumn eq '####' } @{ $self->controller->data } ];
 169
 170   map { $_->{object}->$numbercolumn('') } @{ $without_number };
 171
 172   $self->SUPER::save_objects(data => $with_number);
 173   $self->SUPER::save_objects(data => $without_number);
 174 }
 175
 176 sub field_lengths {
 177   return ( name           => 75,
 178            department_1   => 75,
 179            department_2   => 75,
 180            street         => 75,
 181            zipcode        => 10,
 182            city           => 75,
 183            country        => 75,
 184            contact        => 75,
 185            phone          => 30,
 186            fax            => 30,
 187            account_number => 15,
 188            bank_code      => 10,
 189            language       => 5,
 190            username       => 50,
 191            ustid          => 14,
 192            iban           => 100,
 193            bic            => 100,
 194          );
 195 }
 196
 197 sub init_profile {
 198   my ($self) = @_;
 199
 200   my $profile = $self->SUPER::init_profile;
 201   delete @{$profile}{qw(business datevexport language payment salesman salesman_id taxincluded terms)};
 202
 203   return $profile;
 204 }
 205
 206 sub setup_displayable_columns {
 207   my ($self) = @_;
 208
 209   $self->SUPER::setup_displayable_columns;
 210   $self->add_cvar_columns_to_displayable_columns;
 211
 212   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 213                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 214                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 215                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 216                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 217                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 218                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 219                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 220                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 221                                  { name => 'city',              description => $::locale->text('City')                            },
 222                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 223                                  { name => 'country',           description => $::locale->text('Country')                         },
 224                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 225                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 226                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 227                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 228                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 229                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 230                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 231                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 232                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 233                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 234                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 235                                  { name => 'klass',             description => $::locale->text('Preisklasse')                     },
 236                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 237                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 238                                  { name => 'name',              description => $::locale->text('Name')                            },
 239                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 240                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 241                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 242                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 243                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 244                                  { name => 'street',            description => $::locale->text('Street')                          },
 245                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 246                                  { name => 'taxzone_id',        description => $::locale->text('Steuersatz')                      },
 247                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 248                                  { name => 'username',          description => $::locale->text('Username')                        },
 249                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 250                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 251                                 );
 252 }
 253
 254 # TODO:
 255 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 256
 257 1;