SL/Controller/CsvImport/DeliveryOrder.pm

   1 package SL::Controller::CsvImport::DeliveryOrder;
   2
   3
   4 use strict;
   5
   6 use List::Util qw(first);
   7 use List::MoreUtils qw(any none uniq);
   8 use DateTime;
   9
  10 use SL::Controller::CsvImport::Helper::Consistency;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::DeliveryOrder::TypeData qw(:types);
  13 use SL::DB::DeliveryOrderItem;
  14 use SL::DB::DeliveryOrderItemsStock;
  15 use SL::DB::Part;
  16 use SL::DB::PaymentTerm;
  17 use SL::DB::Contact;
  18 use SL::DB::PriceFactor;
  19 use SL::DB::Shipto;
  20 use SL::DB::Unit;
  21 use SL::DB::Inventory;
  22 use SL::DB::TransferType;
  23 use SL::DBUtils;
  24 use SL::Helper::ShippedQty;
  25 use SL::PriceSource;
  26 use SL::TransNumber;
  27 use SL::Util qw(trim);
  28
  29 use parent qw(SL::Controller::CsvImport::BaseMulti);
  30
  31
  32 use Rose::Object::MakeMethods::Generic
  33 (
  34  'scalar --get_set_init' => [ qw(settings languages_by all_parts parts_by part_counts_by
  35                                  contacts_by ct_shiptos_by
  36                                  price_factors_by units_by
  37                                  warehouses_by bins_by transfer_types_by) ],
  38 );
  39
  40
  41 sub init_class {
  42   my ($self) = @_;
  43   $self->class(['SL::DB::DeliveryOrder', 'SL::DB::DeliveryOrderItem', 'SL::DB::DeliveryOrderItemsStock']);
  44 }
  45
  46 sub set_profile_defaults {
  47   my ($self) = @_;
  48
  49   $self->controller->profile->_set_defaults(
  50     order_column         => $::locale->text('DeliveryOrder'),
  51     item_column          => $::locale->text('OrderItem'),
  52     stock_column         => $::locale->text('StockInfo'),
  53     ignore_faulty_positions => 0,
  54   );
  55 };
  56
  57 sub init_settings {
  58   my ($self) = @_;
  59
  60   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(order_column item_column stock_column ignore_faulty_positions) };
  61 }
  62
  63 sub init_cvar_configs_by {
  64   my ($self) = @_;
  65
  66   my $item_cvar_configs = SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
  67   $item_cvar_configs = [grep { $_->has_flag('editable') } @{ $item_cvar_configs }];
  68
  69   my $ccb;
  70   $ccb->{class}->{$self->class->[0]}        = [];
  71   $ccb->{class}->{$self->class->[1]}        = $item_cvar_configs;
  72   $ccb->{class}->{$self->class->[2]}        = [];
  73   $ccb->{row_ident}->{$self->_order_column} = [];
  74   $ccb->{row_ident}->{$self->_item_column}  = $item_cvar_configs;
  75   $ccb->{row_ident}->{$self->_stock_column} = [];
  76
  77   return $ccb;
  78 }
  79
  80 sub init_profile {
  81   my ($self) = @_;
  82
  83   my $profile = $self->SUPER::init_profile;
  84
  85   # SUPER::init_profile sets row_ident to the translated class name
  86   # overwrite it with the user specified settings
  87   foreach my $p (@{ $profile }) {
  88     $p->{row_ident} = $self->_order_column if $p->{class} eq $self->class->[0];
  89     $p->{row_ident} = $self->_item_column  if $p->{class} eq $self->class->[1];
  90     $p->{row_ident} = $self->_stock_column if $p->{class} eq $self->class->[2];
  91   }
  92
  93   foreach my $p (@{ $profile }) {
  94     my $prof = $p->{profile};
  95     if ($p->{row_ident} eq $self->_order_column) {
  96       # no need to handle
  97       delete @{$prof}{qw(oreqnumber)};
  98     }
  99     if ($p->{row_ident} eq $self->_item_column) {
 100       # no need to handle
 101       delete @{$prof}{qw(delivery_order_id)};
 102     }
 103     if ($p->{row_ident} eq $self->_stock_column) {
 104       # no need to handle
 105       delete @{$prof}{qw(delivery_order_item_id)};
 106       delete @{$prof}{qw(bestbefore)} if !$::instance_conf->get_show_bestbefore;
 107     }
 108   }
 109
 110   return $profile;
 111 }
 112
 113 sub init_existing_objects {
 114   my ($self) = @_;
 115
 116   # only use objects of main class (the first one)
 117   eval "require " . $self->class->[0];
 118   $self->existing_objects($self->manager_class->[0]->get_all);
 119 }
 120
 121 sub get_duplicate_check_fields {
 122   return {
 123     donumber => {
 124       label     => $::locale->text('Delivery Order Number'),
 125       default   => 1,
 126       std_check => 1,
 127       maker     => sub {
 128         my ($object, $worker) = @_;
 129         return if ref $object ne $worker->class->[0];
 130         return $object->donumber;
 131       },
 132     },
 133   };
 134 }
 135
 136 sub check_std_duplicates {
 137   my $self = shift;
 138
 139   my $duplicates = {};
 140
 141   my $all_fields = $self->get_duplicate_check_fields();
 142
 143   foreach my $key (keys(%{ $all_fields })) {
 144     if ( $self->controller->profile->get('duplicates_'. $key) && (!exists($all_fields->{$key}->{std_check}) || $all_fields->{$key}->{std_check} )  ) {
 145       $duplicates->{$key} = {};
 146     }
 147   }
 148
 149   my @duplicates_keys = keys(%{ $duplicates });
 150
 151   if ( !scalar(@duplicates_keys) ) {
 152     return;
 153   }
 154
 155   if ( $self->controller->profile->get('duplicates') eq 'check_db' ) {
 156     foreach my $object (@{ $self->existing_objects }) {
 157       foreach my $key (@duplicates_keys) {
 158         my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 159         $duplicates->{$key}->{$value} = 'db';
 160       }
 161     }
 162   }
 163
 164   # only check order rows
 165   foreach my $entry (@{ $self->controller->data }) {
 166     if ($entry->{raw_data}->{datatype} ne $self->_order_column) {
 167       next;
 168     }
 169     if ( @{ $entry->{errors} } ) {
 170       next;
 171     }
 172
 173     my $object = $entry->{object};
 174
 175     foreach my $key (@duplicates_keys) {
 176       my $value = exists($all_fields->{$key}->{maker}) ? $all_fields->{$key}->{maker}->($object, $self) : $object->$key;
 177
 178       if ( exists($duplicates->{$key}->{$value}) ) {
 179         push(@{ $entry->{errors} }, $duplicates->{$key}->{$value} eq 'db' ? $::locale->text('Duplicate in database') : $::locale->text('Duplicate in CSV file'));
 180         last;
 181       } else {
 182         $duplicates->{$key}->{$value} = 'csv';
 183       }
 184
 185     }
 186   }
 187 }
 188
 189 sub setup_displayable_columns {
 190   my ($self) = @_;
 191
 192   $self->SUPER::setup_displayable_columns;
 193
 194   $self->add_cvar_columns_to_displayable_columns($self->_order_column);
 195
 196   $self->add_displayable_columns($self->_order_column,
 197                                  { name => 'datatype',                description => $self->_order_column . ' [1]'                            },
 198                                  { name => 'closed',                  description => $::locale->text('Closed')                                },
 199                                  { name => 'contact',                 description => $::locale->text('Contact Person (name)')                 },
 200                                  { name => 'cp_id',                   description => $::locale->text('Contact Person (database ID)')          },
 201                                  { name => 'currency',                description => $::locale->text('Currency')                              },
 202                                  { name => 'currency_id',             description => $::locale->text('Currency (database ID)')                },
 203                                  { name => 'customer',                description => $::locale->text('Customer (name)')                       },
 204                                  { name => 'customernumber',          description => $::locale->text('Customer Number')                       },
 205                                  { name => 'customer_id',             description => $::locale->text('Customer (database ID)')                },
 206                                  { name => 'cusordnumber',            description => $::locale->text('Customer Order Number')                 },
 207                                  { name => 'delivered',               description => $::locale->text('Delivered')                             },
 208                                  { name => 'delivery_term',           description => $::locale->text('Delivery terms (name)')                 },
 209                                  { name => 'delivery_term_id',        description => $::locale->text('Delivery terms (database ID)')          },
 210                                  { name => 'department_id',           description => $::locale->text('Department (database ID)')              },
 211                                  { name => 'department',              description => $::locale->text('Department (description)')              },
 212                                  { name => 'donumber',                description => $::locale->text('Delivery Order Number')                 },
 213                                  { name => 'employee_id',             description => $::locale->text('Employee (database ID)')                },
 214                                  { name => 'globalproject',           description => $::locale->text('Document Project (description)')        },
 215                                  { name => 'globalprojectnumber',     description => $::locale->text('Document Project (number)')             },
 216                                  { name => 'globalproject_id',        description => $::locale->text('Document Project (database ID)')        },
 217                                  { name => 'intnotes',                description => $::locale->text('Internal Notes')                        },
 218                                  { name => 'language',                description => $::locale->text('Language (name)')                       },
 219                                  { name => 'language_id',             description => $::locale->text('Language (database ID)')                },
 220                                  { name => 'notes',                   description => $::locale->text('Notes')                                 },
 221                                  { name => 'record_type',             description => $::locale->text('Delivery Order Type')                   },
 222                                  { name => 'ordnumber',               description => $::locale->text('Order Number')                          },
 223                                  { name => 'payment',                 description => $::locale->text('Payment terms (name)')                  },
 224                                  { name => 'payment_id',              description => $::locale->text('Payment terms (database ID)')           },
 225                                  { name => 'reqdate',                 description => $::locale->text('Reqdate')                               },
 226                                  { name => 'salesman_id',             description => $::locale->text('Salesman (database ID)')                },
 227                                  { name => 'shippingpoint',           description => $::locale->text('Shipping Point')                        },
 228                                  { name => 'shipvia',                 description => $::locale->text('Ship via')                              },
 229                                  { name => 'shipto_id',               description => $::locale->text('Ship to (database ID)')                 },
 230                                  { name => 'taxincluded',             description => $::locale->text('Tax Included')                          },
 231                                  { name => 'taxzone',                 description => $::locale->text('Tax zone (description)')                },
 232                                  { name => 'taxzone_id',              description => $::locale->text('Tax zone (database ID)')                },
 233                                  { name => 'transaction_description', description => $::locale->text('Transaction description')               },
 234                                  { name => 'transdate',               description => $::locale->text('Order Date')                            },
 235                                  { name => 'vendor',                  description => $::locale->text('Vendor (name)')                         },
 236                                  { name => 'vendornumber',            description => $::locale->text('Vendor Number')                         },
 237                                  { name => 'vendor_id',               description => $::locale->text('Vendor (database ID)')                  },
 238                                 );
 239
 240   $self->add_cvar_columns_to_displayable_columns($self->_item_column);
 241
 242   $self->add_displayable_columns($self->_item_column,
 243                                  { name => 'datatype',        description => $self->_item_column . ' [1]'                  },
 244                                  { name => 'cusordnumber',    description => $::locale->text('Customer Order Number')      },
 245                                  { name => 'description',     description => $::locale->text('Description')                },
 246                                  { name => 'discount',        description => $::locale->text('Discount')                   },
 247                                  { name => 'lastcost',        description => $::locale->text('Lastcost')                   },
 248                                  { name => 'longdescription', description => $::locale->text('Long Description')           },
 249                                  { name => 'ordnumber',       description => $::locale->text('Order Number')               },
 250                                  { name => 'partnumber',      description => $::locale->text('Part Number')                },
 251                                  { name => 'parts_id',        description => $::locale->text('Part (database ID)')         },
 252                                  { name => 'position',        description => $::locale->text('position')                   },
 253                                  { name => 'price_factor',    description => $::locale->text('Price factor (name)')        },
 254                                  { name => 'price_factor_id', description => $::locale->text('Price factor (database ID)') },
 255                                  { name => 'pricegroup',      description => $::locale->text('Price group (name)')         },
 256                                  { name => 'pricegroup_id',   description => $::locale->text('Price group (database ID)')  },
 257                                  { name => 'project',         description => $::locale->text('Project (description)')      },
 258                                  { name => 'projectnumber',   description => $::locale->text('Project (number)')           },
 259                                  { name => 'project_id',      description => $::locale->text('Project (database ID)')      },
 260                                  { name => 'qty',             description => $::locale->text('Quantity')                   },
 261                                  { name => 'reqdate',         description => $::locale->text('Reqdate')                    },
 262                                  { name => 'sellprice',       description => $::locale->text('Sellprice')                  },
 263                                  { name => 'serialnumber',    description => $::locale->text('Serial No.')                 },
 264                                  { name => 'transdate',       description => $::locale->text('Order Date')                 },
 265                                  { name => 'unit',            description => $::locale->text('Unit')                       },
 266                                 );
 267
 268   $self->add_cvar_columns_to_displayable_columns($self->_stock_column);
 269
 270   $self->add_displayable_columns($self->_stock_column,
 271                                  { name => 'datatype',     description => $self->_stock_column . ' [1]'              },
 272                                  { name => 'warehouse',    description => $::locale->text('Warehouse')               },
 273                                  { name => 'warehouse_id', description => $::locale->text('Warehouse (database ID)') },
 274                                  { name => 'bin',          description => $::locale->text('Bin')                     },
 275                                  { name => 'bin_id',       description => $::locale->text('Bin (database ID)')       },
 276                                  { name => 'chargenumber', description => $::locale->text('Charge number')           },
 277                                  { name => 'qty',          description => $::locale->text('Quantity')                },
 278                                  { name => 'unit',         description => $::locale->text('Unit')                    },
 279                                 );
 280   if ($::instance_conf->get_show_bestbefore) {
 281     $self->add_displayable_columns($self->_stock_column,
 282                                    { name => 'bestbefore', description => $::locale->text('Best Before') });
 283   }
 284 }
 285
 286
 287 sub init_languages_by {
 288   my ($self) = @_;
 289
 290   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
 291 }
 292
 293 sub init_all_parts {
 294   my ($self) = @_;
 295
 296   return SL::DB::Manager::Part->get_all(where => [or => [ obsolete => 0, obsolete => undef ]]);
 297 }
 298
 299 sub init_parts_by {
 300   my ($self) = @_;
 301
 302   return { map { my $col = $_; ( $col => { map { ( trim($_->$col) => $_ ) } @{ $self->all_parts } } ) } qw(id partnumber ean description) };
 303 }
 304
 305 sub init_part_counts_by {
 306   my ($self) = @_;
 307
 308   my $part_counts_by;
 309
 310   $part_counts_by->{ean}->        {trim($_->ean)}++         for @{ $self->all_parts };
 311   $part_counts_by->{description}->{trim($_->description)}++ for @{ $self->all_parts };
 312
 313   return $part_counts_by;
 314 }
 315
 316 sub init_contacts_by {
 317   my ($self) = @_;
 318
 319   my $all_contacts = SL::DB::Manager::Contact->get_all;
 320
 321   my $cby;
 322   # by customer/vendor id  _and_  contact person id
 323   $cby->{'cp_cv_id+cp_id'}   = { map { ( $_->cp_cv_id . '+' . $_->cp_id   => $_ ) } @{ $all_contacts } };
 324   # by customer/vendor id  _and_  contact person name
 325   $cby->{'cp_cv_id+cp_name'} = { map { ( $_->cp_cv_id . '+' . $_->cp_name => $_ ) } @{ $all_contacts } };
 326
 327   return $cby;
 328 }
 329
 330 sub init_ct_shiptos_by {
 331   my ($self) = @_;
 332
 333   my $all_ct_shiptos = SL::DB::Manager::Shipto->get_all(query => [module => 'CT']);
 334
 335   my $sby;
 336   # by trans_id  _and_  shipto_id
 337   $sby->{'trans_id+shipto_id'} = { map { ( $_->trans_id . '+' . $_->shipto_id => $_ ) } @{ $all_ct_shiptos } };
 338
 339   return $sby;
 340 }
 341
 342 sub init_price_factors_by {
 343   my ($self) = @_;
 344
 345   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
 346   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
 347 }
 348
 349 sub init_units_by {
 350   my ($self) = @_;
 351
 352   my $all_units = SL::DB::Manager::Unit->get_all;
 353   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
 354 }
 355
 356 sub init_warehouses_by {
 357   my ($self) = @_;
 358
 359   my $all_warehouses = SL::DB::Manager::Warehouse->get_all(query => [ or => [ invalid => 0, invalid => undef ]]);
 360   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_warehouses } } ) } qw(id description) };
 361 }
 362
 363 sub init_bins_by {
 364   my ($self) = @_;
 365
 366   my $all_bins = SL::DB::Manager::Bin->get_all();
 367   my $bins_by;
 368   $bins_by->{_wh_id_and_id_ident()}          = { map { ( _wh_id_and_id_maker($_->warehouse_id, $_->id)                   => $_ ) } @{ $all_bins } };
 369   $bins_by->{_wh_id_and_description_ident()} = { map { ( _wh_id_and_description_maker($_->warehouse_id, $_->description) => $_ ) } @{ $all_bins } };
 370
 371   return $bins_by;
 372 }
 373
 374 sub init_transfer_types_by {
 375   my ($self) = @_;
 376
 377   my $all_transfer_types = SL::DB::Manager::TransferType->get_all();
 378   my $transfer_types_by;
 379   $transfer_types_by->{_transfer_type_dir_and_description_ident()} = {
 380     map { ( _transfer_type_dir_and_description_maker($_->direction, $_->description) => $_ ) } @{ $all_transfer_types }
 381   };
 382
 383   return $transfer_types_by;
 384 }
 385
 386 sub check_objects {
 387   my ($self) = @_;
 388
 389   $self->controller->track_progress(phase => 'building data', progress => 0);
 390
 391   my $i = 0;
 392   my $num_data = scalar @{ $self->controller->data };
 393   my $order_entry;
 394   my $item_entry;
 395   foreach my $entry (@{ $self->controller->data }) {
 396     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 397
 398     $entry->{info_data}->{datatype} = $entry->{raw_data}->{datatype};
 399
 400     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 401       $self->handle_order($entry);
 402       $order_entry = $entry;
 403     } elsif ($entry->{raw_data}->{datatype} eq $self->_item_column && $entry->{object}->can('part')) {
 404       $self->handle_item($entry, $order_entry);
 405       $item_entry = $entry;
 406     } elsif ($entry->{raw_data}->{datatype} eq $self->_stock_column) {
 407       $self->handle_stock($entry, $item_entry, $order_entry);
 408       push @{ $order_entry->{errors} }, $::locale->text('Error: Stock problem') if scalar(@{$entry->{errors}}) > 0;
 409     } else {
 410       $order_entry = undef;
 411       $item_entry  = undef;
 412     }
 413
 414     $self->handle_cvars($entry, sub_module => 'delivery_order_items');
 415
 416   } continue {
 417     $i++;
 418   }
 419
 420   $self->add_info_columns($self->_order_column,
 421                           { header => $::locale->text('Data type'), method => 'datatype' });
 422   $self->add_info_columns($self->_item_column,
 423                           { header => $::locale->text('Data type'), method => 'datatype' });
 424   $self->add_info_columns($self->_stock_column,
 425                           { header => $::locale->text('Data type'), method => 'datatype' });
 426
 427   $self->add_info_columns($self->_order_column,
 428                           { header => $::locale->text('Customer/Vendor'), method => 'vc_name' });
 429   # Todo: access via ->[0] ok? Better: search first order column and use this
 430   $self->add_columns($self->_order_column,
 431                      map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(payment delivery_term language department globalproject taxzone cp currency));
 432   $self->add_columns($self->_order_column, 'globalproject_id') if exists $self->controller->data->[0]->{raw_data}->{globalprojectnumber};
 433   $self->add_columns($self->_order_column, 'cp_id')            if exists $self->controller->data->[0]->{raw_data}->{contact};
 434
 435   $self->add_info_columns($self->_item_column,
 436                           { header => $::locale->text('Part Number'), method => 'partnumber' });
 437   # Todo: access via ->[1] ok? Better: search first item column and use this
 438   $self->add_columns($self->_item_column,
 439                      map { "${_}_id" } grep { exists $self->controller->data->[1]->{raw_data}->{$_} } qw(project price_factor pricegroup));
 440   $self->add_columns($self->_item_column, 'project_id') if exists $self->controller->data->[1]->{raw_data}->{projectnumber};
 441
 442   $self->add_cvar_raw_data_columns();
 443
 444
 445   # Check overall qtys for sales delivery orders, because they are
 446   # stocked out in the end and a stock underrun can occure.
 447   # Todo: let it work even with bestbefore turned off.
 448   $order_entry = undef;
 449   $item_entry  = undef;
 450   my %wanted_qtys_by_part_wh_bin_charge_bestbefore;
 451   my %stock_entries_with_part_wh_bin_charge_bestbefore;
 452   my %order_entries_with_part_wh_bin_charge_bestbefore;
 453   foreach my $entry (@{ $self->controller->data }) {
 454     if ($entry->{raw_data}->{datatype} eq $self->_order_column) {
 455       if (scalar(@{ $entry->{errors} }) || !$entry->{object}->is_sales) {
 456         $order_entry = undef;
 457         $item_entry  = undef;
 458         next;
 459       }
 460       $order_entry = $entry;
 461
 462     } elsif (defined $order_entry && $entry->{raw_data}->{datatype} eq $self->_item_column) {
 463       if (scalar(@{ $entry->{errors} })) {
 464         $item_entry = undef;
 465         next;
 466       }
 467       $item_entry = $entry;
 468
 469     } elsif (defined $item_entry && $entry->{raw_data}->{datatype} eq $self->_stock_column) {
 470       my $object = $entry->{object};
 471       my $key = join('+',
 472                      $item_entry->{object}->parts_id,
 473                      $object->warehouse_id,
 474                      $object->bin_id,
 475                      $object->chargenumber,
 476                      $object->bestbefore);
 477       $wanted_qtys_by_part_wh_bin_charge_bestbefore{$key} += $object->qty;
 478       push @{$order_entries_with_part_wh_bin_charge_bestbefore{$key}}, $order_entry;
 479       push @{$stock_entries_with_part_wh_bin_charge_bestbefore{$key}}, $entry;
 480     }
 481   }
 482
 483   foreach my $key (keys %wanted_qtys_by_part_wh_bin_charge_bestbefore) {
 484     my ($parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore) = split '\+', $key;
 485     my $qty = $self->get_stocked_qty($parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore);
 486     if ($wanted_qtys_by_part_wh_bin_charge_bestbefore{$key} > $qty) {
 487
 488       foreach my $stock_entry (@{ $stock_entries_with_part_wh_bin_charge_bestbefore{$key} }) {
 489         push @{ $stock_entry->{errors} }, $::locale->text('Error: Stocking out would result in stock underrun');
 490       }
 491
 492       foreach my $order_entry (uniq @{ $order_entries_with_part_wh_bin_charge_bestbefore{$key} }) {
 493         my $part            = $self->parts_by->{id}->{$parts_id}->displayable_name;
 494         my $stock           = $self->bins_by->{_wh_id_and_id_ident()}->{_wh_id_and_id_maker($wh_id, $bin_id)}->full_description;
 495         my $bestbefore_obj  = $::locale->parse_date_to_object($bestbefore, dateformat=>'yyyy-mm-dd');
 496         my $bestbefore_text = $bestbefore_obj? $::locale->parse_date_to_object($bestbefore_obj, dateformat=>'yyyy-mm-dd')->to_kivitendo: '-';
 497         my $wanted_qty      = $wanted_qtys_by_part_wh_bin_charge_bestbefore{$key};
 498         my $details_text    = sprintf('%s (%s / %s / %s): %s > %s',
 499                                       $part,
 500                                       $stock,
 501                                       $chargenumber,
 502                                       $bestbefore_text,
 503                                       $::form->format_amount(\%::myconfig, $wanted_qty,  2),
 504                                       $::form->format_amount(\%::myconfig, $qty, 2));
 505         push @{ $order_entry->{errors} }, $::locale->text('Error: Stocking out would result in stock underrun: #1', $details_text);
 506       }
 507
 508     }
 509   }
 510
 511 }
 512
 513 sub handle_order {
 514   my ($self, $entry) = @_;
 515
 516   my $object = $entry->{object};
 517
 518   $object->orderitems([]);
 519
 520   $self->handle_order_sources($entry);
 521   my $first_source_order = $object->{source_orders}->[0];
 522
 523   my $vc_obj;
 524   if (any { $entry->{raw_data}->{$_} } qw(customer customernumber customer_id)) {
 525     $self->check_vc($entry, 'customer_id');
 526     $vc_obj = SL::DB::Customer->new(id => $object->customer_id)->load if $object->customer_id;
 527
 528   } elsif (any { $entry->{raw_data}->{$_} } qw(vendor vendornumber vendor_id)) {
 529     $self->check_vc($entry, 'vendor_id');
 530     $vc_obj = SL::DB::Vendor->new(id => $object->vendor_id)->load if $object->vendor_id;
 531
 532   } else {
 533     # customer / vendor from (first) source order if not given
 534     if ($first_source_order) {
 535       if ($first_source_order->customer) {
 536         $vc_obj = $first_source_order->customer;
 537         $object->customer($first_source_order->customer);
 538       } elsif ($first_source_order->vendor) {
 539         $vc_obj = $first_source_order->vendor;
 540         $object->vendor($first_source_order->vendor);
 541       }
 542     }
 543   }
 544
 545   if (!$vc_obj) {
 546     push @{ $entry->{errors} }, $::locale->text('Error: Customer/vendor missing');
 547   }
 548
 549   $self->handle_type($entry);
 550   $self->check_contact($entry);
 551   $self->check_language($entry);
 552   $self->check_payment($entry);
 553   $self->check_delivery_term($entry);
 554   $self->check_department($entry);
 555   $self->check_project($entry, global => 1);
 556   $self->check_ct_shipto($entry);
 557   $self->check_taxzone($entry);
 558   $self->check_currency($entry, take_default => 0);
 559
 560   # copy from (first) source order if not given
 561   # if no source order, then copy some values from customer/vendor
 562   if ($first_source_order) {
 563     foreach (qw(cusordnumber notes intnotes shippingpoint shipvia
 564                 transaction_description currency_id delivery_term_id
 565                 department_id language_id payment_id globalproject_id shipto_id
 566                 taxzone_id)) {
 567       $object->$_($first_source_order->$_) unless $object->$_;
 568     }
 569   } elsif ($vc_obj) {
 570     foreach (qw(currency_id delivery_term_id language_id payment_id taxzone_id)) {
 571       $object->$_($vc_obj->$_) unless $object->$_;
 572     }
 573     $object->intnotes($vc_obj->notes) unless $object->intnotes;
 574   }
 575
 576   $self->handle_salesman($entry);
 577   $self->handle_employee($entry);
 578 }
 579
 580 sub handle_item {
 581   my ($self, $entry, $order_entry) = @_;
 582
 583   return unless $order_entry;
 584
 585   my $order_obj = $order_entry->{object};
 586   my $object    = $entry->{object};
 587   $object->delivery_order_stock_entries([]);
 588
 589   if (!$self->check_part($entry)) {
 590     if ($self->controller->profile->get('ignore_faulty_positions')) {
 591       push @{ $order_entry->{information} }, $::locale->text('Warning: Faulty position ignored');
 592     } else {
 593       push @{ $order_entry->{errors} }, $::locale->text('Error: Faulty position in this delivery order');
 594     }
 595     return;
 596   }
 597
 598   $order_obj->add_items($object);
 599
 600   my $part_obj = SL::DB::Part->new(id => $object->parts_id)->load;
 601
 602   $self->handle_item_source($entry, $order_entry);
 603   $object->position($object->{source_item}->position) if $object->{source_item};
 604
 605   $self->handle_unit($entry);
 606
 607   # copy from part if not given
 608   $object->description($part_obj->description) unless $object->description;
 609   $object->longdescription($part_obj->notes)   unless $object->longdescription;
 610   $object->lastcost($part_obj->lastcost)       unless defined $object->lastcost;
 611
 612   $self->check_project($entry, global => 0);
 613   $self->check_price_factor($entry);
 614   $self->check_pricegroup($entry);
 615
 616   $self->handle_sellprice($entry, $order_entry);
 617   $self->handle_discount($entry, $order_entry);
 618
 619   push @{ $order_entry->{errors} }, $::locale->text('Error: Faulty position in this delivery order') if scalar(@{$entry->{errors}}) > 0;
 620 }
 621
 622 sub handle_stock {
 623   my ($self, $entry, $item_entry, $order_entry) = @_;
 624
 625   return unless $item_entry;
 626
 627   my $item_obj  = $item_entry->{object};
 628   return unless $item_obj->part;
 629
 630   my $order_obj = $order_entry->{object};
 631   my $object    = $entry->{object};
 632
 633   $item_obj->add_delivery_order_stock_entries($object);
 634
 635   $self->check_warehouse($entry);
 636   $self->check_bin($entry);
 637
 638   $self->handle_unit($entry, $item_obj->part);
 639
 640   # check if enough is stocked
 641   # not necessary, because overall stock underrun is checked later
 642   # if ($order_obj->is_sales) {
 643   #   my $stocked_qty = $self->get_stocked_qty($item_obj->parts_id,
 644   #                                            $object->warehouse_id,
 645   #                                            $object->bin_id,
 646   #                                            $object->chargenumber,
 647   #                                            $object->bestbefore);
 648   #   if ($stocked_qty < $object->qty) {
 649   #     push @{ $entry->{errors} }, $::locale->text('Error: Not enough parts in stock');
 650   #   }
 651   # }
 652
 653   my ($stock_info_entry, $part) = @_;
 654
 655   # Todo: option: should stock?
 656   if (1) {
 657     my $tt_key = $order_obj->is_sales
 658                ? _transfer_type_dir_and_description_maker('out', 'shipped')
 659                : _transfer_type_dir_and_description_maker('in', 'stock');
 660     my $trans_type_id = $self->transfer_types_by->{_transfer_type_dir_and_description_ident()}{$tt_key}->id;
 661
 662     my $qty = $order_obj->is_sales ? -1*($object->qty) : $object->qty;
 663     my $inventory = SL::DB::Inventory->new(
 664       parts_id      => $item_obj->parts_id,
 665       warehouse_id  => $object->warehouse_id,
 666       bin_id        => $object->bin_id,
 667       PURCHASE_DELIVERY_ORDER_TYPE() => $trans_type_id,
 668       qty           => $qty,
 669       chargenumber  => $object->chargenumber,
 670       employee_id   => $order_obj->employee_id,
 671       shippingdate  => ($order_obj->reqdate || DateTime->today_local),
 672       comment       => $order_obj->transaction_description,
 673       project_id    => ($order_obj->globalproject_id || $item_obj->project_id),
 674     );
 675     $inventory->bestbefore($object->bestbefore) if $::instance_conf->get_show_bestbefore;
 676     $object->{inventory_obj} = $inventory;
 677     $order_obj->delivered(1);
 678   }
 679 }
 680
 681 sub handle_type {
 682   my ($self, $entry) = @_;
 683
 684   if (!exists $entry->{raw_data}->{record_type}) {
 685     # if no type is present - set to sales delivery order or purchase delivery
 686     # order depending on is_sales or customer/vendor
 687
 688     $entry->{object}->record_type(
 689       $entry->{object}->customer_id  ? SALES_DELIVERY_ORDER_TYPE :
 690       $entry->{object}->vendor_id    ? PURCHASE_DELIVERY_ORDER_TYPE :
 691       $entry->{raw_data}->{is_sales} ? SALES_DELIVERY_ORDER_TYPE :
 692                                        PURCHASE_DELIVERY_ORDER_TYPE
 693     );
 694   }
 695 }
 696
 697 sub handle_order_sources {
 698   my ($self, $entry) = @_;
 699
 700   my $record = $entry->{object};
 701
 702   $record->{source_orders} = [];
 703   return $record->{source_orders} if !$record->ordnumber;
 704
 705   my @order_numbers = split ' ', $record->ordnumber;
 706
 707   my $orders = SL::DB::Manager::Order->get_all(where => [ordnumber => \@order_numbers]);
 708
 709   if (scalar @$orders == 0) {
 710     push @{ $entry->{errors} }, $::locale->text('Error: Source order not found');
 711   } elsif (scalar @$orders > 1) {
 712     push @{ $entry->{errors} }, $::locale->text('Error: More than one source order found');
 713   }
 714
 715   foreach my $order (@$orders) {
 716     $self->{remaining_source_qtys_by_item_id} = { map { $_->id => $_->qty } @{ $order->items } };
 717   }
 718
 719   $record->{source_orders} = $orders;
 720 }
 721
 722 sub handle_item_source {
 723   my ($self, $entry, $record_entry) = @_;
 724
 725   my $item   = $entry->{object};
 726   my $record = $record_entry->{object};
 727
 728   return if !@{ $record->{source_orders} };
 729
 730   # Todo: units?
 731
 732   foreach my $order (@{ $record->{source_orders} }) {
 733     # First: Excact matches and source order position is still complete.
 734     $item->{source_item} = first {
 735          $item->parts_id                                     == $_->parts_id
 736       && $item->qty                                          == $_->qty
 737       && $self->{remaining_source_qtys_by_item_id}->{$_->id} == $_->qty
 738     } @{ $order->items_sorted };
 739     if ($item->{source_item}) {
 740       $self->{remaining_source_qtys_by_item_id}->{$item->{source_item}->id} -= $item->qty;
 741       last;
 742     }
 743
 744     # Second: Smallest remaining order qty greater or equal delivery order qty.
 745     $item->{source_item} = first {
 746          $item->parts_id                                     == $_->parts_id
 747       && $self->{remaining_source_qtys_by_item_id}->{$_->id} >= $item->qty
 748     } sort { $self->{remaining_source_qtys_by_item_id}->{$a->id} <=> $self->{remaining_source_qtys_by_item_id}->{$b->id} } @{ $order->items_sorted };
 749     if ($item->{source_item}) {
 750       $self->{remaining_source_qtys_by_item_id}->{$item->{source_item}->id} -= $item->qty;
 751       last;
 752     }
 753
 754     # Last: Overdelivery?
 755     # $item->{source_item} = first {
 756     #      $item->parts_id == $_->parts_id
 757     # } @{ $order->items_sorted };
 758     # if ($item->{source_item}) {
 759     #   $self->{remaining_source_qtys_by_item_id}->{$item->{source_item}->id} -= $item->qty;
 760     #   last;
 761     # }
 762   }
 763 }
 764
 765 sub handle_unit {
 766   my ($self, $entry, $part) = @_;
 767
 768   my $object = $entry->{object};
 769
 770   $part ||= $object->part;
 771
 772   # Set unit from part if not given.
 773   if (!$object->unit) {
 774     $object->unit($part->unit);
 775     return 1;
 776   }
 777
 778   # Check whether or not unit is valid.
 779   if ($object->unit && !$self->units_by->{name}->{ $object->unit }) {
 780     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 781     return 0;
 782   }
 783
 784   # Check whether unit is convertible to parts unit
 785   if (none { $object->unit eq $_ } map { $_->name } @{ $part->unit_obj->convertible_units }) {
 786     push @{ $entry->{errors} }, $::locale->text('Error: Invalid unit');
 787     return 0;
 788   }
 789
 790   return 1;
 791 }
 792
 793 sub handle_sellprice {
 794   my ($self, $entry, $record_entry) = @_;
 795
 796   my $item   = $entry->{object};
 797   my $record = $record_entry->{object};
 798
 799   return if !$record->customervendor;
 800
 801   # If sellprice is given, set price source to pricegroup if given or to none.
 802   if (exists $entry->{raw_data}->{sellprice}) {
 803     my $price_source      = SL::PriceSource->new(record_item => $item, record => $record);
 804     my $price_source_spec = $item->pricegroup_id ? 'pricegroup' . '/' . $item->pricegroup_id : '';
 805     my $price             = $price_source->price_from_source($price_source_spec);
 806     $item->active_price_source($price->source);
 807
 808   } else {
 809
 810     if ($item->{source_item}) {
 811       # Set sellprice from source order item if not given. Convert with respect to unit.
 812       my $sellprice = $item->{source_item}->sellprice;
 813       if ($item->unit ne $item->{source_item}->unit) {
 814         $sellprice = $item->unit_obj->convert_to($sellprice, $item->{source_item}->unit_obj);
 815       }
 816       $item->sellprice($sellprice);
 817       $item->active_price_source($item->{source_item}->active_price_source);
 818
 819     } else {
 820       # Set sellprice the best price of price source
 821       my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 822       my $price        = $price_source->best_price;
 823       if ($price) {
 824         $item->sellprice($price->price);
 825         $item->active_price_source($price->source);
 826       } else {
 827         $item->sellprice(0);
 828         $item->active_price_source($price_source->price_from_source('')->source);
 829       }
 830     }
 831   }
 832 }
 833
 834 sub handle_discount {
 835   my ($self, $entry, $record_entry) = @_;
 836
 837   my $item   = $entry->{object};
 838   my $record = $record_entry->{object};
 839
 840   return if !$record->customervendor;
 841
 842   # If discount is given, set discount to none.
 843   if (exists $entry->{raw_data}->{discount}) {
 844     my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 845     my $discount     = $price_source->price_from_source('');
 846     $item->active_discount_source($discount->source);
 847
 848   } else {
 849
 850     if ($item->{source_item}) {
 851       # Set discount from source order item if not given.
 852       $item->discount($item->{source_item}->discount);
 853       $item->active_discount_source($item->{source_item}->active_discount_source);
 854
 855     } else {
 856       # Set discount the best discount of price source
 857       my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 858       my $discount     = $price_source->best_discount;
 859       if ($discount) {
 860         $item->discount($discount->discount);
 861         $item->active_discount_source($discount->source);
 862       } else {
 863         $item->discount(0);
 864         $item->active_discount_source($price_source->discount_from_source('')->source);
 865       }
 866     }
 867   }
 868 }
 869
 870 sub check_contact {
 871   my ($self, $entry) = @_;
 872
 873   my $object = $entry->{object};
 874
 875   my $cp_cv_id = $object->customer_id || $object->vendor_id;
 876   return 0 unless $cp_cv_id;
 877
 878   # Check whether or not contact ID is valid.
 879   if ($object->cp_id && !$self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }) {
 880     push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 881     return 0;
 882   }
 883
 884   # Map name to ID if given.
 885   if (!$object->cp_id && $entry->{raw_data}->{contact}) {
 886     my $cp = $self->contacts_by->{'cp_cv_id+cp_name'}->{ $cp_cv_id . '+' . $entry->{raw_data}->{contact} };
 887     if (!$cp) {
 888       push @{ $entry->{errors} }, $::locale->text('Error: Invalid contact');
 889       return 0;
 890     }
 891
 892     $object->cp_id($cp->cp_id);
 893   }
 894
 895   if ($object->cp_id) {
 896     $entry->{info_data}->{contact} = $self->contacts_by->{'cp_cv_id+cp_id'}->{ $cp_cv_id . '+' . $object->cp_id }->cp_name;
 897   }
 898
 899   return 1;
 900 }
 901
 902 sub check_language {
 903   my ($self, $entry) = @_;
 904
 905   my $object = $entry->{object};
 906
 907   # Check whether or not language ID is valid.
 908   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 909     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 910     return 0;
 911   }
 912
 913   # Map name to ID if given.
 914   if (!$object->language_id && $entry->{raw_data}->{language}) {
 915     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 916                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 917
 918     if (!$language) {
 919       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 920       return 0;
 921     }
 922
 923     $object->language_id($language->id);
 924   }
 925
 926   if ($object->language_id) {
 927     $entry->{info_data}->{language} = $self->languages_by->{id}->{ $object->language_id }->description;
 928   }
 929
 930   return 1;
 931 }
 932
 933 sub check_ct_shipto {
 934   my ($self, $entry) = @_;
 935
 936   my $object = $entry->{object};
 937
 938   my $trans_id = $object->customer_id || $object->vendor_id;
 939   return 0 unless $trans_id;
 940
 941   # Check whether or not shipto ID is valid.
 942   if ($object->shipto_id && !$self->ct_shiptos_by->{'trans_id+shipto_id'}->{ $trans_id . '+' . $object->shipto_id }) {
 943     push @{ $entry->{errors} }, $::locale->text('Error: Invalid shipto');
 944     return 0;
 945   }
 946
 947   return 1;
 948 }
 949
 950 sub check_part {
 951   my ($self, $entry) = @_;
 952
 953   my $object = $entry->{object};
 954   my $is_ambiguous;
 955
 956   # Check whether or not part ID is valid.
 957   if ($object->parts_id && !$self->parts_by->{id}->{ $object->parts_id }) {
 958     push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 959     return 0;
 960   }
 961
 962   # Map number to ID if given.
 963   if (!$object->parts_id && $entry->{raw_data}->{partnumber}) {
 964     my $part = $self->parts_by->{partnumber}->{ trim($entry->{raw_data}->{partnumber}) };
 965     if (!$part) {
 966       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 967       return 0;
 968     }
 969
 970     $object->parts_id($part->id);
 971   }
 972
 973   # Map description to ID if given.
 974   if (!$object->parts_id && $entry->{raw_data}->{description}) {
 975     my $part = $self->parts_by->{description}->{ trim($entry->{raw_data}->{description}) };
 976     if (!$part) {
 977       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 978       return 0;
 979     }
 980
 981     if ($self->part_counts_by->{description}->{ trim($entry->{raw_data}->{description}) } > 1) {
 982       $is_ambiguous = 1;
 983     } else {
 984       $object->parts_id($part->id);
 985     }
 986   }
 987
 988   # Map ean to ID if given.
 989   if (!$object->parts_id && $entry->{raw_data}->{ean}) {
 990     my $part = $self->parts_by->{ean}->{ trim($entry->{raw_data}->{ean}) };
 991     if (!$part) {
 992       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
 993       return 0;
 994     }
 995
 996     if ($self->part_counts_by->{ean}->{ trim($entry->{raw_data}->{ean}) } > 1) {
 997       $is_ambiguous = 1;
 998     } else {
 999       $object->parts_id($part->id);
1000     }
1001   }
1002
1003   if ($object->parts_id) {
1004     $entry->{info_data}->{partnumber} = $self->parts_by->{id}->{ $object->parts_id }->partnumber;
1005   } else {
1006     if ($is_ambiguous) {
1007       push @{ $entry->{errors} }, $::locale->text('Error: Part is ambiguous');
1008     } else {
1009       push @{ $entry->{errors} }, $::locale->text('Error: Part not found');
1010     }
1011     return 0;
1012   }
1013
1014   return 1;
1015 }
1016
1017 sub check_price_factor {
1018   my ($self, $entry) = @_;
1019
1020   my $object = $entry->{object};
1021
1022   # Check whether or not price_factor ID is valid.
1023   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
1024     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
1025     return 0;
1026   }
1027
1028   # Map description to ID if given.
1029   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
1030     my $price_factor = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
1031     if (!$price_factor) {
1032       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
1033       return 0;
1034     }
1035
1036     $object->price_factor_id($price_factor->id);
1037   }
1038
1039   return 1;
1040 }
1041
1042 sub check_warehouse {
1043   my ($self, $entry) = @_;
1044
1045   my $object = $entry->{object};
1046
1047   # Check whether or not warehouse ID is valid.
1048   if ($object->warehouse_id && !$self->warehouses_by->{id}->{ $object->warehouse_id }) {
1049     push @{ $entry->{errors} }, $::locale->text('Error: Invalid warehouse');
1050     return 0;
1051   }
1052
1053   # Map description to ID if given.
1054   if (!$object->warehouse_id && $entry->{raw_data}->{warehouse}) {
1055     my $wh = $self->warehouses_by->{description}->{ $entry->{raw_data}->{warehouse} };
1056     if (!$wh) {
1057       push @{ $entry->{errors} }, $::locale->text('Error: Invalid warehouse');
1058       return 0;
1059     }
1060
1061     $object->warehouse_id($wh->id);
1062   }
1063
1064   if ($object->warehouse_id) {
1065     $entry->{info_data}->{warehouse} = $self->warehouses_by->{id}->{ $object->warehouse_id }->description;
1066   } else {
1067     push @{ $entry->{errors} }, $::locale->text('Error: Warehouse not found');
1068     return 0;
1069   }
1070
1071   return 1;
1072 }
1073
1074 # Check bin for given warehouse, so check_warehouse must be called first.
1075 sub check_bin {
1076   my ($self, $entry) = @_;
1077
1078   my $object = $entry->{object};
1079
1080   # Check whether or not bin ID is valid.
1081   if ($object->bin_id && !$self->bins_by->{_wh_id_and_id_ident()}->{ _wh_id_and_id_maker($object->warehouse_id, $object->bin_id) }) {
1082     push @{ $entry->{errors} }, $::locale->text('Error: Invalid bin');
1083     return 0;
1084   }
1085
1086   # Map description to ID if given.
1087   if (!$object->bin_id && $entry->{raw_data}->{bin}) {
1088     my $bin = $self->bins_by->{_wh_id_and_description_ident()}->{ _wh_id_and_description_maker($object->warehouse_id, $entry->{raw_data}->{bin}) };
1089     if (!$bin) {
1090       push @{ $entry->{errors} }, $::locale->text('Error: Invalid bin');
1091       return 0;
1092     }
1093
1094     $object->bin_id($bin->id);
1095   }
1096
1097   if ($object->bin_id) {
1098     $entry->{info_data}->{bin} = $self->bins_by->{_wh_id_and_id_ident()}->{ _wh_id_and_id_maker($object->warehouse_id, $object->bin_id) }->description;
1099   } else {
1100     push @{ $entry->{errors} }, $::locale->text('Error: Bin not found');
1101     return 0;
1102   }
1103
1104   return 1;
1105 }
1106
1107 sub save_additions {
1108   my ($self, $object) = @_;
1109
1110   # record links
1111   my $orders = delete $object->{source_orders};
1112
1113   if (scalar(@$orders)) {
1114
1115     $_->link_to_record($object) for @$orders;
1116
1117     foreach my $item (@{ $object->items }) {
1118       my $orderitem = delete $item->{source_item};
1119       $orderitem->link_to_record($item) if $orderitem;
1120     }
1121   }
1122
1123   # delivery order for all positions created?
1124   if (scalar(@$orders)) {
1125     SL::Helper::ShippedQty->new->calculate($orders)->write_to_objects;
1126     $_->update_attributes(delivered => $_->delivered) for @{ $orders };
1127   }
1128
1129   # inventory (or use WH->transfer?)
1130   foreach my $item (@{ $object->items }) {
1131     foreach my $stock_info (@{ $item->delivery_order_stock_entries }) {
1132       my $inventory  = delete $stock_info->{inventory_obj};
1133       next if !$inventory;
1134       my ($trans_id) = selectrow_query($::form, $object->db->dbh, qq|SELECT nextval('id')|);
1135       $inventory->trans_id($trans_id);
1136       $inventory->oe_id($object->id);
1137       $inventory->delivery_order_items_stock_id($stock_info->id);
1138       $inventory->save;
1139     }
1140   }
1141 }
1142
1143 sub save_objects {
1144   my ($self, %params) = @_;
1145
1146   # Collect orders without errors to save.
1147   my $entries_to_save = [];
1148   foreach my $entry (@{ $self->controller->data }) {
1149     next if $entry->{raw_data}->{datatype} ne $self->_order_column;
1150     next if @{ $entry->{errors} };
1151
1152     push @{ $entries_to_save }, $entry;
1153   }
1154
1155   $self->SUPER::save_objects(data => $entries_to_save);
1156 }
1157
1158 sub get_stocked_qty {
1159   my ($self, $parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore) = @_;
1160
1161   my $key = join '+', $parts_id, $wh_id, $bin_id, $chargenumber, $bestbefore;
1162   return $self->{stocked_qty}->{$key} if exists $self->{stocked_qty}->{$key};
1163
1164   my $bestbefore_filter  = '';
1165   my $bestbefore_val_cnt = 0;
1166   if ($::instance_conf->get_show_bestbefore) {
1167     $bestbefore_filter  = ($bestbefore) ? 'AND bestbefore = ?' : 'AND bestbefore IS NULL';
1168     $bestbefore_val_cnt = ($bestbefore) ? 1                    : 0;
1169   }
1170
1171   my $query = <<SQL;
1172     SELECT sum(qty) FROM inventory
1173       WHERE parts_id = ? AND warehouse_id = ? AND bin_id = ? AND chargenumber = ? $bestbefore_filter
1174       GROUP BY warehouse_id, bin_id, chargenumber
1175 SQL
1176
1177   my @values = ($parts_id,
1178                 $wh_id,
1179                 $bin_id,
1180                 $chargenumber);
1181   push @values, $bestbefore if $bestbefore_val_cnt;
1182
1183   my $dbh = $self->controller->data->[0]{object}->db->dbh;
1184   my ($stocked_qty) = selectrow_query($::form, $dbh, $query, @values);
1185
1186   $self->{stocked_qty}->{$key} = $stocked_qty;
1187   return $stocked_qty;
1188 }
1189
1190 sub _wh_id_and_description_ident {
1191   return 'wh_id+description';
1192 }
1193
1194 sub _wh_id_and_description_maker {
1195   return join '+', $_[0], $_[1]
1196 }
1197
1198 sub _wh_id_and_id_ident {
1199   return 'wh_id+id';
1200 }
1201
1202 sub _wh_id_and_id_maker {
1203   return join '+', $_[0], $_[1]
1204 }
1205
1206 sub _transfer_type_dir_and_description_ident {
1207   return 'dir+description';
1208 }
1209
1210 sub _transfer_type_dir_and_description_maker {
1211   return join '+', $_[0], $_[1]
1212 }
1213
1214 sub _order_column {
1215   $_[0]->settings->{'order_column'}
1216 }
1217
1218 sub _item_column {
1219   $_[0]->settings->{'item_column'}
1220 }
1221
1222 sub _stock_column {
1223   $_[0]->settings->{'stock_column'}
1224 }
1225
1226 1;