SL/TransNumber.pm

   1 package SL::TransNumber;
   2
   3 use strict;
   4
   5 use parent qw(Rose::Object);
   6
   7 use Carp;
   8 use List::MoreUtils qw(any none);
   9 use SL::DBUtils;
  10
  11 use Rose::Object::MakeMethods::Generic
  12 (
  13  scalar => [ qw(type id number save dbh dbh_provided business_id) ],
  14 );
  15
  16 my @SUPPORTED_TYPES = qw(invoice credit_note customer vendor sales_delivery_order purchase_delivery_order sales_order purchase_order sales_quotation request_quotation);
  17
  18 sub new {
  19   my $class = shift;
  20   my $self  = $class->SUPER::new(@_);
  21
  22   croak "Invalid type " . $self->type if none { $_ eq $self->type } @SUPPORTED_TYPES;
  23
  24   $self->dbh_provided($self->dbh);
  25   $self->dbh($::form->get_standard_dbh) if !$self->dbh;
  26   $self->save(1) unless defined $self->save;
  27   $self->business_id(undef) if $self->type ne 'customer';
  28
  29   return $self;
  30 }
  31
  32 sub _get_filters {
  33   my $self    = shift;
  34
  35   my $type    = $self->type;
  36   my %filters = ( where => '' );
  37
  38   if (any { $_ eq $type } qw(invoice credit_note)) {
  39     $filters{trans_number}  = "invnumber";
  40     $filters{numberfield}   = $type eq 'credit_note' ? "cnnumber" : "invnumber";
  41     $filters{table}         = "ar";
  42
  43   } elsif (any { $_ eq $type } qw(customer vendor)) {
  44     $filters{trans_number}  = "${type}number";
  45     $filters{numberfield}   = "${type}number";
  46     $filters{table}         = $type;
  47
  48   } elsif ($type =~ /_delivery_order$/) {
  49     $filters{trans_number}  = "donumber";
  50     $filters{numberfield}   = $type eq 'sales_delivery_order' ? "sdonumber" : "pdonumber";
  51     $filters{table}         = "delivery_orders";
  52     $filters{where}         = $type =~ /^sales/ ? '(customer_id IS NOT NULL)' : '(vendor_id IS NOT NULL)';
  53
  54   } elsif ($type =~ /_order$/) {
  55     $filters{trans_number}  = "ordnumber";
  56     $filters{numberfield}   = $type eq 'sales_order' ? "sonumber" : "ponumber";
  57     $filters{table}         = "oe";
  58     $filters{where}         = 'NOT COALESCE(quotation, FALSE)';
  59     $filters{where}        .= $type =~ /^sales/ ? ' AND (customer_id IS NOT NULL)' : ' AND (vendor_id IS NOT NULL)';
  60
  61   } else {
  62     $filters{trans_number}  = "quonumber";
  63     $filters{numberfield}   = $type eq 'sales_quotation' ? "sqnumber" : "rfqnumber";
  64     $filters{table}         = "oe";
  65     $filters{where}         = 'COALESCE(quotation, FALSE)';
  66     $filters{where}        .= $type =~ /^sales/ ? ' AND (customer_id IS NOT NULL)' : ' AND (vendor_id IS NOT NULL)';
  67   }
  68
  69   return %filters;
  70 }
  71
  72 sub is_unique {
  73   my $self = shift;
  74
  75   return undef if !$self->number;
  76
  77   my %filters = $self->_get_filters();
  78
  79   my @where;
  80   my @values = ($self->number);
  81
  82   push @where, $filters{where} if $filters{where};
  83
  84   if ($self->id) {
  85     push @where,  qq|id <> ?|;
  86     push @values, conv_i($self->id);
  87   }
  88
  89   my $where_str = @where ? join(' AND ', map { "($_)" } @where) : '';
  90   my $query     = <<SQL;
  91     SELECT $filters{trans_number}
  92     FROM $filters{table}
  93     WHERE ($filters{trans_number} = ?)
  94       $where_str
  95     LIMIT 1
  96 SQL
  97   my ($existing_number) = selectfirst_array_query($main::form, $self->dbh, $query, @values);
  98
  99   return $existing_number ? 0 : 1;
 100 }
 101
 102 sub create_unique {
 103   my $self    = shift;
 104
 105   my $form    = $main::form;
 106   my %filters = $self->_get_filters();
 107
 108   $self->dbh->begin_work if $self->dbh->{AutoCommit};
 109   do_query($form, $self->dbh, qq|LOCK TABLE defaults|);
 110   do_query($form, $self->dbh, qq|LOCK TABLE business|) if $self->business_id;
 111
 112   my $where = $filters{where} ? ' WHERE ' . $filters{where} : '';
 113   my $query = <<SQL;
 114     SELECT DISTINCT $filters{trans_number}, 1 AS in_use
 115     FROM $filters{table}
 116     $where
 117 SQL
 118
 119   my %numbers_in_use = selectall_as_map($form, $self->dbh, $query, $filters{trans_number}, 'in_use');
 120
 121   my $number;
 122   ($number)   = selectfirst_array_query($form, $self->dbh, qq|SELECT customernumberinit FROM business WHERE id = ?|, $self->business_id) if $self->business_id;
 123   ($number)   = selectfirst_array_query($form, $self->dbh, qq|SELECT $filters{numberfield} FROM defaults|)                               if !$number;
 124   $number   ||= '';
 125
 126   do {
 127     if ($number =~ m/\d+$/) {
 128       my $new_number = substr($number, $-[0]) * 1 + 1;
 129       my $len_diff   = length($number) - $-[0] - length($new_number);
 130       $number        = substr($number, 0, $-[0]) . ($len_diff > 0 ? '0' x $len_diff : '') . $new_number;
 131
 132     } else {
 133       $number = $number . '1';
 134     }
 135   } while ($numbers_in_use{$number});
 136
 137   if ($self->save) {
 138     if ($self->business_id) {
 139       do_query($form, $self->dbh, qq|UPDATE business SET customernumberinit = ? WHERE id = ?|, $number, $self->business_id);
 140     } else {
 141       do_query($form, $self->dbh, qq|UPDATE defaults SET $filters{numberfield} = ?|, $number);
 142     }
 143     $self->dbh->commit if !$self->dbh_provided;
 144   }
 145
 146   return $number;
 147 }
 148
 149 1;