SL/Auth/PasswordPolicy.pm

   1 package SL::Auth::PasswordPolicy;
   2
   3 use strict;
   4
   5 use parent qw(Rose::Object);
   6
   7 use constant OK                   =>  0;
   8 use constant TOO_SHORT            =>  1;
   9 use constant TOO_LONG             =>  2;
  10 use constant MISSING_LOWERCASE    =>  4;
  11 use constant MISSING_UPPERCASE    =>  8;
  12 use constant MISSING_DIGIT        => 16;
  13 use constant MISSING_SPECIAL_CHAR => 32;
  14 use constant INVALID_CHAR         => 64;
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  'scalar --get_set_init' => 'config',
  19 );
  20
  21 sub verify {
  22   my ($self, $password) = @_;
  23
  24   my $cfg = $self->config;
  25   return OK() unless $cfg && %{ $cfg };
  26
  27   my $result = OK();
  28   $result |= TOO_SHORT()            if $cfg->{min_length}                && (length($password) < $cfg->{min_length});
  29   $result |= TOO_LONG()             if $cfg->{max_length}                && (length($password) > $cfg->{max_length});
  30   $result |= MISSING_LOWERCASE()    if $cfg->{require_lowercase}         && $password !~ m/[a-z]/;
  31   $result |= MISSING_UPPERCASE()    if $cfg->{require_uppercase}         && $password !~ m/[A-Z]/;
  32   $result |= MISSING_DIGIT()        if $cfg->{require_digit}             && $password !~ m/[0-9]/;
  33   $result |= MISSING_SPECIAL_CHAR() if $cfg->{require_special_character} && $password !~ $cfg->{special_characters_re};
  34   $result |= INVALID_CHAR()         if $cfg->{invalid_characters_re}     && $password =~ $cfg->{invalid_characters_re};
  35
  36   return $result;
  37 }
  38
  39 sub errors {
  40   my ($self, $result) = @_;
  41
  42   my @errors;
  43
  44   push @errors, $::locale->text('The password is too short (minimum length: #1).', $self->config->{min_length}) if $result & TOO_SHORT();
  45   push @errors, $::locale->text('The password is too long (maximum length: #1).',  $self->config->{max_length}) if $result & TOO_LONG();
  46   push @errors, $::locale->text('A lower-case character is required.')                                          if $result & MISSING_LOWERCASE();
  47   push @errors, $::locale->text('An upper-case character is required.')                                         if $result & MISSING_UPPERCASE();
  48   push @errors, $::locale->text('A digit is required.')                                                         if $result & MISSING_DIGIT();
  49
  50   if ($result & MISSING_SPECIAL_CHAR()) {
  51     my $char_list = join ' ', sort split(m//, $self->config->{special_characters});
  52     push @errors, $::locale->text('A special character is required (valid characters: #1).', $char_list);
  53   }
  54
  55   if (($result & INVALID_CHAR())) {
  56     my $char_list = join ' ', sort split(m//, $self->config->{ $self->config->{invalid_characters} ? 'invalid_characters' : 'valid_characters' });
  57     push @errors, $::locale->text('An invalid character was used (invalid characters: #1).', $char_list) if $self->config->{invalid_characters};
  58     push @errors, $::locale->text('An invalid character was used (valid characters: #1).',   $char_list) if $self->config->{valid_characters};
  59   }
  60
  61   return @errors;
  62 }
  63
  64
  65 sub init_config {
  66   my ($self) = @_;
  67
  68   my %cfg = %{ $::emmvee_conf{password_policy} || {} };
  69
  70   $cfg{valid_characters}      =~ s/[ \n\r]//g if $cfg{valid_characters};
  71   $cfg{invalid_characters}    =~ s/[ \n\r]//g if $cfg{invalid_characters};
  72   $cfg{invalid_characters_re} =  '[^' . quotemeta($cfg{valid_characters})   . ']' if $cfg{valid_characters};
  73   $cfg{invalid_characters_re} =  '['  . quotemeta($cfg{invalid_characters}) . ']' if $cfg{invalid_characters};
  74   $cfg{special_characters}    =  '!@#$%^&*()_+=[]{}<>\'"|\\,;.:?-';
  75   $cfg{special_characters_re} =  '[' . quotemeta($cfg{special_characters}) . ']';
  76   print $cfg{special_characters_re}, "\n";
  77
  78   map { $cfg{"require_${_}"} = $cfg{"require_${_}"} =~ m/^(?:1|true|t|yes|y)$/i } qw(lowercase uppercase digit special_char);
  79
  80   $self->config(\%cfg);
  81 }
  82
  83 1;
  84 __END__
  85
  86 =pod
  87
  88 =encoding utf8
  89
  90 =head1 NAME
  91
  92 SL::Auth::PasswordPolicy - Verify a given password against the policy
  93 set in the configuration file
  94
  95 =head1 SYNOPSIS
  96
  97  my $verifier = SL::Auth::PasswordPolicy->new;
  98  my $result   = $verifier->verify($password);
  99  if ($result != SL::Auth::PasswordPolicy->OK()) {
 100    print "Errors: " . join(' ', $verifier->errors($result)) . "\n";
 101  }
 102
 103 =head1 CONSTANTS
 104
 105 =over 4
 106
 107 =item C<OK>
 108
 109 Password is OK.
 110
 111 =item C<TOO_SHORT>
 112
 113 The password is too short.
 114
 115 =item C<TOO_LONG>
 116
 117 The password is too long.
 118
 119 =item C<MISSING_LOWERCASE>
 120
 121 The password is missing a lower-case character.
 122
 123 =item C<MISSING_UPPERCASE>
 124
 125 The password is missing an upper-case character.
 126
 127 =item C<MISSING_DIGIT>
 128
 129 The password is missing a digit.
 130
 131 =item C<MISSING_SPECIAL_CHAR>
 132
 133 The password is missing a special character. Special characters are
 134 the following: ! " # $ % & ' ( ) * + , - . : ; E<lt> = E<gt> ? @ [ \ ]
 135 ^ _ { | }
 136
 137 =item C<INVALID_CHAR>
 138
 139 The password contains an invalid character.
 140
 141 =back
 142
 143 =head1 FUNCTIONS
 144
 145 =over 4
 146
 147 =item C<verify $password>
 148
 149 Checks whether or not the password matches the policy. Returns C<OK()>
 150 if it does and an error code otherwise (binary or'ed of the error
 151 constants).
 152
 153 =item C<errors $code>
 154
 155 Returns an array of human-readable strings describing the issues set
 156 in C<$code> which should be the result of L</verify>.
 157
 158 =back
 159
 160 =head1 BUGS
 161
 162 Nothing here yet.
 163
 164 =head1 AUTHOR
 165
 166 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 167
 168 =cut