SL/Controller/DeliveryPlan.pm

   1 package SL::Controller::DeliveryPlan;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use Clone qw(clone);
   7 use SL::DB::OrderItem;
   8 use SL::DB::Order::TypeData qw(:types);
   9 use SL::DB::Business;
  10 use SL::Controller::Helper::GetModels;
  11 use SL::Controller::Helper::ReportGenerator;
  12 use SL::Locale::String;
  13 use SL::Helper::ShippedQty;
  14 use SL::AM;
  15 use SL::DBUtils ();
  16 use Carp;
  17
  18 use Rose::Object::MakeMethods::Generic (
  19   'scalar --get_set_init' => [ qw(models all_edit_right vc all_employees all_businesses all_departments) ],
  20 );
  21
  22 __PACKAGE__->run_before(sub { $::auth->assert('delivery_plan'); });
  23
  24 my %sort_columns = (
  25   reqdate           => t8('Reqdate'),
  26   description       => t8('Description'),
  27   partnumber        => t8('Part Number'),
  28   qty               => t8('Qty'),
  29   shipped_qty       => t8('shipped'),
  30   not_shipped_qty   => t8('not shipped'),
  31   ordnumber         => t8('Order'),
  32   customer          => t8('Customer'),
  33   vendor            => t8('Vendor'),
  34 );
  35
  36
  37 sub action_list {
  38   my ($self) = @_;
  39   $self->make_filter_summary;
  40   $self->prepare_report;
  41
  42   my $orderitems = $self->models->get;
  43   $self->calc_qtys($orderitems);
  44   $self->setup_list_action_bar;
  45   $self->report_generator_list_objects(report => $self->{report}, objects => $orderitems);
  46 }
  47
  48 # private functions
  49 #
  50 sub prepare_report {
  51   my ($self)      = @_;
  52
  53   my $vc           = $self->vc;
  54   my $report       = SL::ReportGenerator->new(\%::myconfig, $::form);
  55   $report->{title} = t8('Delivery Plan');
  56   $self->{report}  = $report;
  57
  58   my @columns     = qw(reqdate customer vendor ordnumber partnumber description qty shipped_qty not_shipped_qty);
  59
  60   my @sortable    = qw(reqdate customer vendor ordnumber partnumber description);
  61
  62   my %column_defs = (
  63     reqdate           => {      sub => sub { $_[0]->reqdate_as_date || $_[0]->order->reqdate_as_date                         } },
  64     description       => {      sub => sub { $_[0]->description                                                              },
  65                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  66     partnumber        => {      sub => sub { $_[0]->part->partnumber                                                         },
  67                            obj_link => sub { $self->link_to($_[0]->part)                                                     } },
  68     qty               => {      sub => sub { $_[0]->qty_as_number . ' ' . $_[0]->unit                                        } },
  69     shipped_qty       => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  70     not_shipped_qty   => {      sub => sub { $::form->format_amount(\%::myconfig, $_[0]->qty - $_[0]{shipped_qty}, 2) . ' ' . $_[0]->unit } },
  71     ordnumber         => {      sub => sub { $_[0]->order->ordnumber                                                         },
  72                            obj_link => sub { $self->link_to($_[0]->order)                                                    } },
  73     vendor            => {      sub => sub { $_[0]->order->vendor->name                                                      },
  74                             visible => $vc eq 'vendor',
  75                            obj_link => sub { $self->link_to($_[0]->order->vendor)                                            } },
  76     customer          => {      sub => sub { $_[0]->order->customer->name                                                    },
  77                             visible => $vc eq 'customer',
  78                            obj_link => sub { $self->link_to($_[0]->order->customer)                                          } },
  79   );
  80
  81   $column_defs{$_}->{text} = $sort_columns{$_} for keys %column_defs;
  82
  83   $report->set_options(
  84     std_column_visibility => 1,
  85     controller_class      => 'DeliveryPlan',
  86     output_format         => 'HTML',
  87     top_info_text         => ($vc eq 'customer') ? $::locale->text('Delivery Plan for currently outstanding sales orders') :
  88                                                    $::locale->text('Delivery Plan for currently outstanding purchase orders'),
  89     title                 => $::locale->text('Delivery Plan'),
  90     allow_pdf_export      => 1,
  91     allow_csv_export      => 1,
  92   );
  93   $report->set_columns(%column_defs);
  94   $report->set_column_order(@columns);
  95   $report->set_export_options(qw(list filter vc));
  96   $report->set_options_from_form;
  97   $self->models->disable_plugin('paginated') if $report->{options}{output_format} =~ /^(pdf|csv)$/i;
  98   $self->models->finalize; # for filter laundering
  99   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 100   $self->{assembly_item_number} = $::form->{assembly_item_number} ? $::form->{assembly_item_number} : undef;
 101   $report->set_options(
 102     raw_top_info_text     => $self->render('delivery_plan/report_top',    { output => 0 }),
 103     raw_bottom_info_text  => $self->render('delivery_plan/report_bottom', { output => 0 }, models => $self->models),
 104   );
 105 }
 106
 107 sub calc_qtys {
 108   my ($self, $orderitems) = @_;
 109
 110   return unless scalar @$orderitems;
 111
 112   SL::Helper::ShippedQty
 113     ->new()
 114     ->calculate($orderitems)
 115     ->write_to_objects;
 116 }
 117
 118 sub make_filter_summary {
 119   my ($self) = @_;
 120   my $vc     = $self->vc;
 121   my ($business, $employee, $department, $assembly_item_number);
 122
 123   my $filter = $::form->{filter} || {};
 124   my @filter_strings;
 125
 126   $business = SL::DB::Business->new(id => $filter->{order}{customer}{"business_id"})->load->description if $filter->{order}{customer}{"business_id"};
 127   $employee = SL::DB::Employee->new(id => $filter->{order}{employee_id})->load->name if $filter->{order}{employee_id};
 128   $department = SL::DB::Department->new(id => $filter->{order}{department_id})->load->description if $filter->{order}{department_id};
 129   $assembly_item_number = $::form->{assembly_item_number};
 130
 131   my @filters = (
 132     [ $filter->{order}{"ordnumber:substr::ilike"},                    $::locale->text('Number')                                             ],
 133     [ $filter->{order}{globalproject}{"projectnumber:substr::ilike"}, $::locale->text('Document Project Number')                            ],
 134     [ $filter->{part}{"partnumber:substr::ilike"},                    $::locale->text('Part Number')                                        ],
 135     [ $filter->{"description:substr::ilike"},                         $::locale->text('Part Description')                                   ],
 136     [ $filter->{"reqdate:date::ge"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('From Date') ],
 137     [ $filter->{"reqdate:date::le"},                                  $::locale->text('Delivery Date') . " " . $::locale->text('To Date')   ],
 138     [ $filter->{"qty:number"},                                        $::locale->text('Quantity')                                           ],
 139     [ $filter->{order}{vendor}{"name:substr::ilike"},                 $::locale->text('Vendor')                                             ],
 140     [ $filter->{order}{vendor}{"vendornumber:substr::ilike"},         $::locale->text('Vendor Number')                                      ],
 141     [ $filter->{order}{customer}{"name:substr::ilike"},               $::locale->text('Customer')                                           ],
 142     [ $filter->{order}{customer}{"customernumber:substr::ilike"},     $::locale->text('Customer Number')                                    ],
 143     [ $business,                                                      $::locale->text('Customer type')                                      ],
 144     [ $department,                                                    $::locale->text('Department')                                         ],
 145     [ $employee,                                                      $::locale->text('Employee')                                           ],
 146     [ $assembly_item_number,                                          $::locale->text('Assembly Item Number')                               ],
 147   );
 148
 149   my %flags = (
 150     part     => $::locale->text('Parts'),
 151     service  => $::locale->text('Services'),
 152     assembly => $::locale->text('Assemblies'),
 153   );
 154   my @flags = map { $flags{$_} } @{ $filter->{part}{type} || [] };
 155
 156   for (@flags) {
 157     push @filter_strings, $_ if $_;
 158   }
 159   for (@filters) {
 160     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 161   }
 162
 163   $self->{filter_summary} = join ', ', @filter_strings;
 164 }
 165
 166 sub delivery_plan_query_linked_items {
 167   my ($self) = @_;
 168   my $record_type = ($self->vc eq 'customer' ? SALES_ORDER_TYPE() : PURCHASE_ORDER_TYPE());
 169   my $employee_id = SL::DB::Manager::Employee->current->id;
 170   my $oe_owner = $_[0]->all_edit_right ? '' : " oe.employee_id = $employee_id AND";
 171
 172   [
 173   record_type => $record_type,
 174   'order.closed' => 0,
 175
 176   # filter by shipped_qty < qty, read from innermost to outermost
 177   'id' => [ \"
 178     SELECT id FROM (
 179       SELECT oi.qty, oi.id, SUM(doi.qty) AS doi_qty
 180       FROM orderitems oi, oe, record_links rl, delivery_order_items doi
 181       WHERE
 182         oe.id = oi.trans_id AND
 183         oe.record_type = '$record_type' AND
 184         NOT oe.closed AND
 185         $oe_owner
 186         doi.id = rl.to_id AND
 187         rl.from_table = 'orderitems'AND
 188         rl.to_table   = 'delivery_order_items' AND
 189         rl.from_id = oi.id
 190       GROUP BY oi.id
 191     ) linked
 192     WHERE qty > doi_qty
 193
 194     UNION ALL
 195
 196     -- 2. since the join over record_links fails for items not in any delivery order
 197     --    retrieve those without record_links at all
 198     SELECT oi.id FROM orderitems oi, oe
 199     WHERE
 200       oe.id = oi.trans_id AND
 201       oe.record_type = '$record_type' AND
 202       NOT oe.closed AND
 203       $oe_owner
 204       NOT EXISTS (
 205         SELECT from_id
 206         FROM record_links rl
 207         WHERE
 208           rl.from_table = 'orderitems' AND
 209           rl.to_table = 'delivery_order_items' AND
 210           rl.from_id = oi.id
 211       )
 212
 213   " ], # make emacs happy again: " ]
 214   ]
 215 }
 216
 217 sub init_models {
 218   my ($self) = @_;
 219   my $vc     = $self->vc;
 220
 221   my $query = $self->delivery_plan_query_linked_items;
 222
 223   if ($::form->{assembly_item_number}) {
 224
 225     my $assembly_parts = SL::DB::Manager::Part->get_all(where => [ partnumber => { ilike => '%' . $::form->{assembly_item_number} . '%' } ]);
 226
 227     my @assemblies;
 228
 229     foreach my $assembly_part (@{ $assembly_parts }) {
 230       push @assemblies, SL::DB::Manager::Assembly->get_all(where => [parts_id =>$assembly_part->id]);
 231     }
 232
 233     if (scalar @assemblies > 0) {
 234       my %assembly_ids;
 235       foreach my $list (@assemblies) {
 236         foreach my $assembly (@{ $list }) {
 237           $assembly_ids{$assembly->id} = 1;
 238         }
 239       }
 240       my @assembly_ids_array = (keys %assembly_ids);
 241       $::form->{filter}{part}{id} = { or => [ @assembly_ids_array ] };
 242     }
 243   }
 244
 245   SL::Controller::Helper::GetModels->new(
 246     controller   => $self,
 247     model        => 'OrderItem',
 248     sorted       => {
 249       _default     => {
 250         by           => 'reqdate',
 251         dir          => 1,
 252       },
 253       %sort_columns,
 254     },
 255     query        => $query,
 256     with_objects => [ 'order', "order.$vc", 'part' ],
 257     additional_url_params => { vc => $vc },
 258   );
 259 }
 260
 261 sub init_all_edit_right {
 262   return $_[0]->vc eq 'customer' ? $::auth->assert('sales_all_edit', 1) : $::auth->assert('purchase_all_edit', 1);
 263 }
 264 sub init_vc {
 265   return $::form->{vc} if ($::form->{vc} eq 'customer' || $::form->{vc} eq 'vendor') || croak "self (DeliveryPlan) has no vc defined";
 266 }
 267
 268 sub init_all_employees {
 269   return SL::DB::Manager::Employee->get_all_sorted;
 270 }
 271 sub init_all_businesses {
 272   return SL::DB::Manager::Business->get_all_sorted;
 273 }
 274 sub init_all_departments {
 275   return SL::DB::Manager::Department->get_all_sorted;
 276 }
 277 sub link_to {
 278   my ($self, $object, %params) = @_;
 279
 280   return unless $object;
 281   my $action = $params{action} || 'edit';
 282
 283   if ($object->isa('SL::DB::Order')) {
 284     my $type   = $object->type;
 285     my $id     = $object->id;
 286     return "controller.pl?action=Order/$action&type=$type&id=$id";
 287   }
 288   if ($object->isa('SL::DB::Part')) {
 289     my $id     = $object->id;
 290     return "controller.pl?action=Part/$action&part.id=$id";
 291   }
 292   if ($object->isa('SL::DB::Customer')) {
 293     my $id     = $object->id;
 294     return "controller.pl?action=CustomerVendor/$action&id=$id&db=customer";
 295   }
 296 }
 297
 298 sub setup_list_action_bar {
 299   my ($self, %params) = @_;
 300
 301   for my $bar ($::request->layout->get('actionbar')) {
 302     $bar->add(
 303       action => [
 304         t8('Update'),
 305         submit    => [ '#filter_form', { action => 'DeliveryPlan/list' } ],
 306         accesskey => 'enter',
 307       ],
 308     );
 309   }
 310 }
 311
 312 1;