SL/DB/Manager/Part.pm

   1 package SL::DB::Manager::Part;
   2
   3 use strict;
   4
   5 use SL::DB::Helper::Manager;
   6 use SL::DB::Helper::Sorted;
   7 use SL::DB::Helper::Paginated;
   8 use SL::DB::Helper::Filtered;
   9 use base qw(SL::DB::Helper::Manager);
  10
  11 use Carp;
  12 use SL::DBUtils;
  13 use SL::MoreCommon qw(listify);
  14
  15 sub object_class { 'SL::DB::Part' }
  16
  17 __PACKAGE__->make_manager_methods;
  18 __PACKAGE__->add_filter_specs(
  19   part_type => sub {
  20     my ($key, $value, $prefix) = @_;
  21     return __PACKAGE__->type_filter($value, $prefix);
  22   },
  23   all => sub {
  24     my ($key, $value, $prefix) = @_;
  25     return or => [ map { $prefix . $_ => $value } qw(partnumber description ean) ]
  26   },
  27   all_with_makemodel => sub {
  28     my ($key, $value, $prefix) = @_;
  29     return or => [ map { $prefix . $_ => $value } qw(partnumber description ean makemodels.model) ],
  30       $prefix . 'makemodels';
  31   },
  32   all_with_customer_partnumber => sub {
  33     my ($key, $value, $prefix) = @_;
  34     return or => [ map { $prefix . $_ => $value } qw(partnumber description ean customerprices.customer_partnumber) ],
  35       $prefix . 'customerprices';
  36   },
  37 );
  38
  39 sub type_filter {
  40   my ($class, $type, $prefix) = @_;
  41
  42   return () unless $type;
  43
  44   $prefix //= '';
  45
  46   # this is to make selections like part_type => { part => 1, service => 1 } work
  47   if ('HASH' eq ref $type) {
  48     $type = [ grep { $type->{$_} } keys %$type ];
  49   }
  50
  51   my @types = grep { $_ } listify($type);
  52   my @filter;
  53
  54   for my $type (@types) {
  55     if ($type =~ m/^part/) {
  56       push @filter, ($prefix . part_type => 'part');
  57     } elsif ($type =~ m/^service/) {
  58       push @filter, ($prefix . part_type => 'service');
  59     } elsif ($type =~ m/^assembly/) {
  60       push @filter, ($prefix . part_type => 'assembly');
  61     } elsif ($type =~ m/^assortment/) {
  62       push @filter, ($prefix . part_type => 'assortment');
  63     }
  64   }
  65
  66   return @filter > 2 ? (or => \@filter) : @filter;
  67 }
  68
  69 sub get_ordered_qty {
  70   my $class    = shift;
  71   my @part_ids = @_;
  72
  73   return () unless @part_ids;
  74
  75   my $placeholders = join ',', ('?') x @part_ids;
  76   my $query        = <<SQL;
  77     SELECT oi.parts_id, SUM(oi.base_qty) AS qty
  78     FROM orderitems oi
  79     LEFT JOIN oe ON (oi.trans_id = oe.id)
  80     WHERE (oi.parts_id IN ($placeholders))
  81       AND oe.record_type = 'purchase_order'
  82       AND (NOT COALESCE(oe.closed,    FALSE))
  83       AND (NOT COALESCE(oe.delivered, FALSE))
  84     GROUP BY oi.parts_id
  85 SQL
  86
  87   my %qty_by_id = map { $_->{parts_id} => $_->{qty} * 1 } @{ selectall_hashref_query($::form, $class->object_class->init_db->dbh, $query, @part_ids) };
  88   map { $qty_by_id{$_} ||= 0 } @part_ids;
  89
  90   return %qty_by_id;
  91 }
  92
  93 sub get_open_ordered_qty {
  94   my $class    = shift;
  95   my $part_id  = shift;
  96   return () unless $part_id;
  97
  98   my $query = <<SQL;
  99 WITH
 100 open_qty AS (
 101   SELECT parts_id, sum(oi.qty) as sum
 102   FROM orderitems oi
 103   LEFT OUTER JOIN oe o ON (oi.trans_id = o.id)
 104   WHERE
 105     oi.parts_id = ?
 106     AND (o.record_type = 'purchase_order')
 107     AND (NOT COALESCE(o.closed,    FALSE))
 108     AND (NOT COALESCE(o.delivered, FALSE))
 109     AND (COALESCE(o.vendor_id, 0) <> 0)
 110   GROUP BY oi.parts_id
 111 ),
 112
 113 open_orderitems_ids AS (
 114   SELECT oi.id, parts_id
 115   FROM orderitems oi
 116   LEFT OUTER JOIN oe o ON (oi.trans_id = o.id)
 117   WHERE
 118     oi.parts_id = ?
 119     AND (o.record_type = 'purchase_order')
 120     AND (NOT COALESCE(o.closed,    FALSE))
 121     AND (NOT COALESCE(o.delivered, FALSE))
 122     AND (o.vendor_id is not null)
 123 ),
 124
 125 delivered_qty AS (
 126   SELECT parts_id, sum(qty) AS sum
 127   FROM delivery_order_items
 128   WHERE id IN (
 129     SELECT to_id from record_links
 130     WHERE
 131       from_id IN ( SELECT id FROM open_orderitems_ids)
 132       AND from_table = 'orderitems'
 133       AND to_table = 'delivery_order_items'
 134   ) AND parts_id = ?
 135   GROUP BY parts_id
 136 ),
 137
 138 open_ordered_qty AS (
 139   SELECT
 140     oq.parts_id,
 141     oq.sum AS ordered_sum,
 142     COALESCE(dq.sum,0.00) AS sum,
 143     sum(COALESCE(oq.sum,0.00) - COALESCE(dq.sum,0.00)) AS open_qty
 144   FROM open_qty oq
 145   LEFT JOIN delivered_qty dq ON dq.parts_id = oq.parts_id
 146   GROUP BY oq.parts_id, oq.sum, dq.sum
 147 )
 148
 149 SELECT open_qty FROM open_ordered_qty
 150
 151 SQL
 152
 153   my ($open_qty) = selectfirst_array_query(
 154     $::form, $class->object_class->init_db->dbh,
 155     $query, $part_id, $part_id, $part_id
 156   );
 157
 158   $open_qty ||= 0;
 159   return $open_qty
 160 }
 161
 162 sub _sort_spec {
 163   (
 164     default  => [ 'partnumber', 1 ],
 165     columns  => {
 166       SIMPLE => 'ALL',
 167     },
 168     nulls    => {},
 169   );
 170 }
 171
 172 1;
 173 __END__
 174
 175 =pod
 176
 177 =encoding utf8
 178
 179 =head1 NAME
 180
 181 SL::DB::Manager::Part - RDBO manager for the C<parts> table
 182
 183 =head1 FUNCTIONS
 184
 185 =over 4
 186
 187 =item C<get_ordered_qty @part_ids>
 188
 189 For each of the given part IDs the ordered quantity is
 190 calculated. This is done by summing over all open purchase orders.
 191
 192 Returns a hash with the part IDs being the keys and the ordered
 193 quantities being the values.
 194
 195 =item C<type_filter @types>
 196
 197 Constructs a partial filter for matching any of the article types
 198 given with C<@types>. The returned partial filter is suitable for a
 199 Rose manager query.
 200
 201 Each type can be either 'C<part>', 'C<service>' or 'C<assembly>'
 202 (their plurals are recognized as well). If multiple types are given
 203 then they're combined with C<OR>.
 204
 205 =back
 206
 207 =head1 BUGS
 208
 209 Nothing here yet.
 210
 211 =head1 AUTHOR
 212
 213 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>,
 214 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 215
 216 =cut