SL/Controller/Letter.pm

   1 package SL::Controller::Letter;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use POSIX qw(strftime);
   7 use SL::Controller::Helper::GetModels;
   8 use SL::Controller::Helper::ReportGenerator;
   9 use SL::DB::Letter;
  10 use SL::DB::LetterDraft;
  11 use SL::DB::Employee;
  12 use SL::Helper::Flash qw(flash);
  13 use SL::Helper::CreatePDF;
  14 use SL::Locale::String qw(t8);
  15 use SL::IS;
  16 use SL::ReportGenerator;
  17
  18 use Rose::Object::MakeMethods::Generic (
  19   'scalar --get_set_init' => [ qw(letter all_employees models) ],
  20 );
  21
  22 __PACKAGE__->run_before('check_auth_edit');
  23 __PACKAGE__->run_before('check_auth_report', only => [ qw(list) ]);
  24
  25 use constant TEXT_CREATED_FOR_VALUES => (qw(presskit fax letter));
  26 use constant PAGE_CREATED_FOR_VALUES => (qw(sketch 1 2));
  27
  28 my %sort_columns = (
  29   date                  => t8('Date'),
  30   subject               => t8('Subject'),
  31   letternumber          => t8('Letternumber'),
  32   vc_id                 => t8('Customer'),
  33   contact               => t8('Contact'),
  34 );
  35
  36 sub action_add {
  37   my ($self, %params) = @_;
  38
  39   return if $self->load_letter_draft(%params);
  40
  41   $self->letter->employee_id(SL::DB::Manager::Employee->current->id);
  42   $self->letter->salesman_id(SL::DB::Manager::Employee->current->id);
  43
  44   $self->_display(
  45     title       => t8('Add Letter'),
  46     language_id => $params{language_id},
  47   );
  48 }
  49
  50 sub action_edit {
  51   my ($self, %params) = @_;
  52
  53   return $self->action_add
  54     unless $::form->{letter} || $::form->{draft};
  55
  56   $self->letter(SL::DB::Letter->new_from_draft($::form->{draft}{id}))
  57     if $::form->{draft};
  58
  59   $self->_display(
  60     title  => t8('Edit Letter'),
  61   );
  62 }
  63
  64 sub action_save {
  65   my ($self, %params) = @_;
  66
  67   my $letter = $self->_update;
  68
  69   if (!$self->check_letter($letter)) {
  70     return $self->_display;
  71   }
  72
  73   $self->check_number;
  74
  75   if (!$letter->save) {
  76     flash('error', t8('There was an error saving the letter'));
  77     return $self->_display;
  78   }
  79
  80   flash('info', t8('Letter saved!'));
  81
  82   $self->_display;
  83 }
  84
  85 sub action_update_contacts {
  86   my ($self) = @_;
  87
  88   my $letter = $self->letter;
  89
  90   if (!$self->letter->vc_id || !$self->letter->customer) {
  91     return $self->js
  92       ->replaceWith(
  93         '#letter_cp_id',
  94         SL::Presenter->get->select_tag('letter.cp_id', [], value_key => 'cp_id', title_key => 'full_name')
  95       )
  96       ->render;
  97   }
  98
  99   my $contacts = $letter->customer->contacts;
 100
 101   my $default;
 102   if (   $letter->contact
 103       && $letter->contact->cp_cv_id
 104       && $letter->contact->cp_cv_id == $letter->vc_id) {
 105     $default = $letter->contact->cp_id;
 106   } else {
 107     $default = '';
 108   }
 109
 110   $self->js
 111     ->replaceWith(
 112       '#letter_cp_id',
 113       SL::Presenter->get->select_tag('letter.cp_id', $contacts, default => $default, value_key => 'cp_id', title_key => 'full_name')
 114     )
 115     ->render;
 116 }
 117
 118 sub action_save_letter_draft {
 119   my ($self, %params) = @_;
 120
 121   $self->check_letter;
 122
 123   my $letter_draft = SL::DB::LetterDraft->new_from_letter($self->_update);
 124
 125   if (!$letter_draft->save) {
 126     flash('error', t8('There was an error saving the letter draft'));
 127     return $self->_display;
 128   }
 129
 130   flash('info', t8('Draft for this Letter saved!'));
 131
 132   $self->_display;
 133 }
 134
 135 sub action_delete {
 136   my ($self, %params) = @_;
 137
 138   if (!$self->letter->delete) {
 139     flash('error', t8('An error occured. Letter could not be deleted.'));
 140     return $self->action_update;
 141   }
 142
 143   flash_later('info', t8('Letter deleted'));
 144   $self->redirect_to(action => 'list');
 145 }
 146
 147 sub action_delete_letter_drafts {
 148   my ($self, %params) = @_;
 149
 150   my @ids =  grep { /^checked_(.*)/ && $::form->{$_} } keys %$::form;
 151
 152   SL::DB::Manager::LetterDraft->delete_all(query => [ ids => \@ids ]) if @ids;
 153
 154   $self->redirect_to(action => 'add');
 155 }
 156
 157 sub action_list {
 158   my ($self, %params) = @_;
 159
 160   $self->make_filter_summary;
 161   $self->prepare_report;
 162
 163   my $letters = $self->models->get;
 164   $self->report_generator_list_objects(report => $self->{report}, objects => $letters);
 165
 166 }
 167
 168 sub action_print_letter {
 169   my ($self, $old_form) = @_;
 170
 171   my $display_form = $::form->{display_form} || "display_form";
 172   my $letter       = $self->_update;
 173
 174   $self->export_letter_to_form($letter);
 175   $::form->{formname} = "letter";
 176   $::form->{format} = "pdf";
 177
 178   my $language_saved      = $::form->{language_id};
 179   my $greeting_saved      = $::form->{greeting};
 180   my $cp_id_saved         = $::form->{cp_id};
 181
 182   IS->customer_details(\%::myconfig, $::form);
 183
 184   if (!$cp_id_saved) {
 185     # No contact was selected. Delete all contact variables because
 186     # IS->customer_details() and IR->vendor_details() get the default
 187     # contact anyway.
 188     map({ delete($::form->{$_}); } grep(/^cp_/, keys(%{ $::form })));
 189   }
 190
 191   $::form->{greeting} = $greeting_saved;
 192   $::form->{language_id} = $language_saved;
 193
 194   if ($::form->{cp_id}) {
 195     CT->get_contact(\%::myconfig, $::form);
 196   }
 197
 198   $::form->{cp_contact_formal} = ($::form->{cp_greeting} ? "$::form->{cp_greeting} " : '') . ($::form->{cp_givenname} ? "$::form->{cp_givenname} " : '') . $::form->{cp_name};
 199
 200   $::form->get_employee_data('prefix' => 'employee', 'id' => $letter->{employee_id});
 201   $::form->get_employee_data('prefix' => 'salesman', 'id' => $letter->{salesman_id});
 202
 203   my %create_params = (
 204     template  => scalar(SL::Helper::CreatePDF->find_template(
 205       name        => 'letter',
 206       printer_id  => $::form->{printer_id},
 207       language_id => $::form->{language_id},
 208       formname    => 'letter',
 209       format      => 'pdf',
 210     )),
 211     variables => $::form,
 212     return    => 'file_name',
 213   );
 214   my $pdf_file_name;
 215   eval {
 216     $pdf_file_name = SL::Helper::CreatePDF->create_pdf(%create_params);
 217
 218     # set some form defaults for printing webdav copy variables
 219     if ( $::form->{media} eq 'email') {
 220       my $mail             = Mailer->new;
 221       my $signature        = $::myconfig{signature};
 222       $mail->{$_}          = $::form->{$_}               for qw(cc subject message bcc to);
 223       $mail->{from}        = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 224       $mail->{fileid}      = time() . '.' . $$ . '.';
 225       $mail->{attachments} =  [{ "filename" => $pdf_file_name,
 226                                  "name"     => $::form->{attachment_name} }];
 227       $mail->{message}    .=  "\n-- \n$signature";
 228       $mail->{message}     =~ s/\r//g;
 229
 230       # copy_file_to_webdav was already done via io.pl -> edit_e_mail
 231       my $err = $mail->send;
 232       return !$err;
 233     }
 234
 235     if (!$::form->{printer_id} || $::form->{media} eq 'screen') {
 236
 237       my $file = IO::File->new($pdf_file_name, 'r') || croak("Cannot open file '$pdf_file_name'");
 238       my $size = -s $pdf_file_name;
 239       my $content_type    =  'application/pdf';
 240       my $attachment_name =  $::form->generate_attachment_filename;
 241       $attachment_name    =~ s:.*//::g;
 242
 243       print $::form->create_http_response(content_type        => $content_type,
 244                                           content_disposition => 'attachment; filename="' . $attachment_name . '"',
 245                                           content_length      => $size);
 246
 247       $::locale->with_raw_io(\*STDOUT, sub { print while <$file> });
 248       $file->close;
 249
 250       Common::copy_file_to_webdav_folder($::form) if $::instance_conf->get_webdav_documents;
 251       unlink $pdf_file_name;
 252       return 1;
 253     }
 254
 255     my $printer = SL::DB::Printer->new(id => $::form->{printer_id})->load;
 256     my $command = SL::Template::create(type => 'ShellCommand', form => Form->new(''))->parse($printer->printer_command);
 257
 258     open my $out, '|-', $command or die $!;
 259     binmode $out;
 260     print $out scalar(read_file($pdf_file_name));
 261     close $out;
 262     Common::copy_file_to_webdav_folder($::form) if $::instance_conf->get_webdav_documents;
 263
 264     flash_later('info', t8('The documents have been sent to the printer \'#1\'.', $printer->printer_description));
 265     $self->redirect_to(action => 'edit', id => $letter->{id}, 'printer_id' => $::form->{printer_id});
 266     1;
 267   } or do {
 268     unlink $pdf_file_name;
 269     $::form->error(t8("Creating the PDF failed:") . " " . $@);
 270   };
 271
 272 }
 273
 274 sub action_update {
 275   my ($self, $name_selected) = @_;
 276
 277   $self->_display(
 278     letter => $self->_update,
 279   );
 280 }
 281
 282 sub action_skip_draft {
 283   my ($self) = @_;
 284   $self->action_add(skip_drafts => 1);
 285 }
 286
 287 sub action_delete_drafts {
 288   my ($self) = @_;
 289   delete_letter_drafts();
 290   $self->action_add(skip_drafts => 1);
 291 }
 292
 293 sub _display {
 294   my ($self, %params) = @_;
 295
 296   my $letter = $self->letter;
 297
 298   require 'bin/mozilla/io.pl';
 299
 300  $params{title} ||= t8('Edit Letter');
 301
 302   $::form->{type}             = 'letter';   # needed for print_options
 303   $::form->{vc}               = 'customer'; # needs to be for _get_contacts...
 304
 305   $::request->layout->add_javascripts('customer_or_vendor_selection.js');
 306   $::request->layout->add_javascripts('edit_part_window.js');
 307
 308   $::form->{language_id} ||= $params{language_id};
 309
 310   $self->render('letter/edit',
 311     %params,
 312     TCF           => [ map { key => $_, value => t8(ucfirst $_) }, TEXT_CREATED_FOR_VALUES() ],
 313     PCF           => [ map { key => $_, value => t8(ucfirst $_) }, PAGE_CREATED_FOR_VALUES() ],
 314     letter        => $letter,
 315     employees     => $self->all_employees,
 316     print_options => print_options(inline => 1),
 317   );
 318 }
 319
 320 sub _update {
 321   my ($self, %params) = @_;
 322
 323   my $letter = $self->letter;
 324
 325   $self->check_date;
 326   $self->set_greetings;
 327
 328   return $letter;
 329 }
 330
 331 sub prepare_report {
 332   my ($self) = @_;
 333
 334   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 335   $self->{report} = $report;
 336
 337   my @columns  = qw(date subject letternumber vc_id contact date);
 338   my @sortable = qw(date subject letternumber vc_id contact date);
 339
 340   my %column_defs = (
 341     date                  => { text => t8('Date'),         sub => sub { $_[0]->date_as_date } },
 342     subject               => { text => t8('Subject'),      sub => sub { $_[0]->subject },
 343                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 344     letternumber          => { text => t8('Letternumber'), sub => sub { $_[0]->letternumber },
 345                                obj_link => sub { $self->url_for(action => 'edit', 'letter.id' => $_[0]->id, callback => $self->models->get_callback) }  },
 346     vc_id                 => { text => t8('Customer'),      sub => sub { $_[0]->customer->displayable_name } },
 347     contact               => { text => t8('Contact'),       sub => sub { $_[0]->contact ? $_[0]->contact->full_name : '' } },
 348   );
 349
 350   $column_defs{$_}{text} = $sort_columns{$_} for keys %column_defs;
 351
 352   $report->set_options(
 353     std_column_visibility => 1,
 354     controller_class      => 'Letter',
 355     output_format         => 'HTML',
 356     top_info_text         => t8('Letters'),
 357     title                 => t8('Letters'),
 358     allow_pdf_export      => 1,
 359     allow_csv_export      => 1,
 360   );
 361
 362   $report->set_columns(%column_defs);
 363   $report->set_column_order(@columns);
 364   $report->set_export_options(qw(list filter));
 365   $report->set_options_from_form;
 366
 367   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
 368   $self->models->finalize;
 369   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 370
 371   $report->set_options(
 372     raw_top_info_text    => $self->render('letter/report_top',    { output => 0 }),
 373     raw_bottom_info_text => $self->render('letter/report_bottom', { output => 0 }, models => $self->models),
 374     attachment_basename  => t8('letters_list') . strftime('_%Y%m%d', localtime time),
 375   );
 376 }
 377
 378 sub make_filter_summary {
 379   my ($self) = @_;
 380
 381   my $filter = $::form->{filter} || {};
 382   my @filter_strings;
 383
 384   my $employee = $filter->{employee_id} ? SL::DB::Employee->new(id => $filter->{employee_id})->load->name : '';
 385   my $salesman = $filter->{salesman_id} ? SL::DB::Employee->new(id => $filter->{salesman_id})->load->name : '';
 386
 387   my @filters = (
 388     [ $filter->{"letternumber:substr::ilike"},  t8('Number')     ],
 389     [ $filter->{"subject:substr::ilike"},       t8('Subject')    ],
 390     [ $filter->{"body:substr::ilike"},          t8('Body')       ],
 391     [ $filter->{"date:date::ge"},               t8('From Date')  ],
 392     [ $filter->{"date:date::le"},               t8('To Date')    ],
 393     [ $employee,                                t8('Employee')   ],
 394     [ $salesman,                                t8('Salesman')   ],
 395   );
 396
 397   my %flags = (
 398   );
 399   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 400
 401   for (@flags) {
 402     push @filter_strings, $_ if $_;
 403   }
 404   for (@filters) {
 405     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 406   }
 407
 408   $self->{filter_summary} = join ', ', @filter_strings;
 409 }
 410
 411 sub e_mail {
 412   my $letter = _update();
 413
 414   $letter->check_number;
 415   $letter->save;
 416
 417   $::form->{formname} = "letter";
 418   $letter->export_to($::form);
 419
 420   $::form->{id} = $letter->{id};
 421   edit_e_mail();
 422 }
 423
 424 sub load_letter_draft {
 425   my ($self, %params) = @_;
 426
 427   return 0 if $params{skip_drafts};
 428
 429   my $letter_drafts = SL::DB::Manager::LetterDraft->get_all;
 430
 431   return unless @$letter_drafts;
 432
 433   $self->render('letter/load_drafts',
 434     title         => t8('Letter Draft'),
 435     LETTER_DRAFTS => $letter_drafts,
 436   );
 437
 438   return 1;
 439 }
 440
 441 sub check_date {
 442   my ($self) = @_;
 443   my $letter = $self->letter;
 444
 445   return unless $letter;
 446   return if $letter->date;
 447
 448   $letter->date(DateTime->today)
 449 }
 450
 451 sub check_letter {
 452   my ($self, $letter) = @_;
 453
 454   $letter ||= $self->letter;
 455
 456   my $error;
 457
 458   if (!$letter->subject) {
 459     flash('error', t8('The subject is missing.'));
 460     $error = 1;
 461   }
 462   if (!$letter->body) {
 463     flash('error', t8('The body is missing.'));
 464     $error = 1;
 465   }
 466   if (!$letter->employee_id) {
 467     flash('error', t8('The employee is missing.'));
 468     $error = 1;
 469   }
 470
 471   return !$error;
 472 }
 473
 474 sub check_number {
 475   my ($self, $letter) = @_;
 476
 477   $letter ||= $self->letter;
 478
 479   return if $letter->letternumber;
 480
 481   $letter->letternumber(SL::TransNumber->new(type => 'letter', id => $self->{id}, number => $self->{letternumber})->create_unique);
 482 }
 483
 484 sub set_greetings {
 485   my ($self) = @_;
 486   my $letter = $self->letter;
 487
 488   return unless $letter;
 489   return if $letter->greeting;
 490
 491   $letter->greeting(t8('Dear Sir or Madam,'));
 492 }
 493
 494 sub export_letter_to_form {
 495   my ($self, $letter) = @_;
 496   # nope, not pretty.
 497
 498   $letter ||= $self->letter;
 499
 500   for ($letter->meta->columns) {
 501     if ((ref $_) =~ /Date/i) {
 502       $::form->{$_->name} = $letter->$_->to_kivitendo;
 503     } else {
 504       $::form->{$_->name} = $letter->$_;
 505     }
 506   }
 507 }
 508
 509 sub init_letter {
 510   my ($self) = @_;
 511
 512   my $letter      = SL::DB::Manager::Letter->find_by_or_create(id => $::form->{letter}{id} || 0)
 513                                            ->assign_attributes(%{ $::form->{letter} });
 514
 515   if ($letter->cp_id) {
 516 #     $letter->vc_id($letter->contact->cp_cv_id);
 517       # contacts don't have language_id yet
 518 #     $letter->greeting(GenericTranslations->get(
 519 #       translation_type => 'greetings::' . ($letter->contact->cp_gender eq 'f' ? 'female' : 'male'),
 520 #       language_id      => $letter->contact->language_id,
 521 #       allow_fallback   => 1
 522 #     ));
 523   }
 524
 525   $letter;
 526 }
 527
 528 sub init_models {
 529   my ($self) = @_;
 530
 531   SL::Controller::Helper::GetModels->new(
 532     controller   => $self,
 533     model        => 'Letter',
 534     sorted       => {
 535       _default     => {
 536         by           => 'letternumber',
 537         dir          => 1,
 538       },
 539       %sort_columns,
 540     },
 541     with_objects => [ 'contact', 'salesman', 'employee' ],
 542   );
 543 }
 544
 545 sub init_all_employees {
 546   SL::DB::Manager::Employee->get_all(query => [ deleted => 0 ]);
 547 }
 548
 549 sub check_auth_edit {
 550   $::auth->assert('sales_letter_edit');
 551 }
 552
 553 sub check_auth_report {
 554   $::auth->assert('sales_letter_report');
 555 }
 556
 557 1;
 558
 559 __END__
 560
 561 =encoding utf-8
 562
 563 =head1 NAME
 564
 565 SL::Controller::Letter - Letters CRUD and printing
 566
 567 =head1 DESCRIPTION
 568
 569 Simple letter CRUD controller with drafting capabilities.
 570
 571 =head1 TODO
 572
 573   Customer/Vendor switch for dealing with vendor letters
 574
 575 copy to webdav is crap
 576
 577 customer/vendor stuff
 578
 579 =head1 AUTHOR
 580
 581 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 582
 583 =cut