SL/Controller/Order.pm

   1 package SL::Controller::Order;
   2
   3 use strict;
   4 use parent qw(SL::Controller::Base);
   5
   6 use SL::Helper::Flash qw(flash_later);
   7 use SL::Presenter;
   8 use SL::Locale::String qw(t8);
   9 use SL::SessionFile::Random;
  10 use SL::PriceSource;
  11 use SL::Webdav;
  12
  13 use SL::DB::Order;
  14 use SL::DB::Default;
  15 use SL::DB::Unit;
  16 use SL::DB::Part;
  17 use SL::DB::Printer;
  18 use SL::DB::Language;
  19
  20 use SL::Helper::CreatePDF qw(:all);
  21 use SL::Helper::PrintOptions;
  22
  23 use SL::Controller::Helper::GetModels;
  24
  25 use List::Util qw(first);
  26 use List::MoreUtils qw(none pairwise first_index);
  27 use English qw(-no_match_vars);
  28 use File::Spec;
  29
  30 use Rose::Object::MakeMethods::Generic
  31 (
  32  scalar => [ qw(item_ids_to_delete) ],
  33  'scalar --get_set_init' => [ qw(order valid_types type cv p multi_items_models all_price_factors) ],
  34 );
  35
  36
  37 # safety
  38 __PACKAGE__->run_before('_check_auth');
  39
  40 __PACKAGE__->run_before('_recalc',
  41                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  42
  43 __PACKAGE__->run_before('_get_unalterable_data',
  44                         only => [ qw(save save_and_delivery_order print create_pdf send_email) ]);
  45
  46 #
  47 # actions
  48 #
  49
  50 # add a new order
  51 sub action_add {
  52   my ($self) = @_;
  53
  54   $self->order->transdate(DateTime->now_local());
  55   $self->order->reqdate(DateTime->today_local->next_workday) if !$self->order->reqdate;
  56
  57   $self->_pre_render();
  58   $self->render(
  59     'order/form',
  60     title => $self->type eq _sales_order_type()    ? $::locale->text('Add Sales Order')
  61            : $self->type eq _purchase_order_type() ? $::locale->text('Add Purchase Order')
  62            : '',
  63     %{$self->{template_args}}
  64   );
  65 }
  66
  67 # edit an existing order
  68 sub action_edit {
  69   my ($self) = @_;
  70
  71   $self->_load_order;
  72   $self->_recalc();
  73   $self->_pre_render();
  74   $self->render(
  75     'order/form',
  76     title => $self->type eq _sales_order_type()    ? $::locale->text('Edit Sales Order')
  77            : $self->type eq _purchase_order_type() ? $::locale->text('Edit Purchase Order')
  78            : '',
  79     %{$self->{template_args}}
  80   );
  81 }
  82
  83 # delete the order
  84 sub action_delete {
  85   my ($self) = @_;
  86
  87   my $errors = $self->_delete();
  88
  89   if (scalar @{ $errors }) {
  90     $self->js->flash('error', $_) foreach @{ $errors };
  91     return $self->js->render();
  92   }
  93
  94   flash_later('info', $::locale->text('The order has been deleted'));
  95   my @redirect_params = (
  96     action => 'add',
  97     type   => $self->type,
  98   );
  99
 100   $self->redirect_to(@redirect_params);
 101 }
 102
 103 # save the order
 104 sub action_save {
 105   my ($self) = @_;
 106
 107   my $errors = $self->_save();
 108
 109   if (scalar @{ $errors }) {
 110     $self->js->flash('error', $_) foreach @{ $errors };
 111     return $self->js->render();
 112   }
 113
 114   flash_later('info', $::locale->text('The order has been saved'));
 115   my @redirect_params = (
 116     action => 'edit',
 117     type   => $self->type,
 118     id     => $self->order->id,
 119   );
 120
 121   $self->redirect_to(@redirect_params);
 122 }
 123
 124 # print the order
 125 #
 126 # This is called if "print" is pressed in the print dialog.
 127 # If PDF creation was requested and succeeded, the pdf is stored in a session
 128 # file and the filename is stored as session value with an unique key. A
 129 # javascript function with this key is then called. This function calls the
 130 # download action below (action_download_pdf), which offers the file for
 131 # download.
 132 sub action_print {
 133   my ($self) = @_;
 134
 135   my $format      = $::form->{print_options}->{format};
 136   my $media       = $::form->{print_options}->{media};
 137   my $formname    = $::form->{print_options}->{formname};
 138   my $copies      = $::form->{print_options}->{copies};
 139   my $groupitems  = $::form->{print_options}->{groupitems};
 140
 141   # only pdf by now
 142   if (none { $format eq $_ } qw(pdf)) {
 143     return $self->js->flash('error', t8('Format \'#1\' is not supported yet/anymore.', $format))->render;
 144   }
 145
 146   # only screen or printer by now
 147   if (none { $media eq $_ } qw(screen printer)) {
 148     return $self->js->flash('error', t8('Media \'#1\' is not supported yet/anymore.', $media))->render;
 149   }
 150
 151   my $language;
 152   $language = SL::DB::Language->new(id => $::form->{print_options}->{language_id})->load if $::form->{print_options}->{language_id};
 153
 154   my $form = Form->new;
 155   $form->{ordnumber} = $self->order->ordnumber;
 156   $form->{type}      = $self->type;
 157   $form->{format}    = $format;
 158   $form->{formname}  = $formname;
 159   $form->{language}  = '_' . $language->template_code if $language;
 160   my $pdf_filename   = $form->generate_attachment_filename();
 161
 162   my $pdf;
 163   my @errors = _create_pdf($self->order, \$pdf, { format     => $format,
 164                                                   formname   => $formname,
 165                                                   language   => $language,
 166                                                   groupitems => $groupitems });
 167   if (scalar @errors) {
 168     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render;
 169   }
 170
 171   if ($media eq 'screen') {
 172     # screen/download
 173     my $sfile = SL::SessionFile::Random->new(mode => "w");
 174     $sfile->fh->print($pdf);
 175     $sfile->fh->close;
 176
 177     my $key = join('_', Time::HiRes::gettimeofday(), int rand 1000000000000);
 178     $::auth->set_session_value("Order::create_pdf-${key}" => $sfile->file_name);
 179
 180     $self->js
 181     ->run('kivi.Order.download_pdf', $pdf_filename, $key)
 182     ->flash('info', t8('The PDF has been created'));
 183
 184   } elsif ($media eq 'printer') {
 185     # printer
 186     my $printer_id = $::form->{print_options}->{printer_id};
 187     SL::DB::Printer->new(id => $printer_id)->load->print_document(
 188       copies  => $copies,
 189       content => $pdf,
 190     );
 191
 192     $self->js->flash('info', t8('The PDF has been printed'));
 193   }
 194
 195   # copy file to webdav folder
 196   if ($self->order->ordnumber && $::instance_conf->get_webdav_documents) {
 197     my $webdav = SL::Webdav->new(
 198       type     => $self->type,
 199       number   => $self->order->ordnumber,
 200     );
 201     my $webdav_file = SL::Webdav::File->new(
 202       webdav   => $webdav,
 203       filename => $pdf_filename,
 204     );
 205     eval {
 206       $webdav_file->store(data => \$pdf);
 207       1;
 208     } or do {
 209       $self->js->flash('error', t8('Storing PDF to webdav folder failed: #1', $@));
 210     }
 211   }
 212
 213   $self->js->render;
 214 }
 215
 216 # offer pdf for download
 217 #
 218 # It needs to get the key for the session value to get the pdf file.
 219 sub action_download_pdf {
 220   my ($self) = @_;
 221
 222   my $key = $::form->{key};
 223   my $tmp_filename = $::auth->get_session_value("Order::create_pdf-${key}");
 224   return $self->send_file(
 225     $tmp_filename,
 226     type => 'application/pdf',
 227     name => $::form->{pdf_filename},
 228   );
 229 }
 230
 231 # open the email dialog
 232 sub action_show_email_dialog {
 233   my ($self) = @_;
 234
 235   my $cv_method = $self->cv;
 236
 237   if (!$self->order->$cv_method) {
 238     return $self->js->flash('error', $self->cv eq 'customer' ? t8('Cannot send E-mail without customer given') : t8('Cannot send E-mail without vendor given'))
 239                     ->render($self);
 240   }
 241
 242   $self->{email}->{to}   = $self->order->contact->cp_email if $self->order->contact;
 243   $self->{email}->{to} ||= $self->order->$cv_method->email;
 244   $self->{email}->{cc}   = $self->order->$cv_method->cc;
 245   $self->{email}->{bcc}  = join ', ', grep $_, $self->order->$cv_method->bcc, SL::DB::Default->get->global_bcc;
 246   # Todo: get addresses from shipto, if any
 247
 248   my $form = Form->new;
 249   $form->{ordnumber} = $self->order->ordnumber;
 250   $form->{formname}  = $self->type;
 251   $form->{type}      = $self->type;
 252   $form->{language} = 'de';
 253   $form->{format}   = 'pdf';
 254
 255   $self->{email}->{subject}             = $form->generate_email_subject();
 256   $self->{email}->{attachment_filename} = $form->generate_attachment_filename();
 257   $self->{email}->{message}             = $form->create_email_signature();
 258
 259   my $dialog_html = $self->render('order/tabs/_email_dialog', { output => 0 });
 260   $self->js
 261       ->run('kivi.Order.show_email_dialog', $dialog_html)
 262       ->reinit_widgets
 263       ->render($self);
 264 }
 265
 266 # send email
 267 #
 268 # Todo: handling error messages: flash is not displayed in dialog, but in the main form
 269 sub action_send_email {
 270   my ($self) = @_;
 271
 272   my $mail      = Mailer->new;
 273   $mail->{from} = qq|"$::myconfig{name}" <$::myconfig{email}>|;
 274   $mail->{$_}   = $::form->{email}->{$_} for qw(to cc bcc subject message);
 275
 276   my $pdf;
 277   my @errors = _create_pdf($self->order, \$pdf, {media => 'email'});
 278   if (scalar @errors) {
 279     return $self->js->flash('error', t8('Conversion to PDF failed: #1', $errors[0]))->render($self);
 280   }
 281
 282   $mail->{attachments} = [{ "content" => $pdf,
 283                             "name"    => $::form->{email}->{attachment_filename} }];
 284
 285   if (my $err = $mail->send) {
 286     return $self->js->flash('error', t8('Sending E-mail: ') . $err)
 287                     ->render($self);
 288   }
 289
 290   # internal notes
 291   my $intnotes = $self->order->intnotes;
 292   $intnotes   .= "\n\n" if $self->order->intnotes;
 293   $intnotes   .= t8('[email]')                                                                                        . "\n";
 294   $intnotes   .= t8('Date')       . ": " . $::locale->format_date_object(DateTime->now_local, precision => 'seconds') . "\n";
 295   $intnotes   .= t8('To (email)') . ": " . $mail->{to}                                                                . "\n";
 296   $intnotes   .= t8('Cc')         . ": " . $mail->{cc}                                                                . "\n"    if $mail->{cc};
 297   $intnotes   .= t8('Bcc')        . ": " . $mail->{bcc}                                                               . "\n"    if $mail->{bcc};
 298   $intnotes   .= t8('Subject')    . ": " . $mail->{subject}                                                           . "\n\n";
 299   $intnotes   .= t8('Message')    . ": " . $mail->{message};
 300
 301   $self->js
 302       ->val('#order_intnotes', $intnotes)
 303       ->run('kivi.Order.close_email_dialog')
 304       ->render($self);
 305 }
 306
 307 # save the order and redirect to the frontend subroutine for a new
 308 # delivery order
 309 sub action_save_and_delivery_order {
 310   my ($self) = @_;
 311
 312   my $errors = $self->_save();
 313
 314   if (scalar @{ $errors }) {
 315     $self->js->flash('error', $_) foreach @{ $errors };
 316     return $self->js->render();
 317   }
 318   flash_later('info', $::locale->text('The order has been saved'));
 319
 320   my @redirect_params = (
 321     controller => 'oe.pl',
 322     action     => 'oe_delivery_order_from_order',
 323     id         => $self->order->id,
 324   );
 325
 326   $self->redirect_to(@redirect_params);
 327 }
 328
 329 # set form elements in respect of a changed customer or vendor
 330 #
 331 # This action is called on an change of the customer/vendor picker.
 332 sub action_customer_vendor_changed {
 333   my ($self) = @_;
 334
 335   my $cv_method = $self->cv;
 336
 337   if ($self->order->$cv_method->contacts && scalar @{ $self->order->$cv_method->contacts } > 0) {
 338     $self->js->show('#cp_row');
 339   } else {
 340     $self->js->hide('#cp_row');
 341   }
 342
 343   if ($self->order->$cv_method->shipto && scalar @{ $self->order->$cv_method->shipto } > 0) {
 344     $self->js->show('#shipto_row');
 345   } else {
 346     $self->js->hide('#shipto_row');
 347   }
 348
 349   $self->order->taxzone_id($self->order->$cv_method->taxzone_id);
 350
 351   if ($self->order->is_sales) {
 352     $self->order->taxincluded(defined($self->order->$cv_method->taxincluded_checked)
 353                               ? $self->order->$cv_method->taxincluded_checked
 354                               : $::myconfig{taxincluded_checked});
 355   }
 356
 357   $self->order->payment_id($self->order->$cv_method->payment_id);
 358   $self->order->delivery_term_id($self->order->$cv_method->delivery_term_id);
 359
 360   $self->_recalc();
 361
 362   $self->js
 363     ->replaceWith('#order_cp_id',            $self->build_contact_select)
 364     ->replaceWith('#order_shipto_id',        $self->build_shipto_select)
 365     ->val(        '#order_taxzone_id',       $self->order->taxzone_id)
 366     ->val(        '#order_taxincluded',      $self->order->taxincluded)
 367     ->val(        '#order_payment_id',       $self->order->payment_id)
 368     ->val(        '#order_delivery_term_id', $self->order->delivery_term_id)
 369     ->val(        '#order_intnotes',         $self->order->$cv_method->notes)
 370     ->focus(      '#order_' . $self->cv . '_id');
 371
 372   $self->_js_redisplay_amounts_and_taxes;
 373   $self->js->render();
 374 }
 375
 376 # called if a unit in an existing item row is changed
 377 sub action_unit_changed {
 378   my ($self) = @_;
 379
 380   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 381   my $item = $self->order->items_sorted->[$idx];
 382
 383   my $old_unit_obj = SL::DB::Unit->new(name => $::form->{old_unit})->load;
 384   $item->sellprice($item->unit_obj->convert_to($item->sellprice, $old_unit_obj));
 385
 386   $self->_recalc();
 387
 388   $self->js
 389     ->run('kivi.Order.update_sellprice', $::form->{item_id}, $item->sellprice_as_number);
 390   $self->_js_redisplay_linetotals;
 391   $self->_js_redisplay_amounts_and_taxes;
 392   $self->js->render();
 393 }
 394
 395 # add an item row for a new item entered in the input row
 396 sub action_add_item {
 397   my ($self) = @_;
 398
 399   my $form_attr = $::form->{add_item};
 400
 401   return unless $form_attr->{parts_id};
 402
 403   my $item = _new_item($self->order, $form_attr);
 404
 405   $self->order->add_items($item);
 406
 407   $self->_recalc();
 408
 409   my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 410   my $row_as_html = $self->p->render('order/tabs/_row',
 411                                      ITEM              => $item,
 412                                      ID                => $item_id,
 413                                      ALL_PRICE_FACTORS => $self->all_price_factors
 414   );
 415
 416   $self->js
 417     ->append('#row_table_id', $row_as_html);
 418
 419   if ( $item->part->is_assortment ) {
 420     $form_attr->{qty_as_number} = 1 unless $form_attr->{qty_as_number};
 421     foreach my $assortment_item ( @{$item->part->assortment_items} ) {
 422       my $attr = { parts_id => $assortment_item->parts_id,
 423                    qty      => $assortment_item->qty * $::form->parse_amount(\%::myconfig, $form_attr->{qty_as_number}), # TODO $form_attr->{unit}
 424                    unit     => $assortment_item->unit,
 425                    description => $assortment_item->part->description,
 426                  };
 427       my $item = _new_item($self->order, $attr);
 428       $self->order->add_items( $item );
 429       $self->_recalc();
 430       my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 431       my $row_as_html = $self->p->render('order/tabs/_row',
 432                                          ITEM              => $item,
 433                                          ID                => $item_id,
 434                                          ALL_PRICE_FACTORS => $self->all_price_factors
 435       );
 436       $self->js
 437         ->append('#row_table_id', $row_as_html);
 438     };
 439   };
 440
 441   $self->js
 442     ->val('.add_item_input', '')
 443     ->run('kivi.Order.init_row_handlers')
 444     ->run('kivi.Order.row_table_scroll_down')
 445     ->run('kivi.Order.renumber_positions')
 446     ->focus('#add_item_parts_id_name');
 447
 448   $self->_js_redisplay_amounts_and_taxes;
 449   $self->js->render();
 450 }
 451
 452 # open the dialog for entering multiple items at once
 453 sub action_show_multi_items_dialog {
 454   require SL::DB::PartsGroup;
 455   $_[0]->render('order/tabs/_multi_items_dialog', { layout => 0 },
 456                 all_partsgroups => SL::DB::Manager::PartsGroup->get_all);
 457 }
 458
 459 # update the filter results in the multi item dialog
 460 sub action_multi_items_update_result {
 461   my $max_count = 100;
 462
 463   $::form->{multi_items}->{filter}->{obsolete} = 0;
 464
 465   my $count = $_[0]->multi_items_models->count;
 466
 467   if ($count == 0) {
 468     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('No results.'));
 469     $_[0]->render($text, { layout => 0 });
 470   } elsif ($count > $max_count) {
 471     my $text = SL::Presenter::EscapedText->new(text => $::locale->text('Too many results (#1 from #2).', $count, $max_count));
 472     $_[0]->render($text, { layout => 0 });
 473   } else {
 474     my $multi_items = $_[0]->multi_items_models->get;
 475     $_[0]->render('order/tabs/_multi_items_result', { layout => 0 },
 476                   multi_items => $multi_items);
 477   }
 478 }
 479
 480 # add item rows for multiple items add once
 481 sub action_add_multi_items {
 482   my ($self) = @_;
 483
 484   my @form_attr = grep { $_->{qty_as_number} } @{ $::form->{add_multi_items} };
 485   return $self->js->render() unless scalar @form_attr;
 486
 487   my @items;
 488   foreach my $attr (@form_attr) {
 489     push @items, _new_item($self->order, $attr);
 490   }
 491   $self->order->add_items(@items);
 492
 493   $self->_recalc();
 494
 495   foreach my $item (@items) {
 496     my $item_id = join('_', 'new', Time::HiRes::gettimeofday(), int rand 1000000000000);
 497     my $row_as_html = $self->p->render('order/tabs/_row',
 498                                        ITEM              => $item,
 499                                        ID                => $item_id,
 500                                        ALL_PRICE_FACTORS => $self->all_price_factors
 501     );
 502
 503     $self->js->append('#row_table_id', $row_as_html);
 504   }
 505
 506   $self->js
 507     ->run('kivi.Order.close_multi_items_dialog')
 508     ->run('kivi.Order.init_row_handlers')
 509     ->run('kivi.Order.row_table_scroll_down')
 510     ->run('kivi.Order.renumber_positions')
 511     ->focus('#add_item_parts_id_name');
 512
 513   $self->_js_redisplay_amounts_and_taxes;
 514   $self->js->render();
 515 }
 516
 517 # recalculate all linetotals, amounts and taxes and redisplay them
 518 sub action_recalc_amounts_and_taxes {
 519   my ($self) = @_;
 520
 521   $self->_recalc();
 522
 523   $self->_js_redisplay_linetotals;
 524   $self->_js_redisplay_amounts_and_taxes;
 525   $self->js->render();
 526 }
 527
 528 # redisplay item rows if the are sorted by an attribute
 529 sub action_reorder_items {
 530   my ($self) = @_;
 531
 532   my %sort_keys = (
 533     partnumber  => sub { $_[0]->part->partnumber },
 534     description => sub { $_[0]->description },
 535     qty         => sub { $_[0]->qty },
 536     sellprice   => sub { $_[0]->sellprice },
 537     discount    => sub { $_[0]->discount },
 538   );
 539
 540   my $method = $sort_keys{$::form->{order_by}};
 541   my @to_sort = map { { old_pos => $_->position, order_by => $method->($_) } } @{ $self->order->items_sorted };
 542   if ($::form->{sort_dir}) {
 543     @to_sort = sort { $a->{order_by} cmp $b->{order_by} } @to_sort;
 544   } else {
 545     @to_sort = sort { $b->{order_by} cmp $a->{order_by} } @to_sort;
 546   }
 547   $self->js
 548     ->run('kivi.Order.redisplay_items', \@to_sort)
 549     ->render;
 550 }
 551
 552 # show the popup to choose a price/discount source
 553 sub action_price_popup {
 554   my ($self) = @_;
 555
 556   my $idx  = first_index { $_ eq $::form->{item_id} } @{ $::form->{orderitem_ids} };
 557   my $item = $self->order->items_sorted->[$idx];
 558
 559   $self->render_price_dialog($item);
 560 }
 561
 562 # get the longdescription for an item if the dialog to enter/change the
 563 # longdescription was opened and the longdescription is empty
 564 #
 565 # If this item is new, get the longdescription from Part.
 566 # Get it from OrderItem else.
 567 sub action_get_item_longdescription {
 568   my $longdescription;
 569
 570   if ($::form->{item_id}) {
 571     $longdescription = SL::DB::OrderItem->new(id => $::form->{item_id})->load->longdescription;
 572   } elsif ($::form->{parts_id}) {
 573     $longdescription = SL::DB::Part->new(id => $::form->{parts_id})->load->notes;
 574   }
 575   $_[0]->render(\ $longdescription, { type => 'text' });
 576 }
 577
 578 sub _js_redisplay_linetotals {
 579   my ($self) = @_;
 580
 581   my @data = map {$::form->format_amount(\%::myconfig, $_->{linetotal}, 2, 0)} @{ $self->order->items_sorted };
 582   $self->js
 583     ->run('kivi.Order.redisplay_linetotals', \@data);
 584 }
 585
 586 sub _js_redisplay_amounts_and_taxes {
 587   my ($self) = @_;
 588
 589   if (scalar @{ $self->{taxes} }) {
 590     $self->js->show('#taxincluded_row_id');
 591   } else {
 592     $self->js->hide('#taxincluded_row_id');
 593   }
 594
 595   if ($self->order->taxincluded) {
 596     $self->js->hide('#subtotal_row_id');
 597   } else {
 598     $self->js->show('#subtotal_row_id');
 599   }
 600
 601   $self->js
 602     ->html('#netamount_id', $::form->format_amount(\%::myconfig, $self->order->netamount, -2))
 603     ->html('#amount_id',    $::form->format_amount(\%::myconfig, $self->order->amount,    -2))
 604     ->remove('.tax_row')
 605     ->insertBefore($self->build_tax_rows, '#amount_row_id');
 606 }
 607
 608 #
 609 # helpers
 610 #
 611
 612 sub init_valid_types {
 613   [ _sales_order_type(), _purchase_order_type() ];
 614 }
 615
 616 sub init_type {
 617   my ($self) = @_;
 618
 619   if (none { $::form->{type} eq $_ } @{$self->valid_types}) {
 620     die "Not a valid type for order";
 621   }
 622
 623   $self->type($::form->{type});
 624 }
 625
 626 sub init_cv {
 627   my ($self) = @_;
 628
 629   my $cv = $self->type eq _sales_order_type()    ? 'customer'
 630          : $self->type eq _purchase_order_type() ? 'vendor'
 631          : die "Not a valid type for order";
 632
 633   return $cv;
 634 }
 635
 636 sub init_p {
 637   SL::Presenter->get;
 638 }
 639
 640 sub init_order {
 641   $_[0]->_make_order;
 642 }
 643
 644 # model used to filter/display the parts in the multi-items dialog
 645 sub init_multi_items_models {
 646   SL::Controller::Helper::GetModels->new(
 647     controller     => $_[0],
 648     model          => 'Part',
 649     with_objects   => [ qw(unit_obj) ],
 650     disable_plugin => 'paginated',
 651     source         => $::form->{multi_items},
 652     sorted         => {
 653       _default    => {
 654         by  => 'partnumber',
 655         dir => 1,
 656       },
 657       partnumber  => t8('Partnumber'),
 658       description => t8('Description')}
 659   );
 660 }
 661
 662 sub init_all_price_factors {
 663   SL::DB::Manager::PriceFactor->get_all;
 664 }
 665
 666 sub _check_auth {
 667   my ($self) = @_;
 668
 669   my $right_for = { map { $_ => $_.'_edit' } @{$self->valid_types} };
 670
 671   my $right   = $right_for->{ $self->type };
 672   $right    ||= 'DOES_NOT_EXIST';
 673
 674   $::auth->assert($right);
 675 }
 676
 677 # build the selection box for contacts
 678 #
 679 # Needed, if customer/vendor changed.
 680 sub build_contact_select {
 681   my ($self) = @_;
 682
 683   $self->p->select_tag('order.cp_id', [ $self->order->{$self->cv}->contacts ],
 684                        value_key  => 'cp_id',
 685                        title_key  => 'full_name_dep',
 686                        default    => $self->order->cp_id,
 687                        with_empty => 1,
 688                        style      => 'width: 300px',
 689   );
 690 }
 691
 692 # build the selection box for shiptos
 693 #
 694 # Needed, if customer/vendor changed.
 695 sub build_shipto_select {
 696   my ($self) = @_;
 697
 698   $self->p->select_tag('order.shipto_id', [ $self->order->{$self->cv}->shipto ],
 699                        value_key  => 'shipto_id',
 700                        title_key  => 'displayable_id',
 701                        default    => $self->order->shipto_id,
 702                        with_empty => 1,
 703                        style      => 'width: 300px',
 704   );
 705 }
 706
 707 # build the rows for displaying taxes
 708 #
 709 # Called if amounts where recalculated and redisplayed.
 710 sub build_tax_rows {
 711   my ($self) = @_;
 712
 713   my $rows_as_html;
 714   foreach my $tax (sort { $a->{tax}->rate cmp $b->{tax}->rate } @{ $self->{taxes} }) {
 715     $rows_as_html .= $self->p->render('order/tabs/_tax_row', TAX => $tax, TAXINCLUDED => $self->order->taxincluded);
 716   }
 717   return $rows_as_html;
 718 }
 719
 720
 721 sub render_price_dialog {
 722   my ($self, $record_item) = @_;
 723
 724   my $price_source = SL::PriceSource->new(record_item => $record_item, record => $self->order);
 725
 726   $self->js
 727     ->run(
 728       'kivi.io.price_chooser_dialog',
 729       t8('Available Prices'),
 730       $self->render('order/tabs/_price_sources_dialog', { output => 0 }, price_source => $price_source)
 731     )
 732     ->reinit_widgets;
 733
 734 #   if (@errors) {
 735 #     $self->js->text('#dialog_flash_error_content', join ' ', @errors);
 736 #     $self->js->show('#dialog_flash_error');
 737 #   }
 738
 739   $self->js->render;
 740 }
 741
 742 sub _load_order {
 743   my ($self) = @_;
 744
 745   return if !$::form->{id};
 746
 747   $self->order(SL::DB::Manager::Order->find_by(id => $::form->{id}));
 748 }
 749
 750 # load or create a new order object
 751 #
 752 # And assign changes from the for to this object.
 753 # If the order is loaded from db, check if items are deleted in the form,
 754 # remove them form the object and collect them for removing from db on saving.
 755 # Then create/update items from form (via _make_item) and add them.
 756 sub _make_order {
 757   my ($self) = @_;
 758
 759   # add_items adds items to an order with no items for saving, but they cannot
 760   # be retrieved via items until the order is saved. Adding empty items to new
 761   # order here solves this problem.
 762   my $order;
 763   $order   = SL::DB::Manager::Order->find_by(id => $::form->{id}) if $::form->{id};
 764   $order ||= SL::DB::Order->new(orderitems => []);
 765
 766   my $form_orderitems = delete $::form->{order}->{orderitems};
 767   $order->assign_attributes(%{$::form->{order}});
 768
 769   # remove deleted items
 770   $self->item_ids_to_delete([]);
 771   foreach my $idx (reverse 0..$#{$order->orderitems}) {
 772     my $item = $order->orderitems->[$idx];
 773     if (none { $item->id == $_->{id} } @{$form_orderitems}) {
 774       splice @{$order->orderitems}, $idx, 1;
 775       push @{$self->item_ids_to_delete}, $item->id;
 776     }
 777   }
 778
 779   my @items;
 780   my $pos = 1;
 781   foreach my $form_attr (@{$form_orderitems}) {
 782     my $item = _make_item($order, $form_attr);
 783     $item->position($pos);
 784     push @items, $item;
 785     $pos++;
 786   }
 787   $order->add_items(grep {!$_->id} @items);
 788
 789   return $order;
 790 }
 791
 792 # create or update items from form
 793 #
 794 # Make item objects from form values. For items already existing read from db.
 795 # Create a new item else. And assign attributes.
 796 sub _make_item {
 797   my ($record, $attr) = @_;
 798
 799   my $item;
 800   $item = first { $_->id == $attr->{id} } @{$record->items} if $attr->{id};
 801
 802   my $is_new = !$item;
 803
 804   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 805   # they cannot be retrieved via custom_variables until the order/orderitem is
 806   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 807   $item ||= SL::DB::OrderItem->new(custom_variables => []);
 808
 809   $item->assign_attributes(%$attr);
 810   $item->longdescription($item->part->notes) if $is_new && !defined $attr->{longdescription};
 811   # item fields that currently can't be set in in row but are needed:
 812   $item->lastcost($item->part->lastcost) if $is_new;
 813
 814   return $item;
 815 }
 816
 817 # create a new item
 818 #
 819 # This is used to add one (or more) items
 820 sub _new_item {
 821   my ($record, $attr) = @_;
 822
 823   my $item = SL::DB::OrderItem->new;
 824   $item->assign_attributes(%$attr);
 825
 826   my $part         = SL::DB::Part->new(id => $attr->{parts_id})->load;
 827   my $price_source = SL::PriceSource->new(record_item => $item, record => $record);
 828
 829   $item->unit($part->unit) if !$item->unit;
 830
 831   my $price_src;
 832   if ($item->sellprice) {
 833     $price_src = $price_source->price_from_source("");
 834     $price_src->price($item->sellprice);
 835   } else {
 836     $price_src = $price_source->best_price
 837            ? $price_source->best_price
 838            : $price_source->price_from_source("");
 839     $price_src->price(0) if !$price_source->best_price;
 840   }
 841
 842   my $discount_src;
 843   if ($item->discount) {
 844     $discount_src = $price_source->discount_from_source("");
 845     $discount_src->discount($item->discount);
 846   } else {
 847     $discount_src = $price_source->best_discount
 848                   ? $price_source->best_discount
 849                   : $price_source->discount_from_source("");
 850     $discount_src->discount(0) if !$price_source->best_discount;
 851   }
 852
 853   my %new_attr;
 854   $new_attr{part}                   = $part;
 855   $new_attr{description}            = $part->description     if ! $item->description;
 856   $new_attr{qty}                    = 1.0                    if ! $item->qty;
 857   $new_attr{price_factor_id}        = $part->price_factor_id if ! $item->price_factor_id;
 858   $new_attr{sellprice}              = $price_src->price;
 859   $new_attr{discount}               = $discount_src->discount;
 860   $new_attr{active_price_source}    = $price_src;
 861   $new_attr{active_discount_source} = $discount_src;
 862
 863   $new_attr{longdescription}        = $part->notes if ! defined $attr->{longdescription};
 864
 865   # add_custom_variables adds cvars to an orderitem with no cvars for saving, but
 866   # they cannot be retrieved via custom_variables until the order/orderitem is
 867   # saved. Adding empty custom_variables to new orderitem here solves this problem.
 868   $new_attr{custom_variables} = [];
 869
 870   $item->assign_attributes(%new_attr);
 871
 872   return $item;
 873 }
 874
 875 # recalculate prices and taxes
 876 #
 877 # Using the PriceTaxCalculator. Store linetotals in the item objects.
 878 sub _recalc {
 879   my ($self) = @_;
 880
 881   # bb: todo: currency later
 882   $self->order->currency_id($::instance_conf->get_currency_id());
 883
 884   my %pat = $self->order->calculate_prices_and_taxes();
 885   $self->{taxes} = [];
 886   foreach my $tax_chart_id (keys %{ $pat{taxes} }) {
 887     my $tax = SL::DB::Manager::Tax->find_by(chart_id => $tax_chart_id);
 888
 889     my @amount_keys = grep { $pat{amounts}->{$_}->{tax_id} == $tax->id } keys %{ $pat{amounts} };
 890     push(@{ $self->{taxes} }, { amount    => $pat{taxes}->{$tax_chart_id},
 891                                 netamount => $pat{amounts}->{$amount_keys[0]}->{amount},
 892                                 tax       => $tax });
 893   }
 894
 895   pairwise { $a->{linetotal} = $b->{linetotal} } @{$self->order->items}, @{$pat{items}};
 896 }
 897
 898 # get data for saving, printing, ..., that is not changed in the form
 899 #
 900 # Only cvars for now.
 901 sub _get_unalterable_data {
 902   my ($self) = @_;
 903
 904   foreach my $item (@{ $self->order->items }) {
 905     # autovivify all cvars that are not in the form (cvars_by_config can do it).
 906     # workaround to pre-parse number-cvars (parse_custom_variable_values does not parse number values).
 907     foreach my $var (@{ $item->cvars_by_config }) {
 908       $var->unparsed_value($::form->parse_amount(\%::myconfig, $var->{__unparsed_value})) if ($var->config->type eq 'number' && exists($var->{__unparsed_value}));
 909     }
 910     $item->parse_custom_variable_values;
 911   }
 912 }
 913
 914 # delete the order
 915 #
 916 # And remove related files in the spool directory
 917 sub _delete {
 918   my ($self) = @_;
 919
 920   my $errors = [];
 921   my $db     = $self->order->db;
 922
 923   $db->with_transaction(
 924     sub {
 925       my @spoolfiles = grep { $_ } map { $_->spoolfile } @{ SL::DB::Manager::Status->get_all(where => [ trans_id => $self->order->id ]) };
 926       $self->order->delete;
 927       my $spool = $::lx_office_conf{paths}->{spool};
 928       unlink map { "$spool/$_" } @spoolfiles if $spool;
 929
 930       1;
 931   }) || push(@{$errors}, $db->error);
 932
 933   return $errors;
 934 }
 935
 936 # save the order
 937 #
 938 # And delete items that are deleted in the form.
 939 sub _save {
 940   my ($self) = @_;
 941
 942   my $errors = [];
 943   my $db     = $self->order->db;
 944
 945   $db->with_transaction(sub {
 946     SL::DB::OrderItem->new(id => $_)->delete for @{$self->item_ids_to_delete};
 947     $self->order->save(cascade => 1);
 948   }) || push(@{$errors}, $db->error);
 949
 950   return $errors;
 951 }
 952
 953
 954 sub _pre_render {
 955   my ($self) = @_;
 956
 957   $self->{all_taxzones}        = SL::DB::Manager::TaxZone->get_all_sorted();
 958   $self->{all_departments}     = SL::DB::Manager::Department->get_all_sorted();
 959   $self->{all_employees}       = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->employee_id,
 960                                                                                        deleted => 0 ] ],
 961                                                                     sort_by => 'name');
 962   $self->{all_salesmen}        = SL::DB::Manager::Employee->get_all(where => [ or => [ id => $self->order->salesman_id,
 963                                                                                        deleted => 0 ] ],
 964                                                                     sort_by => 'name');
 965   $self->{all_projects}        = SL::DB::Manager::Project->get_all(where => [ or => [ id => $self->order->globalproject_id,
 966                                                                                       active => 1 ] ],
 967                                                                    sort_by => 'projectnumber');
 968   $self->{all_payment_terms}   = SL::DB::Manager::PaymentTerm->get_all_sorted();
 969   $self->{all_delivery_terms}  = SL::DB::Manager::DeliveryTerm->get_all_sorted();
 970
 971   $self->{current_employee_id} = SL::DB::Manager::Employee->current->id;
 972
 973   my $print_form = Form->new('');
 974   $print_form->{type}      = $self->type;
 975   $print_form->{printers}  = SL::DB::Manager::Printer->get_all_sorted;
 976   $print_form->{languages} = SL::DB::Manager::Language->get_all_sorted;
 977   $self->{print_options}   = SL::Helper::PrintOptions->get_print_options(
 978     form => $print_form,
 979     options => {dialog_name_prefix => 'print_options.',
 980                 show_headers       => 1,
 981                 no_queue           => 1,
 982                 no_postscript      => 1,
 983                 no_opendocument    => 1,
 984                 no_html            => 1},
 985   );
 986
 987   foreach my $item (@{$self->order->orderitems}) {
 988     my $price_source = SL::PriceSource->new(record_item => $item, record => $self->order);
 989     $item->active_price_source(   $price_source->price_from_source(   $item->active_price_source   ));
 990     $item->active_discount_source($price_source->discount_from_source($item->active_discount_source));
 991   }
 992
 993   if ($self->order->ordnumber && $::instance_conf->get_webdav) {
 994     my $webdav = SL::Webdav->new(
 995       type     => $self->type,
 996       number   => $self->order->ordnumber,
 997     );
 998     my $webdav_path = $webdav->webdav_path;
 999     my @all_objects = $webdav->get_all_objects;
1000     @{ $self->{template_args}->{WEBDAV} } = map { { name => $_->filename,
1001                                                     type => t8('File'),
1002                                                     link => File::Spec->catdir($webdav_path, $_->filename),
1003                                                 } } @all_objects;
1004   }
1005
1006   $::request->{layout}->use_javascript("${_}.js")  for qw(kivi.SalesPurchase kivi.Order ckeditor/ckeditor ckeditor/adapters/jquery);
1007 }
1008
1009 sub _create_pdf {
1010   my ($order, $pdf_ref, $params) = @_;
1011
1012   my @errors = ();
1013
1014   my $print_form = Form->new('');
1015   $print_form->{type}        = $order->type;
1016   $print_form->{formname}    = $params->{formname} || $order->type;
1017   $print_form->{format}      = $params->{format}   || 'pdf';
1018   $print_form->{media}       = $params->{media}    || 'file';
1019   $print_form->{groupitems}  = $params->{groupitems};
1020   $print_form->{media}       = 'file'                             if $print_form->{media} eq 'screen';
1021   $print_form->{language}    = $params->{language}->template_code if $print_form->{language};
1022   $print_form->{language_id} = $params->{language}->id            if $print_form->{language};
1023
1024   $order->flatten_to_form($print_form, format_amounts => 1);
1025
1026   # search for the template
1027   my ($template_file, @template_files) = SL::Helper::CreatePDF->find_template(
1028     name        => $print_form->{formname},
1029     email       => $print_form->{media} eq 'email',
1030     language    => $params->{language},
1031     printer_id  => $print_form->{printer_id},  # todo
1032   );
1033
1034   if (!defined $template_file) {
1035     push @errors, $::locale->text('Cannot find matching template for this print request. Please contact your template maintainer. I tried these: #1.', join ', ', map { "'$_'"} @template_files);
1036   }
1037
1038   return @errors if scalar @errors;
1039
1040   $print_form->throw_on_error(sub {
1041     eval {
1042       $print_form->prepare_for_printing;
1043
1044       $$pdf_ref = SL::Helper::CreatePDF->create_pdf(
1045         template  => $template_file,
1046         variables => $print_form,
1047         variable_content_types => {
1048           longdescription => 'html',
1049           partnotes       => 'html',
1050           notes           => 'html',
1051         },
1052       );
1053       1;
1054     } || push @errors, ref($EVAL_ERROR) eq 'SL::X::FormError' ? $EVAL_ERROR->getMessage : $EVAL_ERROR;
1055   });
1056
1057   return @errors;
1058 }
1059
1060 sub _sales_order_type {
1061   'sales_order';
1062 }
1063
1064 sub _purchase_order_type {
1065   'purchase_order';
1066 }
1067
1068 1;
1069
1070 __END__
1071
1072 =encoding utf-8
1073
1074 =head1 NAME
1075
1076 SL::Controller::Order - controller for orders
1077
1078 =head1 SYNOPSIS
1079
1080 This is a new form to enter orders, completely rewritten with the use
1081 of controller and java script techniques.
1082
1083 The aim is to provide the user a better expirience and a faster flow
1084 of work. Also the code should be more readable, more reliable and
1085 better to maintain.
1086
1087 =head2 Key Features
1088
1089 =over 4
1090
1091 =item *
1092
1093 One input row, so that input happens every time at the same place.
1094
1095 =item *
1096
1097 Use of pickers where possible.
1098
1099 =item *
1100
1101 Possibility to enter more than one item at once.
1102
1103 =item *
1104
1105 Save order only on "save" (and "save and delivery order"-workflow). No
1106 hidden save on "print" or "email".
1107
1108 =item *
1109
1110 Item list in a scrollable area, so that the workflow buttons stay at
1111 the bottom.
1112
1113 =item *
1114
1115 Reordering item rows with drag and drop is possible. Sorting item rows is
1116 possible (by partnumber, description, qty, sellprice and discount for now).
1117
1118 =item *
1119
1120 No C<update> is necessary. All entries and calculations are managed
1121 with ajax-calls and the page does only reload on C<save>.
1122
1123 =item *
1124
1125 User can see changes immediately, because of the use of java script
1126 and ajax.
1127
1128 =back
1129
1130 =head1 CODE
1131
1132 =head2 Layout
1133
1134 =over 4
1135
1136 =item * C<SL/Controller/Order.pm>
1137
1138 the controller
1139
1140 =item * C<template/webpages/order/form.html>
1141
1142 main form
1143
1144 =item * C<template/webpages/order/tabs/basic_data.html>
1145
1146 Main tab for basic_data.
1147
1148 This is the only tab here for now. "linked records" and "webdav" tabs are
1149 reused from generic code.
1150
1151 =over 4
1152
1153 =item * C<template/webpages/order/tabs/_item_input.html>
1154
1155 The input line for items
1156
1157 =item * C<template/webpages/order/tabs/_row.html>
1158
1159 One row for already entered items
1160
1161 =item * C<template/webpages/order/tabs/_tax_row.html>
1162
1163 Displaying tax information
1164
1165 =item * C<template/webpages/order/tabs/_multi_items_dialog.html>
1166
1167 Dialog for entering more than one item at once
1168
1169 =item * C<template/webpages/order/tabs/_multi_items_result.html>
1170
1171 Results for the filter in the multi items dialog
1172
1173 =item * C<template/webpages/order/tabs/_price_sources_dialog.html>
1174
1175 Dialog for selecting price and discount sources
1176
1177 =item * C<template/webpages/order/tabs/_email_dialog.html>
1178
1179 Email dialog
1180
1181 =back
1182
1183 =item * C<js/kivi.Order.js>
1184
1185 java script functions
1186
1187 =back
1188
1189 =head1 TODO
1190
1191 =over 4
1192
1193 =item * testing
1194
1195 =item * currency
1196
1197 =item * customer/vendor details ('D'-button)
1198
1199 =item * credit limit
1200
1201 =item * more workflows (save as new / invoice)
1202
1203 =item * price sources: little symbols showing better price / better discount
1204
1205 =item * custom shipto address
1206
1207 =item * periodic invoices
1208
1209 =item * more details on second row (marge, ...)
1210
1211 =item * language / part translations
1212
1213 =item * access rights
1214
1215 =item * preset salesman from customer
1216
1217 =item * display weights
1218
1219 =item * force project if enabled in client config
1220
1221 =item * history
1222
1223 =item * mtime check
1224
1225 =back
1226
1227 =head1 KNOWN BUGS AND CAVEATS
1228
1229 =over 4
1230
1231 =item *
1232
1233 Customer discount is not displayed as a valid discount in price source popup
1234 (this might be a bug in price sources)
1235
1236 =item *
1237
1238 No indication that double click expands second row, no exand all button
1239
1240 =item *
1241
1242 Implementation of second row with a tbody for every item is not supported by
1243 our css.
1244
1245 =item *
1246
1247 As a consequence row striping does not currently work
1248
1249 =item *
1250
1251 Inline creation of parts is not currently supported
1252
1253 =item *
1254
1255 Table header is not sticky in the scrolling area.
1256
1257 =item *
1258
1259 Sorting does not include C<position>, neither does reordering.
1260
1261 This behavior was implemented intentionally. But we can discuss, which behavior
1262 should be implemented.
1263
1264 =item *
1265
1266 C<show_multi_items_dialog> does not use the currently inserted string for
1267 filtering.
1268
1269 =item * Performance
1270
1271 Rendering a 50 items order takes twice as long as the old code.
1272
1273 90% of that is rendering the (hidden) second rows, and 50% of those again are
1274 checks for is_valid and C<INCLUDE> on the cvar input template.
1275
1276 Suggestion: fetch second rows when asked for.
1277
1278 =back
1279
1280 =head1 AUTHOR
1281
1282 Bernd Bleßmann E<lt>bernd@kivitendo-premium.deE<gt>
1283
1284 =cut