SL/DB/DeliveryOrder.pm

   1 package SL::DB::DeliveryOrder;
   2
   3 use strict;
   4
   5 use Carp;
   6
   7 use Rose::DB::Object::Helpers ();
   8
   9 use SL::DB::MetaSetup::DeliveryOrder;
  10 use SL::DB::Manager::DeliveryOrder;
  11 use SL::DB::Helper::AttrHTML;
  12 use SL::DB::Helper::AttrSorted;
  13 use SL::DB::Helper::FlattenToForm;
  14 use SL::DB::Helper::LinkedRecords;
  15 use SL::DB::Helper::TransNumberGenerator;
  16
  17 use List::Util qw(first);
  18
  19 __PACKAGE__->meta->add_relationship(orderitems => { type         => 'one to many',
  20                                                     class        => 'SL::DB::DeliveryOrderItem',
  21                                                     column_map   => { id => 'delivery_order_id' },
  22                                                     manager_args => { with_objects => [ 'part' ] }
  23                                                   },
  24                                     custom_shipto => {
  25                                       type        => 'one to one',
  26                                       class       => 'SL::DB::Shipto',
  27                                       column_map  => { id => 'trans_id' },
  28                                       query_args  => [ module => 'DO' ],
  29                                     },
  30                                    );
  31
  32 __PACKAGE__->meta->initialize;
  33
  34 __PACKAGE__->attr_html('notes');
  35 __PACKAGE__->attr_sorted('items');
  36
  37 __PACKAGE__->before_save('_before_save_set_donumber');
  38
  39 # hooks
  40
  41 sub _before_save_set_donumber {
  42   my ($self) = @_;
  43
  44   $self->create_trans_number if !$self->donumber;
  45
  46   return 1;
  47 }
  48
  49 # methods
  50
  51 sub items { goto &orderitems; }
  52 sub add_items { goto &add_orderitems; }
  53
  54 sub sales_order {
  55   my $self   = shift;
  56   my %params = @_;
  57
  58
  59   require SL::DB::Order;
  60   my $orders = SL::DB::Manager::Order->get_all(
  61     query => [
  62       ordnumber => $self->ordnumber,
  63       @{ $params{query} || [] },
  64     ],
  65   );
  66
  67   return first { $_->is_type('sales_order') } @{ $orders };
  68 }
  69
  70 sub type {
  71   return shift->customer_id ? 'sales_delivery_order' : 'purchase_delivery_order';
  72 }
  73
  74 sub displayable_state {
  75   my ($self) = @_;
  76
  77   return join '; ',
  78     ($self->closed    ? $::locale->text('closed')    : $::locale->text('open')),
  79     ($self->delivered ? $::locale->text('delivered') : $::locale->text('not delivered'));
  80 }
  81
  82 sub date {
  83   goto &transdate;
  84 }
  85
  86 sub _clone_orderitem_cvar {
  87   my ($cvar) = @_;
  88
  89   my $cloned = Rose::DB::Object::Helpers::clone_and_reset($_);
  90   $cloned->sub_module('delivery_order_items');
  91
  92   return $cloned;
  93 }
  94
  95 sub new_from {
  96   my ($class, $source, %params) = @_;
  97
  98   croak("Unsupported source object type '" . ref($source) . "'") unless ref($source) eq 'SL::DB::Order';
  99
 100   my ($item_parent_id_column, $item_parent_column);
 101
 102   if (ref($source) eq 'SL::DB::Order') {
 103     $item_parent_id_column = 'trans_id';
 104     $item_parent_column    = 'order';
 105   }
 106
 107   my $terms = $source->can('payment_id') && $source->payment_id ? $source->payment_terms->terms_netto : 0;
 108
 109   my %args = ( map({ ( $_ => $source->$_ ) } qw(cp_id currency_id customer_id cusordnumber department_id employee_id globalproject_id intnotes language_id notes
 110                                                 ordnumber reqdate salesman_id shippingpoint shipvia taxincluded taxzone_id transaction_description vendor_id
 111                                              )),
 112                closed    => 0,
 113                is_sales  => !!$source->customer_id,
 114                delivered => 0,
 115                terms     => $terms,
 116                transdate => DateTime->today_local,
 117             );
 118
 119   # Custom shipto addresses (the ones specific to the sales/purchase
 120   # record and not to the customer/vendor) are only linked from
 121   # shipto -> delivery_orders. Meaning delivery_orders.shipto_id
 122   # will not be filled in that case. Therefore we have to return the
 123   # new shipto object as a separate object so that the caller can
 124   # save it, too.
 125   my $custom_shipto;
 126   if (!$source->shipto_id && $source->id) {
 127     my $old = $source->custom_shipto;
 128     if ($old) {
 129       $custom_shipto = SL::DB::Shipto->new(
 130         map  { +($_ => $old->$_) }
 131         grep { !m{^ (?: itime | mtime | shipto_id | trans_id ) $}x }
 132         map  { $_->name }
 133         @{ $old->meta->columns }
 134       );
 135       $custom_shipto->module('DO');
 136     }
 137
 138   } else {
 139     $args{shipto_id} = $source->shipto_id;
 140   }
 141
 142   my $delivery_order = $class->new(%args);
 143   $delivery_order->assign_attributes(%{ $params{attributes} }) if $params{attributes};
 144   my $items          = delete($params{items}) || $source->items_sorted;
 145   my %item_parents;
 146
 147   my @items = map {
 148     my $source_item      = $_;
 149     my $source_item_id   = $_->$item_parent_id_column;
 150     my @custom_variables = map { _clone_orderitem_cvar($_) } @{ $source_item->custom_variables };
 151
 152     $item_parents{$source_item_id} ||= $source_item->$item_parent_column;
 153     my $item_parent                  = $item_parents{$source_item_id};
 154
 155     SL::DB::DeliveryOrderItem->new(map({ ( $_ => $source_item->$_ ) }
 156                                          qw(base_qty cusordnumber description discount lastcost longdescription marge_price_factor parts_id price_factor price_factor_id
 157                                             project_id qty reqdate sellprice serialnumber transdate unit active_discount_source active_price_source
 158                                          )),
 159                                    custom_variables => \@custom_variables,
 160                                    ordnumber        => ref($item_parent) eq 'SL::DB::Order' ? $item_parent->ordnumber : $source_item->ordnumber,
 161                                  );
 162
 163   } @{ $items };
 164
 165   @items = grep { $_->qty * 1 } @items if $params{skip_items_zero_qty};
 166   @items = grep { $_->qty >=0 } @items if $params{skip_items_negative_qty};
 167
 168   $delivery_order->items(\@items);
 169
 170   return ($delivery_order, $custom_shipto);
 171 }
 172
 173 sub customervendor {
 174   $_[0]->is_sales ? $_[0]->customer : $_[0]->vendor;
 175 }
 176
 177 1;
 178 __END__
 179
 180 =pod
 181
 182 =encoding utf8
 183
 184 =head1 NAME
 185
 186 SL::DB::DeliveryOrder - Rose model for delivery orders (table
 187 "delivery_orders")
 188
 189 =head1 FUNCTIONS
 190
 191 =over 4
 192
 193 =item C<date>
 194
 195 An alias for C<transdate> for compatibility with other sales/purchase models.
 196
 197 =item C<displayable_state>
 198
 199 Returns a human-readable description of the state regarding being
 200 closed and delivered.
 201
 202 =item C<items>
 203
 204 An alias for C<deliver_orer_items> for compatibility with other
 205 sales/purchase models.
 206
 207 =item C<new_from $source, %params>
 208
 209 Creates a new C<SL::DB::DeliveryOrder> instance and copies as much
 210 information from C<$source> as possible. At the moment only instances
 211 of C<SL::DB::Order> (sales quotations, sales orders, requests for
 212 quotations and purchase orders) are supported as sources.
 213
 214 The conversion copies order items into delivery order items. Dates are copied
 215 as appropriate, e.g. the C<transdate> field will be set to the current date.
 216
 217 Returns one or two objects depending on the context. In list context
 218 the new delivery order instance and a shipto instance will be
 219 returned. In scalar instance only the delivery order instance is
 220 returned.
 221
 222 Custom shipto addresses (the ones specific to the sales/purchase
 223 record and not to the customer/vendor) are only linked from C<shipto>
 224 to C<delivery_orders>. Meaning C<delivery_orders.shipto_id> will not
 225 be filled in that case. That's why a separate shipto object is created
 226 and returned.
 227
 228 The objects returned are not saved.
 229
 230 C<%params> can include the following options:
 231
 232 =over 2
 233
 234 =item C<items>
 235
 236 An optional array reference of RDBO instances for the items to use. If
 237 missing then the method C<items_sorted> will be called on
 238 C<$source>. This option can be used to override the sorting, to
 239 exclude certain positions or to add additional ones.
 240
 241 =item C<skip_items_negative_qty>
 242
 243 If trueish then items with a negative quantity are skipped. Items with
 244 a quantity of 0 are not affected by this option.
 245
 246 =item C<skip_items_zero_qty>
 247
 248 If trueish then items with a quantity of 0 are skipped.
 249
 250 =item C<attributes>
 251
 252 An optional hash reference. If it exists then it is passed to C<new>
 253 allowing the caller to set certain attributes for the new delivery
 254 order.
 255
 256 =back
 257
 258 =item C<sales_order>
 259
 260 TODO: Describe sales_order
 261
 262 =item C<type>
 263
 264 Returns a stringdescribing this record's type: either
 265 C<sales_delivery_order> or C<purchase_delivery_order>.
 266
 267 =back
 268
 269 =head1 BUGS
 270
 271 Nothing here yet.
 272
 273 =head1 AUTHOR
 274
 275 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 276
 277 =cut