SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash;
   7 use SL::Presenter;
   8 use SL::Locale::String;
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Form;
  12 use SL::Webdav;
  13 use SL::Template;
  14
  15 use SL::DB::Order;
  16 use SL::DB::Customer;
  17 use SL::DB::Vendor;
  18 use SL::DB::TaxZone;
  19 use SL::DB::Employee;
  20 use SL::DB::Project;
  21 use SL::DB::Default;
  22 use SL::DB::Unit;
  23 use SL::DB::Price;
  24 use SL::DB::PriceFactor;
  25 use SL::DB::Part;
  26 use SL::DB::Printer;
  27 use SL::DB::Language;
  28
  29 use SL::Helper::DateTime;
  30 use SL::Helper::CreatePDF qw(:all);
  31 use SL::Helper::PrintOptions;
  32
  33 use SL::Controller::Helper::GetModels;
  34
  35 use List::Util qw(max first);
  36 use List::MoreUtils qw(none pairwise first_index);
  37 use English qw(-no_match_vars);
  38 use File::Spec;
  39
  40 use Rose::Object::MakeMethods::Generic
  41 (
  42  scalar => [ qw(item_ids_to_delete) ],
  43  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  44 );
  45
  46
  47 # safety
  48 __PACKAGE__->run_before('_check_auth');
  49
  50 __PACKAGE__->run_before('_recalc',
  51                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  52
  53 __PACKAGE__->run_before('_get_unalterable_data',
  54                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  55
  56 #
  57 # actions
  58 #
  59
  60 sub action_add {
  61   my ($self) = @_;
  62
  63   $self->order->transdate(DateTime->now_local());
  64   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  65
  66   $self->_pre_render();
  67   $self->render(
  68     'order/form',
  69     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  70            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  71            : '',
  72     %{$self->{template_args}}
  73   );
  74 }
  75
  76 sub action_edit {
  77   my ($self) = @_;
  78
  79   $self->_load_order;
  80   $self->_recalc();
  81   $self->_pre_render();
  82   $self->render(
  83     'order/form',
  84     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  85            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  86            : '',
  87     %{$self->{template_args}}
  88   );
  89 }
  90
  91 sub action_delete {
  92   my ($self) = @_;
  93
  94   my $errors = $self->_delete();
  95
  96   if (scalar @{ $errors }) {
  97     $self->js->flash('error', $_) foreach @{ $errors };
  98     return $self->js->render();
  99   }
 100
 101   flash_later('info', $::locale->text('The order has been deleted'));
 102   my @redirect_params = (
 103     action => 'edit',
 104     type   => $self->type,
 105   );
 106
 107   $self->redirect_to(@redirect_params);
 108 }
 109
 110 sub action_save {
 111   my ($self) = @_;
 112
 113   my $errors = $self->_save();
 114
 115   if (scalar @{ $errors }) {
 116     $self->js->flash('error', $_) foreach @{ $errors };
 117     return $self->js->render();
 118   }
 119
 120   flash_later('info', $::locale->text('The order has been saved'));
 121   my @redirect_params = (
 122     action => 'edit',
 123     type   => $self->type,
 124     id     => $self->order->id,
 125   );
 126
 127   $self->redirect_to(@redirect_params);
 128 }
 129
 130 sub action_print {
 131   my ($self) = @_;
 132
 133   my $format      = $::form->{print_options}->{format};
 134   my $media       = $::form->{print_options}->{media};
 135   my $formname    = $::form->{print_options}->{formname};
 136   my $copies      = $::form->{print_options}->{copies};
 137   my $groupitems  = $::form->{print_options}->{groupitems};
 138
 139   # only pdf by now
 140   if (none { $format eq $_ } qw(pdf)) {
 141     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 142   }
 143
 144   # only screen or printer by now
 145   if (none { $media eq $_ } qw(screen printer)) {
 146     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 147   }
 148
 149   my $language;
 150   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 151
 152   my $form = Form->new;
 153   $form->{ordnumber} = $self->order->ordnumber;
 154   $form->{type}      = $self->type;
 155   $form->{format}    = $format;
 156   $form->{formname}  = $formname;
 157   $form->{language}  = '_' . $language->template_code if $language;
 158   my $pdf_filename   = $form->generate_attachment_filename();
 159
 160   my $pdf;
 161   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 162                                                   formname   => $formname,
 163                                                   language   => $language,
 164                                                   groupitems => $groupitems });
 165   if (scalar @errors) {
 166     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 167   }
 168
 169   if ($media eq 'screen') {
 170     # screen/download
 171     my $sfile = SL::SessionFile::Random->new(mode => "w");
 172     $sfile->fh->print($pdf);
 173     $sfile->fh->close;
 174
 175     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 176     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 177
 178     $self->js
 179     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 180     ->flash('info', t8('The PDF has been created'));
 181
 182   } elsif ($media eq 'printer') {
 183     # printer
 184     my $printer_id = $::form->{print_options}->{printer_id};
 185     my $printer;
 186     $printer = SL::DB::Printer->new(id => $printer_id)->load if $printer_id;
 187     if (!$printer) {
 188       return $self->js->flash('error', t8('Printer not found.'))->render;
 189     }
 190
 191     my $command = SL::Template::create(type => 'ShellCommand', form => Form->new(''))->parse($printer->printer_command);
 192
 193     for my $i (1 .. $copies) {
 194       open my $out, '|-', $command or die $!;
 195       binmode $out;
 196       print $out $pdf;
 197       close $out;
 198     }
 199
 200     $self->js->flash('info', t8('The PDF has been printed'));
 201   }
 202
 203   # copy file to webdav folder
 204   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 205     my $webdav = SL::Webdav->new(
 206       type     => $self->type,
 207       number   => $self->order->ordnumber,
 208     );
 209     my $webdav_file = SL::Webdav::File->new(
 210       webdav   => $webdav,
 211       filename => $pdf_filename,
 212     );
 213     eval {
 214       $webdav_file->store(data => \$pdf);
 215       1;
 216     } or do {
 217       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 218     }
 219   }
 220
 221   $self->js->render;
 222 }
 223
 224 sub action_download_pdf {
 225   my ($self) = @_;
 226
 227   my $key = $::form->{key};
 228   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 229   return $self->send_file(
 230     $tmp_filename,
 231     type => 'application/pdf',
 232     name => $::form->{pdf_filename},
 233   );
 234 }
 235
 236 sub action_show_email_dialog {
 237   my ($self) = @_;
 238
 239   my $cv_method = $self->cv;
 240
 241   if (!$self->order->$cv_method) {
 242     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 243                     ->render($self);
 244   }
 245
 246   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 247   $self->{email}->{to} ||= $self->order->$cv_method->email;
 248   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 249   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 250   # Todo: get addresses from shipto, if any
 251
 252   my $form = Form->new;
 253   $form->{ordnumber} = $self->order->ordnumber;
 254   $form->{formname}  = $self->type;
 255   $form->{type}      = $self->type;
 256   $form->{language} = 'de';
 257   $form->{format}   = 'pdf';
 258
 259   $self->{email}->{subject}             = $form->generate_email_subject();
 260   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 261   $self->{email}->{message}             = $form->create_email_signature();
 262
 263   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 264   $self->js
 265       ->run('kivi.Order.show_email_dialog', $dialog_html)
 266       ->reinit_widgets
 267       ->render($self);
 268 }
 269
 270 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 271 sub action_send_email {
 272   my ($self) = @_;
 273
 274   my $mail      = Mailer->new;
 275   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 276   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 277
 278   my $pdf;
 279   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 280   if (scalar @errors) {
 281     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 282   }
 283
 284   $mail->{attachments} = [{ "content" => $pdf,
 285                             "name"    => $::form->{email}->{attachment_filename} }];
 286
 287   if (my $err = $mail->send) {
 288     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 289                     ->render($self);
 290   }
 291
 292   # internal notes
 293   my $intnotes = $self->order->intnotes;
 294   $intnotes   .= "\n\n" if $self->order->intnotes;
 295   $intnotes   .= t8('[email]')                                                                                        . "\n";
 296   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 297   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 298   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 299   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 300   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 301   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 302
 303   $self->js
 304       ->val('#order_intnotes', $intnotes)
 305       ->run('kivi.Order.close_email_dialog')
 306       ->render($self);
 307 }
 308
 309 sub action_save_and_delivery_order {
 310   my ($self) = @_;
 311
 312   my $errors = $self->_save();
 313
 314   if (scalar @{ $errors }) {
 315     $self->js->flash('error', $_) foreach @{ $errors };
 316     return $self->js->render();
 317   }
 318   flash_later('info', $::locale->text('The order has been saved'));
 319
 320   my @redirect_params = (
 321     controller => 'oe.pl',
 322     action     => 'oe_delivery_order_from_order',
 323     id         => $self->order->id,
 324   );
 325
 326   $self->redirect_to(@redirect_params);
 327 }
 328
 329 sub action_customer_vendor_changed {
 330   my ($self) = @_;
 331
 332   my $cv_method = $self->cv;
 333
 334   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 335     $self->js->show('#cp_row');
 336   } else {
 337     $self->js->hide('#cp_row');
 338   }
 339
 340   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 341     $self->js->show('#shipto_row');
 342   } else {
 343     $self->js->hide('#shipto_row');
 344   }
 345
 346   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 347
 348   if ($self->order->is_sales) {
 349     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 350                               ? $self->order->$cv_method->taxincluded_checked
 351                               : $::myconfig{taxincluded_checked});
 352   }
 353
 354   $self->order->payment_id($self->order->$cv_method->payment_id);
 355   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 356
 357   $self->_recalc();
 358
 359   $self->js
 360     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 361     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 362     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 363     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 364     ->val(        '#order_payment_id',       $self->order->payment_id)
 365     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 366     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 367     ->focus(      '#order_' . $self->cv . '_id');
 368
 369   $self->_js_redisplay_amounts_and_taxes;
 370   $self->js->render();
 371 }
 372
 373 sub action_unit_changed {
 374   my ($self) = @_;
 375
 376   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 377   my $item = $self->order->items_sorted->[$idx];
 378
 379   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 380   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 381
 382   $self->_recalc();
 383
 384   $self->js
 385     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 386   $self->_js_redisplay_linetotals;
 387   $self->_js_redisplay_amounts_and_taxes;
 388   $self->js->render();
 389 }
 390
 391 sub action_add_item {
 392   my ($self) = @_;
 393
 394   my $form_attr = $::form->{add_item};
 395
 396   return unless $form_attr->{parts_id};
 397
 398   my $item = _new_item($self->order, $form_attr);
 399   $self->order->add_items($item);
 400
 401   $self->_recalc();
 402
 403   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 404   my $row_as_html = $self->p->render('order/tabs/_row',
 405                                      ITEM              => $item,
 406                                      ID                => $item_id,
 407                                      ALL_PRICE_FACTORS => $self->all_price_factors
 408   );
 409
 410   $self->js
 411     ->append('#row_table_id', $row_as_html)
 412     ->val('.add_item_input', '')
 413     ->run('kivi.Order.init_row_handlers')
 414     ->run('kivi.Order.row_table_scroll_down')
 415     ->run('kivi.Order.renumber_positions')
 416     ->focus('#add_item_parts_id_name');
 417
 418   $self->_js_redisplay_amounts_and_taxes;
 419   $self->js->render();
 420 }
 421
 422 sub action_show_multi_items_dialog {
 423   require SL::DB::PartsGroup;
 424   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 425                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 426 }
 427
 428 sub action_multi_items_update_result {
 429   my $max_count = 100;
 430
 431   $::form->{multi_items}->{filter}->{obsolete} = 0;
 432
 433   my $count = $_[0]->multi_items_models->count;
 434
 435   if ($count == 0) {
 436     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 437     $_[0]->render($text, { layout => 0 });
 438   } elsif ($count > $max_count) {
 439     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 440     $_[0]->render($text, { layout => 0 });
 441   } else {
 442     my $multi_items = $_[0]->multi_items_models->get;
 443     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 444                   multi_items => $multi_items);
 445   }
 446 }
 447
 448 sub action_add_multi_items {
 449   my ($self) = @_;
 450
 451   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 452   return $self->js->render() unless scalar @form_attr;
 453
 454   my @items;
 455   foreach my $attr (@form_attr) {
 456     push @items, _new_item($self->order, $attr);
 457   }
 458   $self->order->add_items(@items);
 459
 460   $self->_recalc();
 461
 462   foreach my $item (@items) {
 463     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 464     my $row_as_html = $self->p->render('order/tabs/_row',
 465                                        ITEM              => $item,
 466                                        ID                => $item_id,
 467                                        ALL_PRICE_FACTORS => $self->all_price_factors
 468     );
 469
 470     $self->js->append('#row_table_id', $row_as_html);
 471   }
 472
 473   $self->js
 474     ->run('kivi.Order.close_multi_items_dialog')
 475     ->run('kivi.Order.init_row_handlers')
 476     ->run('kivi.Order.row_table_scroll_down')
 477     ->run('kivi.Order.renumber_positions')
 478     ->focus('#add_item_parts_id_name');
 479
 480   $self->_js_redisplay_amounts_and_taxes;
 481   $self->js->render();
 482 }
 483
 484 sub action_recalc_amounts_and_taxes {
 485   my ($self) = @_;
 486
 487   $self->_recalc();
 488
 489   $self->_js_redisplay_linetotals;
 490   $self->_js_redisplay_amounts_and_taxes;
 491   $self->js->render();
 492 }
 493
 494 sub action_reorder_items {
 495   my ($self) = @_;
 496
 497   my %sort_keys = (
 498     partnumber  => sub { $_[0]->part->partnumber },
 499     description => sub { $_[0]->description },
 500     qty         => sub { $_[0]->qty },
 501     sellprice   => sub { $_[0]->sellprice },
 502     discount    => sub { $_[0]->discount },
 503   );
 504
 505   my $method = $sort_keys{$::form->{order_by}};
 506   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 507   if ($::form->{sort_dir}) {
 508     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 509   } else {
 510     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 511   }
 512   $self->js
 513     ->run('kivi.Order.redisplay_items', \@to_sort)
 514     ->render;
 515 }
 516
 517 sub action_price_popup {
 518   my ($self) = @_;
 519
 520   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 521   my $item = $self->order->items_sorted->[$idx];
 522
 523   $self->render_price_dialog($item);
 524 }
 525
 526 sub action_get_item_longdescription {
 527   my $longdescription;
 528
 529   if ($::form->{item_id}) {
 530     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 531   } elsif ($::form->{parts_id}) {
 532     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 533   }
 534   $_[0]->render(\ $longdescription, { type => 'text' });
 535 }
 536
 537
 538 sub _js_redisplay_linetotals {
 539   my ($self) = @_;
 540
 541   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 542   $self->js
 543     ->run('kivi.Order.redisplay_linetotals', \@data);
 544 }
 545
 546 sub _js_redisplay_amounts_and_taxes {
 547   my ($self) = @_;
 548
 549   if (scalar @{ $self->{taxes} }) {
 550     $self->js->show('#taxincluded_row_id');
 551   } else {
 552     $self->js->hide('#taxincluded_row_id');
 553   }
 554
 555   if ($self->order->taxincluded) {
 556     $self->js->hide('#subtotal_row_id');
 557   } else {
 558     $self->js->show('#subtotal_row_id');
 559   }
 560
 561   $self->js
 562     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 563     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 564     ->remove('.tax_row')
 565     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 566 }
 567
 568 #
 569 # helpers
 570 #
 571
 572 sub init_valid_types {
 573   [ _sales_order_type(), _purchase_order_type() ];
 574 }
 575
 576 sub init_type {
 577   my ($self) = @_;
 578
 579   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 580     die "Not a valid type for order";
 581   }
 582
 583   $self->type($::form->{type});
 584 }
 585
 586 sub init_cv {
 587   my ($self) = @_;
 588
 589   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 590          : $self->type eq _purchase_order_type() ? 'vendor'
 591          : die "Not a valid type for order";
 592
 593   return $cv;
 594 }
 595
 596 sub init_p {
 597   SL::Presenter->get;
 598 }
 599
 600 sub init_order {
 601   $_[0]->_make_order;
 602 }
 603
 604 sub init_multi_items_models {
 605   SL::Controller::Helper::GetModels->new(
 606     controller     => $_[0],
 607     model          => 'Part',
 608     with_objects   => [ qw(unit_obj) ],
 609     disable_plugin => 'paginated',
 610     source         => $::form->{multi_items},
 611     sorted         => {
 612       _default    => {
 613         by  => 'partnumber',
 614         dir => 1,
 615       },
 616       partnumber  => t8('Partnumber'),
 617       description => t8('Description')}
 618   );
 619 }
 620
 621 sub init_all_price_factors {
 622   SL::DB::Manager::PriceFactor->get_all;
 623 }
 624
 625 sub _check_auth {
 626   my ($self) = @_;
 627
 628   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 629
 630   my $right   = $right_for->{ $self->type };
 631   $right    ||= 'DOES_NOT_EXIST';
 632
 633   $::auth->assert($right);
 634 }
 635
 636 sub build_contact_select {
 637   my ($self) = @_;
 638
 639   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 640                        value_key  => 'cp_id',
 641                        title_key  => 'full_name_dep',
 642                        default    => $self->order->cp_id,
 643                        with_empty => 1,
 644                        style      => 'width: 300px',
 645   );
 646 }
 647
 648 sub build_shipto_select {
 649   my ($self) = @_;
 650
 651   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 652                        value_key  => 'shipto_id',
 653                        title_key  => 'displayable_id',
 654                        default    => $self->order->shipto_id,
 655                        with_empty => 1,
 656                        style      => 'width: 300px',
 657   );
 658 }
 659
 660 sub build_tax_rows {
 661   my ($self) = @_;
 662
 663   my $rows_as_html;
 664   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 665     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 666   }
 667   return $rows_as_html;
 668 }
 669
 670
 671 sub render_price_dialog {
 672   my ($self, $record_item) = @_;
 673
 674   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 675
 676   $self->js
 677     ->run(
 678       'kivi.io.price_chooser_dialog',
 679       t8('Available Prices'),
 680       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 681     )
 682     ->reinit_widgets;
 683
 684 #   if (@errors) {
 685 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 686 #     $self->js->show('#dialog_flash_error');
 687 #   }
 688
 689   $self->js->render;
 690 }
 691
 692 sub _load_order {
 693   my ($self) = @_;
 694
 695   return if !$::form->{id};
 696
 697   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 698 }
 699
 700 sub _make_order {
 701   my ($self) = @_;
 702
 703   # add_items adds items to an order with no items for saving, but they cannot
 704   # be retrieved via items until the order is saved. Adding empty items to new
 705   # order here solves this problem.
 706   my $order;
 707   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 708   $order ||= SL::DB::Order->new(orderitems => []);
 709
 710   my $form_orderitems = delete $::form->{order}->{orderitems};
 711   $order->assign_attributes(%{$::form->{order}});
 712
 713   # remove deleted items
 714   $self->item_ids_to_delete([]);
 715   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 716     my $item = $order->orderitems->[$idx];
 717     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 718       splice @{$order->orderitems}, $idx, 1;
 719       push @{$self->item_ids_to_delete}, $item->id;
 720     }
 721   }
 722
 723   my @items;
 724   my $pos = 1;
 725   foreach my $form_attr (@{$form_orderitems}) {
 726     my $item = _make_item($order, $form_attr);
 727     $item->position($pos);
 728     push @items, $item;
 729     $pos++;
 730   }
 731   $order->add_items(grep {!$_->id} @items);
 732
 733   return $order;
 734 }
 735
 736
 737 # Make item objects from form values. For items already existing read from db.
 738 # Create a new item else. And assign attributes.
 739 sub _make_item {
 740   my ($record, $attr) = @_;
 741
 742   my $item;
 743   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 744
 745   my $is_new = !$item;
 746
 747   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 748   # they cannot be retrieved via custom_variables until the order/orderitem is
 749   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 750   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 751
 752   $item->assign_attributes(%$attr);
 753   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 754
 755   return $item;
 756 }
 757
 758 sub _new_item {
 759   my ($record, $attr) = @_;
 760
 761   my $item = SL::DB::OrderItem->new;
 762   $item->assign_attributes(%$attr);
 763
 764   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 765   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 766
 767   $item->unit($part->unit) if !$item->unit;
 768
 769   my $price_src;
 770   if ($item->sellprice) {
 771     $price_src = $price_source->price_from_source("");
 772     $price_src->price($item->sellprice);
 773   } else {
 774     $price_src = $price_source->best_price
 775            ? $price_source->best_price
 776            : $price_source->price_from_source("");
 777     $price_src->price(0) if !$price_source->best_price;
 778   }
 779
 780   my $discount_src;
 781   if ($item->discount) {
 782     $discount_src = $price_source->discount_from_source("");
 783     $discount_src->discount($item->discount);
 784   } else {
 785     $discount_src = $price_source->best_discount
 786                   ? $price_source->best_discount
 787                   : $price_source->discount_from_source("");
 788     $discount_src->discount(0) if !$price_source->best_discount;
 789   }
 790
 791   my %new_attr;
 792   $new_attr{part}                   = $part;
 793   $new_attr{description}            = $part->description     if ! $item->description;
 794   $new_attr{qty}                    = 1.0                    if ! $item->qty;
 795   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
 796   $new_attr{sellprice}              = $price_src->price;
 797   $new_attr{discount}               = $discount_src->discount;
 798   $new_attr{active_price_source}    = $price_src;
 799   $new_attr{active_discount_source} = $discount_src;
 800
 801   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 802
 803   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 804   # they cannot be retrieved via custom_variables until the order/orderitem is
 805   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 806   $new_attr{custom_variables} = [];
 807
 808   $item->assign_attributes(%new_attr);
 809
 810   return $item;
 811 }
 812
 813 sub _recalc {
 814   my ($self) = @_;
 815
 816   # bb: todo: currency later
 817   $self->order->currency_id($::instance_conf->get_currency_id());
 818
 819   my %pat = $self->order->calculate_prices_and_taxes();
 820   $self->{taxes} = [];
 821   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 822     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 823
 824     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 825     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 826                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 827                                 tax       => $tax });
 828   }
 829
 830   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 831 }
 832
 833
 834 sub _get_unalterable_data {
 835   my ($self) = @_;
 836
 837   foreach my $item (@{ $self->order->items }) {
 838     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 839     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 840     foreach my $var (@{ $item->cvars_by_config }) {
 841       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 842     }
 843     $item->parse_custom_variable_values;
 844   }
 845 }
 846
 847
 848 sub _delete {
 849   my ($self) = @_;
 850
 851   my $errors = [];
 852   my $db = $self->order->db;
 853
 854   $db->do_transaction(
 855     sub {
 856       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 857       $self->order->delete;
 858       my $spool = $::lx_office_conf{paths}->{spool};
 859       unlink map { "$spool/$_" } @spoolfiles if $spool;
 860
 861       1;
 862   }) || push(@{$errors}, $db->error);
 863
 864   return $errors;
 865 }
 866
 867
 868 sub _save {
 869   my ($self) = @_;
 870
 871   my $errors = [];
 872   my $db = $self->order->db;
 873
 874   $db->do_transaction(
 875     sub {
 876       SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 877       $self->order->save(cascade => 1);
 878   }) || push(@{$errors}, $db->error);
 879
 880   return $errors;
 881 }
 882
 883
 884 sub _pre_render {
 885   my ($self) = @_;
 886
 887   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 888   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 889   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 890                                                                                        deleted => 0 ] ],
 891                                                                     sort_by => 'name');
 892   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 893                                                                                        deleted => 0 ] ],
 894                                                                     sort_by => 'name');
 895   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 896                                                                                       active => 1 ] ],
 897                                                                    sort_by => 'projectnumber');
 898   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 899   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 900
 901   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 902
 903   my $print_form = Form->new('');
 904   $print_form->{type}      = $self->type;
 905   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 906   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 907   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 908     form => $print_form,
 909     options => {dialog_name_prefix => 'print_options.',
 910                 show_headers       => 1,
 911                 no_queue           => 1,
 912                 no_postscript      => 1,
 913                 no_opendocument    => 1,
 914                 no_html            => 1},
 915   );
 916
 917   foreach my $item (@{$self->order->orderitems}) {
 918     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 919     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 920     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 921   }
 922
 923   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 924     my $webdav = SL::Webdav->new(
 925       type     => $self->type,
 926       number   => $self->order->ordnumber,
 927     );
 928     my $webdav_path = $webdav->webdav_path;
 929     my @all_objects = $webdav->get_all_objects;
 930     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
 931                                                     type => t8('File'),
 932                                                     link => File::Spec->catdir($webdav_path, $_->filename),
 933                                                 } } @all_objects;
 934   }
 935
 936   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase kivi.Order ckeditor/ckeditor ckeditor/adapters/jquery);
 937 }
 938
 939 sub _create_pdf {
 940   my ($order, $pdf_ref, $params) = @_;
 941
 942   my @errors = ();
 943
 944   my $print_form = Form->new('');
 945   $print_form->{type}        = $order->type;
 946   $print_form->{formname}    = $params->{formname} || $order->type;
 947   $print_form->{format}      = $params->{format}   || 'pdf';
 948   $print_form->{media}       = $params->{media}    || 'file';
 949   $print_form->{groupitems}  = $params->{groupitems};
 950   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
 951   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
 952   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
 953
 954   $order->flatten_to_form($print_form, format_amounts => 1);
 955   # flatten_to_form sets payment_terms from customer/vendor - we do not want that here
 956   delete $print_form->{payment_terms} if !$print_form->{payment_id};
 957
 958   # search for the template
 959   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
 960     name        => $print_form->{formname},
 961     email       => $print_form->{media} eq 'email',
 962     language    => $params->{language},
 963     printer_id  => $print_form->{printer_id},  # todo
 964   );
 965
 966   if (!defined $template_file) {
 967     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
 968   }
 969
 970   return @errors if scalar @errors;
 971
 972   $print_form->throw_on_error(sub {
 973     eval {
 974       $print_form->prepare_for_printing;
 975
 976       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
 977         template  => $template_file,
 978         variables => $print_form,
 979         variable_content_types => {
 980           longdescription => 'html',
 981           partnotes       => 'html',
 982           notes           => 'html',
 983         },
 984       );
 985       1;
 986     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
 987   });
 988
 989   return @errors;
 990 }
 991
 992 sub _sales_order_type {
 993   'sales_order';
 994 }
 995
 996 sub _purchase_order_type {
 997   'purchase_order';
 998 }
 999
1000 1;
1001
1002 __END__
1003
1004 =encoding utf-8
1005
1006 =head1 NAME
1007
1008 SL::Controller::Order - controller for orders
1009
1010 =head1 TODO
1011
1012 =over 2
1013
1014 =item *
1015
1016 testing
1017
1018
1019 =item *
1020
1021 currency
1022
1023
1024 =item *
1025
1026 customer/vendor details ('D'-button)
1027
1028
1029 =item *
1030
1031 credit limit
1032
1033
1034 =item *
1035
1036 more workflows (save as new / invoice)
1037
1038
1039 =item *
1040
1041 price sources: little symbols showing better price / better discount
1042
1043
1044 =item *
1045
1046 custom shipto address
1047
1048
1049 =item *
1050
1051 periodic invoices
1052
1053
1054 =item *
1055
1056 more details on second row (marge, ...)
1057
1058
1059 =item *
1060
1061 language / part translations
1062
1063
1064 =item *
1065
1066 access rights
1067
1068
1069 =item *
1070
1071 preset salesman from customer
1072
1073
1074 =item *
1075
1076 display weights
1077
1078
1079 =item *
1080
1081 force project if enabled in client config
1082
1083
1084 =back
1085
1086 =head1 AUTHOR
1087
1088 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
1089
1090 =cut