SL/DB/Manager/Order.pm

   1 package SL::DB::Manager::Order;
   2
   3 use strict;
   4
   5 use parent qw(SL::DB::Helper::Manager);
   6
   7 use SL::DB::Order::TypeData qw(:types);
   8 use SL::DB::Helper::Paginated;
   9 use SL::DB::Helper::Sorted;
  10 use SL::DB::Helper::Filtered;
  11
  12 use List::MoreUtils qw(any);
  13
  14 sub object_class { 'SL::DB::Order' }
  15
  16 __PACKAGE__->make_manager_methods;
  17
  18 __PACKAGE__->add_filter_specs(
  19   type => sub {
  20     my ($key, $value, $prefix) = @_;
  21     return __PACKAGE__->type_filter($value, $prefix);
  22   },
  23   all => sub {
  24     my ($key, $value, $prefix) = @_;
  25     return or => [ map { $prefix . $_ => $value } qw(ordnumber quonumber customer.name vendor.name transaction_description) ]
  26   }
  27 );
  28
  29 sub type_filter {
  30   my $class  = shift;
  31   my $type   = lc(shift || '');
  32   my $prefix = shift || '';
  33
  34   return ("${prefix}record_type" => $type) if( any {$type eq $_} (
  35       SALES_ORDER_INTAKE_TYPE(),
  36       SALES_ORDER_TYPE(),
  37       SALES_QUOTATION_TYPE(),
  38       PURCHASE_ORDER_TYPE(),
  39       PURCHASE_ORDER_CONFIRMATION_TYPE(),
  40       REQUEST_QUOTATION_TYPE(),
  41       PURCHASE_QUOTATION_INTAKE_TYPE(),
  42     ));
  43
  44   die "Unknown type $type";
  45 }
  46
  47 sub _sort_spec {
  48   return (
  49     default                   => [ 'transdate', 1 ],
  50     nulls                     => {
  51       transaction_description => 'FIRST',
  52       customer_name           => 'FIRST',
  53       vendor_name             => 'FIRST',
  54       default                 => 'LAST',
  55     },
  56     columns                   => {
  57       SIMPLE                  => 'ALL',
  58       customer                => 'lower(customer.name)',
  59       vendor                  => 'lower(vendor.name)',
  60       globalprojectnumber     => 'lower(globalproject.projectnumber)',
  61
  62       # Bug in Rose::DB::Object: the next should be
  63       # "globalproject.project_type.description". This workaround will
  64       # only work if no other table with "project_type" is visible in
  65       # the current query
  66       globalproject_type      => 'lower(project_type.description)',
  67
  68       map { ( $_ => "lower(oe.$_)" ) } qw(ordnumber quonumber cusordnumber shippingpoint shipvia notes intnotes transaction_description),
  69     });
  70 }
  71
  72 sub default_objects_per_page { 40 }
  73
  74 1;