SL/Presenter/DeliveryOrder.pm

   1 package SL::Presenter::DeliveryOrder;
   2
   3 use strict;
   4
   5 use SL::DB::DeliveryOrder::TypeData ();
   6 use SL::Locale::String qw(t8);
   7 use SL::Presenter::EscapedText qw(escape is_escaped);
   8 use SL::Presenter::Tag         qw(link_tag);
   9
  10 use Exporter qw(import);
  11 our @EXPORT_OK = qw(
  12   show delivery_order delivery_order_status_line
  13   sales_delivery_order purchase_delivery_order
  14   rma_delivery_order supplier_delivery_order
  15 );
  16
  17 use Carp;
  18
  19 sub show {goto &delivery_order};
  20
  21 sub sales_delivery_order {goto &delivery_order}
  22
  23 sub rma_delivery_order {goto &delivery_order};
  24
  25 sub purchase_delivery_order {goto &delivery_order};
  26
  27 sub supplier_delivery_order {goto &delivery_order};
  28
  29 sub delivery_order {
  30   my ($delivery_order, %params) = @_;
  31   my $type = $delivery_order->record_type;
  32
  33   $params{display} ||= 'inline';
  34
  35   croak "Unknown display type '$params{display}'" unless $params{display} =~ m/^(?:inline|table-cell)$/;
  36
  37   my $text = escape($delivery_order->donumber);
  38   if (! delete $params{no_link}) {
  39     my $href = 'controller.pl?action=DeliveryOrder/edit'
  40                . '&type=' . $type
  41                . '&id=' . escape($delivery_order->id);
  42     $text = link_tag($href, $text, %params);
  43   }
  44
  45   is_escaped($text);
  46 }
  47
  48 sub stock_status {
  49   my ($delivery_order) = @_;
  50
  51   my $in_out = SL::DB::DeliveryOrder::TypeData::get3($delivery_order->type, "properties", "transfer");
  52
  53   if ($in_out eq 'in') {
  54     return escape($delivery_order->delivered ? t8('transferred in') : t8('not transferred in yet'));
  55   }
  56
  57   if ($in_out eq 'out') {
  58     return escape($delivery_order->delivered ? t8('transferred out') : t8('not transferred out yet'));
  59   }
  60 }
  61
  62 sub closed_status {
  63   my ($delivery_order) = @_;
  64
  65   return escape($delivery_order->closed ? t8('Closed') : t8('Open'))
  66 }
  67
  68 sub status_line {
  69   my ($delivery_order) = @_;
  70
  71   return "" unless $delivery_order->id;
  72
  73   stock_status($delivery_order) . " ; " . closed_status($delivery_order)
  74 }
  75
  76 sub delivery_order_status_line { goto &status_line };
  77
  78 1;
  79
  80 __END__
  81
  82 =pod
  83
  84 =encoding utf8
  85
  86 =head1 NAME
  87
  88 SL::Presenter::DeliveryOrder - Presenter module for Rose::DB objects
  89 for sales and purchase delivery orders
  90
  91 =head1 SYNOPSIS
  92
  93   # Sales delivery orders:
  94   my $object = SL::DB::Manager::DeliveryOrder->get_first(where => [ record_type  => SALES_DELIVERY_ORDER_TYPE ]);
  95   my $html   = SL::Presenter::DeliveryOrder::sales_delivery_order($object, display => 'inline');
  96
  97   # Purchase delivery orders:
  98   my $object = SL::DB::Manager::DeliveryOrder->get_first(where => [ record_type  => PURCHASE_DELIVERY_ORDER_TYPE ]);
  99   my $html   = SL::Presenter::DeliveryOrder::purchase_delivery_order($object, display => 'inline');
 100
 101   #...
 102
 103   # or for all types:
 104   my $html   = SL::Presenter::DeliveryOrder::delivery_order($object);
 105   my $html   = $object->presenter->show();
 106
 107 =head1 FUNCTIONS
 108
 109 =over 4
 110
 111 =item C<show $object %params>
 112
 113 Alias for C<delivery_order $object %params>.
 114
 115 =item C<sales_delivery_order $object, %params>
 116
 117 Alias for C<delivery_order $object %params>.
 118
 119 =item C<purchase_delivery_order $object, %params>
 120
 121 Alias for C<delivery_order $object %params>.
 122
 123 =item C<rma_delivery_order $object, %params>
 124
 125 Alias for C<delivery_order $object %params>.
 126
 127 =item C<supplier_delivery_order $object, %params>
 128
 129 Alias for C<delivery_order $object %params>.
 130
 131 =item C<delivery_order $object, %params>
 132
 133 Returns a rendered version (actually an instance of
 134 L<SL::Presenter::EscapedText>) of the sales delivery order object
 135 C<$object>.
 136
 137 Remaining C<%params> are passed to the function
 138 L<SL::Presenter::Tag/link_tag>. It can include:
 139
 140 =over 2
 141
 142 =item * display
 143
 144 Either C<inline> (the default) or C<table-cell>. Is passed to the function
 145 C<SL::Presenter::Tag::link_tag>.
 146
 147 =item * no_link
 148
 149 If falsish (the default) then the delivery order number will be linked
 150 to the "edit delivery order" dialog from the sales menu.
 151
 152 =back
 153
 154 =back
 155
 156 =head1 BUGS
 157
 158 Nothing here yet.
 159
 160 =head1 AUTHOR
 161
 162 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>
 163
 164 =cut