bin/mozilla/admin_groups.pl

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (c) 2002
  10 #
  11 #  Author: Moritz Bunkus
  12 #   Email: mbunkus@linet-services.de
  13 #     Web: www.linet-services.de
  14 #
  15 #
  16 # This program is free software; you can redistribute it and/or modify
  17 # it under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 2 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # This program is distributed in the hope that it will be useful,
  22 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 # GNU General Public License for more details.
  25 # You should have received a copy of the GNU General Public License
  26 # along with this program; if not, write to the Free Software
  27 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  28 #======================================================================
  29 #
  30 # group administration module
  31 # add/edit/delete user groups
  32 #
  33 #======================================================================
  34
  35 sub edit_groups {
  36   $lxdebug->enter_sub();
  37
  38   my @groups = sort { lc $a->{name} cmp lc $b->{name} } values %{ $auth->read_groups() };
  39
  40   $form->header();
  41   print $form->parse_html_template("admin/edit_groups", { 'GROUPS'     => \@groups,
  42                                                           'num_groups' => scalar @groups });
  43
  44   $lxdebug->leave_sub();
  45 }
  46
  47 sub add_group {
  48   $lxdebug->enter_sub();
  49
  50   delete $form->{group_id};
  51   $form->{message} = $locale->text("The group has been added.");
  52
  53   save_group();
  54
  55   $lxdebug->leave_sub();
  56 }
  57
  58 sub save_group {
  59   $lxdebug->enter_sub();
  60
  61   $form->isblank('name', $locale->text('The group name is missing.'));
  62
  63   my $groups = $auth->read_groups();
  64
  65   foreach my $group (values %{$groups}) {
  66     if (($form->{group_id} != $group->{id})
  67         && ($form->{name} eq $group->{name})) {
  68       $form->show_generic_error($locale->text("A group with that name does already exist."));
  69     }
  70   }
  71
  72   my $group;
  73
  74   if ($form->{group_id} && $groups->{$form->{group_id}}) {
  75     $group = $groups->{$form->{group_id}};
  76
  77   } else {
  78     $group = { };
  79   }
  80
  81   $group->{name}        = $form->{name};
  82   $group->{description} = $form->{description};
  83   $group->{rights}      = {};
  84
  85   map { $group->{rights}->{$_} = $form->{"${_}_granted"} ? 1 : 0 } SL::Auth::all_rights();
  86
  87   my $is_new = !$form->{group_id};
  88
  89   $auth->save_group($group);
  90
  91   $form->{message} ||= $locale->text('The group has been saved.');
  92
  93   if ($is_new) {
  94     edit_groups();
  95
  96   } else {
  97     edit_group();
  98   }
  99
 100   $lxdebug->leave_sub();
 101 }
 102
 103 sub edit_group {
 104   $lxdebug->enter_sub();
 105
 106   my $groups = $auth->read_groups();
 107
 108   if (!$form->{group_id} || !$groups->{$form->{group_id}}) {
 109     $form->show_generic_error($locale->text("No group has been selected, or the group does not exist anymore."));
 110   }
 111
 112   $group = $groups->{$form->{group_id}};
 113
 114   my %all_users   = $auth->read_all_users();
 115   my %users_by_id = map { $_->{id} => $_ } values %all_users;
 116
 117   my @members     = sort { lc $a->{login} cmp lc $b->{login} } @users_by_id{ @{ $group->{members} } };
 118
 119   my %grouped     = map { $_ => 1 } @{ $group->{members} };
 120   my @non_members = sort { lc $a->{login} cmp lc $b->{login} } grep { !$grouped{$_->{id}} } values %all_users;
 121
 122   my @rights = map {
 123     { "right"       => $_->[0],
 124       "description" => $_->[1],
 125       "is_section"  => '--' eq substr($_->[0], 0, 2),
 126       "granted"     => defined $group->{rights}->{$_->[0]} ? $group->{rights}->{$_->[0]} : 0,
 127     }
 128   } SL::Auth::all_rights_full();
 129
 130   $form->header();
 131   print $form->parse_html_template("admin/edit_group", { "USERS_IN_GROUP"     => \@members,
 132                                                          "USERS_NOT_IN_GROUP" => \@non_members,
 133                                                          "RIGHTS"             => \@rights,
 134                                                          "name"               => $group->{name},
 135                                                          "description"        => $group->{description} });
 136
 137   $lxdebug->leave_sub();
 138 }
 139
 140 sub delete_group {
 141   $lxdebug->enter_sub();
 142
 143   my $groups = $auth->read_groups();
 144
 145   if (!$form->{group_id} || !$groups->{$form->{group_id}}) {
 146     $form->show_generic_error($locale->text("No group has been selected, or the group does not exist anymore."));
 147   }
 148
 149   if ($form->{confirmed}) {
 150     $auth->delete_group($form->{"group_id"});
 151
 152     $form->{message} = $locale->text("The group has been deleted.");
 153     edit_groups();
 154
 155   } else {
 156
 157     $form->header();
 158     print $form->parse_html_template("admin/delete_group_confirm", $groups->{$form->{group_id}});
 159   }
 160
 161   $lxdebug->leave_sub();
 162 }
 163
 164 sub add_to_group {
 165   $lxdebug->enter_sub();
 166
 167   $form->isblank('user_id_not_in_group', $locale->text('No user has been selected.'));
 168
 169   my $groups = $auth->read_groups();
 170
 171   if (!$form->{group_id} || !$groups->{$form->{group_id}}) {
 172     $form->show_generic_error($locale->text('No group has been selected, or the group does not exist anymore.'));
 173   }
 174
 175   $group = $groups->{$form->{group_id}};
 176   push @{ $group->{members} }, $form->{user_id_not_in_group};
 177
 178   $auth->save_group($group);
 179
 180   $form->{message} = $locale->text('The user has been added to this group.');
 181   edit_group();
 182
 183   $lxdebug->leave_sub();
 184 }
 185
 186 sub remove_from_group {
 187   $lxdebug->enter_sub();
 188
 189   $form->isblank('user_id_in_group', $locale->text('No user has been selected.'));
 190
 191   my $groups = $auth->read_groups();
 192
 193   if (!$form->{group_id} || !$groups->{$form->{group_id}}) {
 194     $form->show_generic_error($locale->text('No group has been selected, or the group does not exist anymore.'));
 195   }
 196
 197   $group            = $groups->{$form->{group_id}};
 198   $group->{members} = [ grep { $_ ne $form->{user_id_in_group} } @{ $group->{members} } ];
 199
 200   $auth->save_group($group);
 201
 202   $form->{message} = $locale->text('The user has been removed from this group.');
 203   edit_group();
 204
 205   $lxdebug->leave_sub();
 206 }
 207
 208 sub edit_group_membership {
 209   $lxdebug->enter_sub();
 210
 211   my %users  = $auth->read_all_users();
 212   my $groups = $auth->read_groups();
 213   $groups    = [ sort { lc $a->{name} cmp lc $b->{name} } values %{ $groups } ];
 214
 215   my @headings = map { { 'title' => $_ } } map { $_->{name} } @{ $groups };
 216
 217   foreach my $group (@{ $groups }) {
 218     $group->{members_h} = { map { $_ => 1 } @{ $group->{members} } };
 219   }
 220
 221   my @rows;
 222
 223   foreach my $user (sort { lc $a->{login} cmp lc $b->{login} } values %users) {
 224     my $row = {
 225       'id'              => $user->{id},
 226       'login'           => $user->{login},
 227       'name'            => $user->{name},
 228       'repeat_headings' => (scalar(@rows) % 20) == 0,
 229       'GROUPS'          => [],
 230     };
 231
 232     foreach my $group (@{ $groups }) {
 233       push @{ $row->{GROUPS} }, {
 234         'id'        => $group->{id},
 235         'is_member' => $group->{members_h}->{$user->{id}},
 236       };
 237     }
 238
 239     push @rows, $row;
 240   }
 241
 242   $form->{title} = $locale->text('Edit group membership');
 243   $form->header();
 244   print $form->parse_html_template('admin/edit_group_membership', { 'HEADINGS' => \@headings, 'USERS' => \@rows });
 245
 246   $lxdebug->leave_sub();
 247 }
 248
 249 sub save_group_membership {
 250   $lxdebug->enter_sub();
 251
 252   my %users  = $auth->read_all_users();
 253   my $groups = $auth->read_groups();
 254
 255   foreach my $group (values %{ $groups }) {
 256     $group->{members} = [ ];
 257
 258     foreach my $user (values %users) {
 259       push @{ $group->{members} }, $user->{id} if ($form->{"u_$user->{id}_g_$group->{id}"});
 260     }
 261
 262     $auth->save_group($group);
 263   }
 264
 265   $form->{message} = $locale->text('The group memberships have been saved.');
 266
 267   edit_groups();
 268
 269   $lxdebug->leave_sub();
 270 }
 271
 272 1;