SL/Controller/CsvImport/Base.pm

   1 package SL::Controller::CsvImport::Base;
   2
   3 use strict;
   4
   5 use List::MoreUtils qw(pairwise);
   6
   7 use SL::Helper::Csv;
   8 use SL::DB::Language;
   9 use SL::DB::PaymentTerm;
  10
  11 use parent qw(Rose::Object);
  12
  13 use Rose::Object::MakeMethods::Generic
  14 (
  15  scalar                  => [ qw(controller file csv) ],
  16  'scalar --get_set_init' => [ qw(profile displayable_columns existing_objects class manager_class cvar_columns all_cvar_configs all_languages payment_terms_by) ],
  17 );
  18
  19 sub run {
  20   my ($self) = @_;
  21
  22   my $profile = $self->profile;
  23   $self->csv(SL::Helper::Csv->new(file                   => $self->file->file_name,
  24                                   encoding               => $self->controller->profile->get('charset'),
  25                                   class                  => $self->class,
  26                                   profile                => $profile,
  27                                   ignore_unknown_columns => 1,
  28                                   strict_profile         => 1,
  29                                   map { ( $_ => $self->controller->profile->get($_) ) } qw(sep_char escape_char quote_char),
  30                                  ));
  31   $self->csv->parse;
  32
  33   $self->controller->errors([ $self->csv->errors ]) if $self->csv->errors;
  34
  35   return unless $self->csv->header;
  36
  37   my $headers         = { headers => [ grep { $profile->{$_} } @{ $self->csv->header } ] };
  38   $headers->{methods} = [ map { $profile->{$_} } @{ $headers->{headers} } ];
  39   $headers->{used}    = { map { ($_ => 1) }      @{ $headers->{headers} } };
  40   $self->controller->headers($headers);
  41   $self->controller->raw_data_headers({ used => { }, headers => [ ] });
  42
  43   # my @data;
  44   # foreach my $object ($self->csv->get_objects)
  45   my @objects  = $self->csv->get_objects;
  46   my @raw_data = @{ $self->csv->get_data };
  47   $self->controller->data([ pairwise { { object => $a, raw_data => $b, errors => [] } } @objects, @raw_data ]);
  48
  49   $self->check_objects;
  50   $self->check_duplicates if $self->controller->profile->get('duplicates', 'no_check') ne 'no_check';
  51   $self->fix_field_lengths;
  52 }
  53
  54 sub add_columns {
  55   my ($self, @columns) = @_;
  56
  57   my $h = $self->controller->headers;
  58
  59   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  60     $h->{used}->{$column} = 1;
  61     push @{ $h->{methods} }, $column;
  62     push @{ $h->{headers} }, $column;
  63   }
  64 }
  65
  66 sub add_raw_data_columns {
  67   my ($self, @columns) = @_;
  68
  69   my $h = $self->controller->raw_data_headers;
  70
  71   foreach my $column (grep { !$h->{used}->{$_} } @columns) {
  72     $h->{used}->{$column} = 1;
  73     push @{ $h->{headers} }, $column;
  74   }
  75 }
  76
  77 sub add_cvar_raw_data_columns {
  78   my ($self) = @_;
  79
  80   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->cvar_columns };
  81 }
  82
  83 sub init_cvar_columns {
  84   my ($self) = @_;
  85
  86   return [ map { "cvar_" . $_->name } (@{ $self->all_cvar_configs }) ];
  87 }
  88
  89 sub init_all_languages {
  90   my ($self) = @_;
  91
  92   return SL::DB::Manager::Language->get_all;
  93 }
  94
  95 sub init_payment_terms_by {
  96   my ($self) = @_;
  97
  98   my $all_payment_terms = SL::DB::Manager::PaymentTerm->get_all;
  99   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_payment_terms } } ) } qw(id description) };
 100 }
 101
 102 sub handle_cvars {
 103   my ($self, $entry) = @_;
 104
 105   return unless $self->can('all_cvar_configs');
 106
 107   my %type_to_column = ( text      => 'text_value',
 108                          textfield => 'text_value',
 109                          select    => 'text_value',
 110                          date      => 'timestamp_value_as_date',
 111                          timestamp => 'timestamp_value_as_date',
 112                          number    => 'number_value_as_number',
 113                          bool      => 'bool_value' );
 114
 115   my @cvars;
 116   foreach my $config (@{ $self->all_cvar_configs }) {
 117     next unless exists $entry->{raw_data}->{ "cvar_" . $config->name };
 118     my $value  = $entry->{raw_data}->{ "cvar_" . $config->name };
 119     my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 120
 121     push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value);
 122   }
 123
 124   $entry->{object}->custom_variables(\@cvars);
 125 }
 126
 127 sub init_profile {
 128   my ($self) = @_;
 129
 130   eval "require " . $self->class;
 131
 132   my %unwanted = map { ( $_ => 1 ) } (qw(itime mtime), map { $_->name } @{ $self->class->meta->primary_key_columns });
 133   my %profile;
 134   for my $col ($self->class->meta->columns) {
 135     next if $unwanted{$col};
 136
 137     my $name = $col->isa('Rose::DB::Object::Metadata::Column::Numeric')   ? "$col\_as_number"
 138       :        $col->isa('Rose::DB::Object::Metadata::Column::Date')      ? "$col\_as_date"
 139       :        $col->isa('Rose::DB::Object::Metadata::Column::Timestamp') ? "$col\_as_date"
 140       :                                                                     $col->name;
 141
 142     $profile{$col} = $name;
 143   }
 144
 145   $self->profile(\%profile);
 146 }
 147
 148 sub add_displayable_columns {
 149   my ($self, @columns) = @_;
 150
 151   my @cols       = @{ $self->controller->displayable_columns || [] };
 152   my %ex_col_map = map { $_->{name} => $_ } @cols;
 153
 154   foreach my $column (@columns) {
 155     if ($ex_col_map{ $column->{name} }) {
 156       @{ $ex_col_map{ $column->{name} } }{ keys %{ $column } } = @{ $column }{ keys %{ $column } };
 157     } else {
 158       push @cols, $column;
 159     }
 160   }
 161
 162   $self->controller->displayable_columns([ sort { $a->{name} cmp $b->{name} } @cols ]);
 163 }
 164
 165 sub setup_displayable_columns {
 166   my ($self) = @_;
 167
 168   $self->add_displayable_columns(map { { name => $_ } } keys %{ $self->profile });
 169 }
 170
 171 sub add_cvar_columns_to_displayable_columns {
 172   my ($self) = @_;
 173
 174   return unless $self->can('all_cvar_configs');
 175
 176   $self->add_displayable_columns(map { { name        => 'cvar_' . $_->name,
 177                                          description => $::locale->text('#1 (custom variable)', $_->description) } }
 178                                      @{ $self->all_cvar_configs });
 179 }
 180
 181 sub init_existing_objects {
 182   my ($self) = @_;
 183
 184   eval "require " . $self->class;
 185   $self->existing_objects($self->manager_class->get_all);
 186 }
 187
 188 sub init_class {
 189   die "class not set";
 190 }
 191
 192 sub init_manager_class {
 193   my ($self) = @_;
 194
 195   $self->class =~ m/^SL::DB::(.+)/;
 196   $self->manager_class("SL::DB::Manager::" . $1);
 197 }
 198
 199 sub check_objects {
 200 }
 201
 202 sub check_duplicates {
 203 }
 204
 205 sub check_payment {
 206   my ($self, $entry) = @_;
 207
 208   my $object = $entry->{object};
 209
 210   # Check whether or not payment ID is valid.
 211   if ($object->payment_id && !$self->payment_terms_by->{id}->{ $object->payment_id }) {
 212     push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 213     return 0;
 214   }
 215
 216   # Map name to ID if given.
 217   if (!$object->payment_id && $entry->{raw_data}->{payment}) {
 218     my $terms = $self->payment_terms_by->{description}->{ $entry->{raw_data}->{payment} };
 219
 220     if (!$terms) {
 221       push @{ $entry->{errors} }, $::locale->text('Error: Invalid payment terms');
 222       return 0;
 223     }
 224
 225     $object->payment_id($terms->id);
 226   }
 227
 228   return 1;
 229 }
 230
 231 sub save_objects {
 232   my ($self, %params) = @_;
 233
 234   my $data = $params{data} || $self->controller->data;
 235
 236   foreach my $entry (@{ $data }) {
 237     next if @{ $entry->{errors} };
 238
 239     if (!$entry->{object}->save) {
 240       push @{ $entry->{errors} }, $::locale->text('Error when saving: #1', $entry->{object}->db->error);
 241     } else {
 242       $self->controller->num_imported($self->controller->num_imported + 1);
 243     }
 244   }
 245 }
 246
 247 sub field_lengths {
 248   return ();
 249 }
 250
 251 sub fix_field_lengths {
 252   my ($self) = @_;
 253
 254   my %field_lengths = $self->field_lengths;
 255   foreach my $entry (@{ $self->controller->data }) {
 256     next unless @{ $entry->{errors} };
 257     map { $entry->{object}->$_(substr($entry->{object}->$_, 0, $field_lengths{$_})) if $entry->{object}->$_ } keys %field_lengths;
 258   }
 259 }
 260
 261 1;