SL/AR.pm

   1 #=====================================================================
   2 # LX-Office ERP
   3 # Copyright (C) 2004
   4 # Based on SQL-Ledger Version 2.1.9
   5 # Web http://www.lx-office.org
   6 #
   7 #=====================================================================
   8 # SQL-Ledger Accounting
   9 # Copyright (C) 2001
  10 #
  11 #  Author: Dieter Simader
  12 #   Email: dsimader@sql-ledger.org
  13 #     Web: http://www.sql-ledger.org
  14 #
  15 #  Contributors:
  16 #
  17 # This program is free software; you can redistribute it and/or modify
  18 # it under the terms of the GNU General Public License as published by
  19 # the Free Software Foundation; either version 2 of the License, or
  20 # (at your option) any later version.
  21 #
  22 # This program is distributed in the hope that it will be useful,
  23 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 # GNU General Public License for more details.
  26 # You should have received a copy of the GNU General Public License
  27 # along with this program; if not, write to the Free Software
  28 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  29 #======================================================================
  30 #
  31 # Accounts Receivable module backend routines
  32 #
  33 #======================================================================
  34
  35 package AR;
  36
  37 use Data::Dumper;
  38 use SL::DBUtils;
  39
  40 sub post_transaction {
  41   $main::lxdebug->enter_sub();
  42
  43   my ($self, $myconfig, $form) = @_;
  44
  45   my ($null, $taxrate, $amount, $tax, $diff);
  46   my $exchangerate = 0;
  47   my $i;
  48
  49   my @values;
  50
  51   my $dbh = $form->dbconnect_noauto($myconfig);
  52
  53   if ($form->{currency} eq $form->{defaultcurrency}) {
  54     $form->{exchangerate} = 1;
  55   } else {
  56     $exchangerate =
  57       $form->check_exchangerate($myconfig, $form->{currency},
  58                                 $form->{transdate}, 'buy');
  59   }
  60   for $i (1 .. $form->{rowcount}) {
  61     $form->{AR_amounts}{"amount_$i"} =
  62       (split(/--/, $form->{"AR_amount_$i"}))[0];
  63   }
  64   $form->{AR_amounts}{receivables} = $form->{ARselected};
  65   $form->{AR}{receivables}         = $form->{ARselected};
  66
  67   $form->{exchangerate} =
  68     ($exchangerate)
  69     ? $exchangerate
  70     : $form->parse_amount($myconfig, $form->{exchangerate});
  71
  72   for $i (1 .. $form->{rowcount}) {
  73
  74     $form->{"amount_$i"} =
  75       $form->round_amount($form->parse_amount($myconfig, $form->{"amount_$i"})
  76                             * $form->{exchangerate},
  77                           2);
  78
  79     $form->{netamount} += $form->{"amount_$i"};
  80
  81     # parse tax_$i for later
  82     $form->{"tax_$i"} = $form->parse_amount($myconfig, $form->{"tax_$i"});
  83   }
  84
  85   # this is for ar
  86
  87   $form->{amount} = $form->{netamount};
  88
  89   $form->{tax}       = 0;
  90   $form->{netamount} = 0;
  91   $form->{total_tax} = 0;
  92
  93   # taxincluded doesn't make sense if there is no amount
  94
  95   $form->{taxincluded} = 0 if ($form->{amount} == 0);
  96   for $i (1 .. $form->{rowcount}) {
  97     ($form->{"tax_id_$i"}, $NULL) = split /--/, $form->{"taxchart_$i"};
  98
  99     $query =
 100       qq|SELECT c.accno, t.taxkey, t.rate | .
 101       qq|FROM tax t LEFT JOIN chart c on (c.id = t.chart_id) | .
 102       qq|WHERE t.id = ? | .
 103       qq|ORDER BY c.accno|;
 104
 105     ($form->{AR_amounts}{"tax_$i"}, $form->{"taxkey_$i"}, $form->{"taxrate_$i"}) =
 106       selectrow_query($form, $dbh, $query, $form->{"tax_id_$i"});
 107     $form->{AR_amounts}{"tax_$i"}{taxkey}    = $form->{"taxkey_$i"};
 108     $form->{AR_amounts}{"amount_$i"}{taxkey} = $form->{"taxkey_$i"};
 109
 110     if ($form->{taxincluded} *= 1) {
 111       if (!$form->{"korrektur_$i"}) {
 112       $tax =
 113         $form->{"amount_$i"} -
 114         ($form->{"amount_$i"} / ($form->{"taxrate_$i"} + 1));
 115       } else {
 116         $tax = $form->{"tax_$i"};
 117       }
 118       $amount = $form->{"amount_$i"} - $tax;
 119       $form->{"amount_$i"} = $form->round_amount($amount, 2);
 120       $diff += $amount - $form->{"amount_$i"};
 121       $form->{"tax_$i"} = $form->round_amount($tax, 2);
 122       $form->{netamount} += $form->{"amount_$i"};
 123     } else {
 124       if (!$form->{"korrektur_$i"}) {
 125         $form->{"tax_$i"} = $form->{"amount_$i"} * $form->{"taxrate_$i"};
 126       }
 127       $form->{"tax_$i"} =
 128         $form->round_amount($form->{"tax_$i"} * $form->{exchangerate}, 2);
 129       $form->{netamount} += $form->{"amount_$i"};
 130     }
 131
 132     $form->{total_tax} += $form->{"tax_$i"};
 133   }
 134
 135   # adjust paidaccounts if there is no date in the last row
 136   $form->{paidaccounts}-- unless ($form->{"datepaid_$form->{paidaccounts}"});
 137   $form->{paid} = 0;
 138
 139   # add payments
 140   for $i (1 .. $form->{paidaccounts}) {
 141     $form->{"paid_$i"} =
 142       $form->round_amount($form->parse_amount($myconfig, $form->{"paid_$i"}),
 143                           2);
 144
 145     $form->{paid} += $form->{"paid_$i"};
 146     $form->{datepaid} = $form->{"datepaid_$i"};
 147
 148   }
 149
 150   $form->{amount} = $form->{netamount} + $form->{total_tax};
 151   $form->{paid}   =
 152     $form->round_amount($form->{paid} * $form->{exchangerate}, 2);
 153
 154   my ($query, $sth, $null);
 155
 156   ($null, $form->{employee_id}) = split /--/, $form->{employee};
 157   unless ($form->{employee_id}) {
 158     $form->get_employee($dbh);
 159   }
 160
 161   # if we have an id delete old records
 162   if ($form->{id}) {
 163     # delete detail records
 164     $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 165     do_query($form, $dbh, $query, $form->{id});
 166
 167   } else {
 168     $query = qq|SELECT nextval('glid')|;
 169     ($form->{id}) = selectrow_query($form, $dbh, $query);
 170
 171     $query = qq|INSERT INTO ar (id, invnumber, employee_id) VALUES (?, 'dummy', ?)|;
 172     do_query($form, $dbh, $query, $form->{id}, $form->{employee_id});
 173
 174     if (!$form->{invnumber}) {
 175       $form->{invnumber} = $form->update_defaults($myconfig, "invnumber", $dbh);
 176     }
 177   }
 178
 179   # update department
 180   ($null, $form->{department_id}) = split(/--/, $form->{department});
 181   $form->{department_id} *= 1;
 182
 183   # record last payment date in ar table
 184   $form->{datepaid} = $form->{transdate} unless $form->{datepaid};
 185   my $datepaid = ($form->{paid} != 0) ? $form->{datepaid} : undef;
 186
 187   $query =
 188     qq|UPDATE ar set | .
 189     qq|  invnumber = ?, ordnumber = ?, transdate = ?, customer_id = ?, | .
 190     qq|  taxincluded = ?, amount = ?, duedate = ?, paid = ?, datepaid = ?, | .
 191     qq|  netamount = ?, curr = ?, notes = ?, department_id = ?, | .
 192     qq|  employee_id = ? | .
 193     qq|WHERE id = ?|;
 194   my @values = ($form->{invnumber}, $form->{ordnumber},
 195                 conv_date($form->{transdate}), conv_i($form->{customer_id}),
 196                 $form->{taxincluded} ? 't' : 'f', $form->{amount},
 197                 conv_date($form->{duedate}), $form->{paid},
 198                 conv_date($datepaid), $form->{netamount},
 199                 $form->{currency}, $form->{notes},
 200                 conv_i($form->{department_id}),
 201                 conv_i($form->{employee_id}),
 202                 conv_i($form->{id}));
 203   do_query($form, $dbh, $query, @values);
 204
 205   # amount for AR account
 206   $form->{receivables} = $form->round_amount($form->{amount}, 2) * -1;
 207
 208   # update exchangerate
 209   if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 210     $form->update_exchangerate($dbh, $form->{currency}, $form->{transdate},
 211                                $form->{exchangerate}, 0);
 212   }
 213
 214   # add individual transactions for AR, amount and taxes
 215   for $i (1 .. $form->{rowcount}) {
 216     if ($form->{"amount_$i"} != 0) {
 217       my $project_id = conv_i($form->{"project_id_$i"});
 218       $taxkey = $form->{AR_amounts}{"amount_$i"}{taxkey};
 219
 220       # insert detail records in acc_trans
 221       $query =
 222         qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, | .
 223         qq|  project_id, taxkey) | .
 224         qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?)|;
 225       @values = (conv_i($form->{id}), conv_i($form->{AR_amounts}{"amount_$i"}),
 226                  conv_i($form->{"amount_$i"}), conv_date($form->{transdate}),
 227                  $project_id, conv_i($taxkey));
 228       do_query($form, $dbh, $query, @values);
 229
 230       if ($form->{"tax_$i"} != 0) {
 231         # insert detail records in acc_trans
 232         $query =
 233           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, | .
 234           qq|  project_id, taxkey) | .
 235           qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), | .
 236           qq|  ?, ?, ?, ?)|;
 237         @values = (conv_i($form->{id}), conv_i($form->{AR_amounts}{"tax_$i"}),
 238                    conv_i($form->{"tax_$i"}), conv_date($form->{transdate}),
 239                    $project_id, conv_i($taxkey));
 240         do_query($form, $dbh, $query, @values);
 241       }
 242     }
 243   }
 244
 245   # add recievables
 246   $query =
 247     qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate) | .
 248     qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?)|;
 249   @values = (conv_i($form->{id}), conv_i($form->{AR_amounts}{receivables}),
 250              conv_i($form->{receivables}), conv_date($form->{transdate}));
 251   do_query($form, $dbh, $query, @values);
 252
 253   # add paid transactions
 254   for my $i (1 .. $form->{paidaccounts}) {
 255     if ($form->{"paid_$i"} != 0) {
 256       my $project_id = conv_i($form->{"paid_project_id_$i"});
 257
 258       $form->{"AR_paid_$i"} =~ s/\"//g;
 259       ($form->{AR}{"paid_$i"}) = split(/--/, $form->{"AR_paid_$i"});
 260       $form->{"datepaid_$i"} = $form->{transdate}
 261         unless ($form->{"datepaid_$i"});
 262
 263       $exchangerate = 0;
 264       if ($form->{currency} eq $form->{defaultcurrency}) {
 265         $form->{"exchangerate_$i"} = 1;
 266       } else {
 267         $exchangerate =
 268           $form->check_exchangerate($myconfig, $form->{currency},
 269                                     $form->{"datepaid_$i"}, 'buy');
 270
 271         $form->{"exchangerate_$i"} =
 272           ($exchangerate)
 273           ? $exchangerate
 274           : $form->parse_amount($myconfig, $form->{"exchangerate_$i"});
 275       }
 276
 277       # if there is no amount and invtotal is zero there is no exchangerate
 278       if ($form->{amount} == 0 && $form->{netamount} == 0) {
 279         $form->{exchangerate} = $form->{"exchangerate_$i"};
 280       }
 281
 282       # receivables amount
 283       $amount =
 284         $form->round_amount($form->{"paid_$i"} * $form->{exchangerate}, 2);
 285
 286       if ($form->{receivables} != 0) {
 287         # add receivable
 288         $query =
 289           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id) | .
 290           qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?)|;
 291         @values = (conv_i($form->{id}), conv_i($form->{AR}{receivables}),
 292                    $amount, conv_date($form->{"datepaid_$i"}), $project_id);
 293         do_query($form, $dbh, $query, @values);
 294       }
 295       $form->{receivables} = $amount;
 296
 297       if ($form->{"paid_$i"} != 0) {
 298         my $project_id = conv_i($form->{"paid_project_id_$i"});
 299         # add payment
 300         $amount = $form->{"paid_$i"} * -1;
 301         $query  =
 302           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, source, memo, project_id) | .
 303           qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?)|;
 304         @values = (conv_i($form->{id}), conv_i($form->{AR}{"paid_$i"}), $amount,
 305                    conv_date($form->{"datepaid_$i"}), $form->{"source_$i"},
 306                    $form->{"memo_$i"}, $project_id);
 307         do_query($form, $dbh, $query, @values);
 308
 309         # exchangerate difference for payment
 310         $amount =
 311           $form->round_amount(
 312                     $form->{"paid_$i"} * ($form->{"exchangerate_$i"} - 1) * -1,
 313                     2);
 314
 315         if ($amount != 0) {
 316           $query =
 317             qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id) | .
 318             qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, 't', 'f', ?)|;
 319           @values = (conv_i($form->{id}), conv_i($form->{AR}{"paid_$i"}),
 320                      $amount, conv_date($form->{"datepaid_$i"}), $project_id);
 321           do_query($form, $dbh, $query, @values);
 322         }
 323
 324         # exchangerate gain/loss
 325         $amount =
 326           $form->round_amount(
 327                    $form->{"paid_$i"} *
 328                      ($form->{exchangerate} - $form->{"exchangerate_$i"}) * -1,
 329                    2);
 330
 331         if ($amount != 0) {
 332           $accno =
 333             ($amount > 0) ? $form->{fxgain_accno} : $form->{fxloss_accno};
 334           $query =
 335             qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, fx_transaction, cleared, project_id) | .
 336             qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, 't', 'f', ?)|;
 337           @values = (conv_i($form->{id}), $accno, $amount,
 338                      conv_date($form->{"datepaid_$i"}), $project_id);
 339           do_query($form, $dbh, $query, @values);
 340         }
 341       }
 342
 343       # update exchangerate record
 344       if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 345         $form->update_exchangerate($dbh, $form->{currency},
 346                                    $form->{"datepaid_$i"},
 347                                    $form->{"exchangerate_$i"}, 0);
 348       }
 349     }
 350   }
 351
 352   my $rc = $dbh->commit;
 353   $dbh->disconnect;
 354
 355   $main::lxdebug->leave_sub();
 356
 357   return $rc;
 358 }
 359
 360 sub post_payment {
 361   $main::lxdebug->enter_sub();
 362
 363   my ($self, $myconfig, $form, $locale) = @_;
 364
 365   # connect to database, turn off autocommit
 366   my $dbh = $form->dbconnect_noauto($myconfig);
 367
 368   $form->{datepaid} = $form->{transdate};
 369
 370   # total payments, don't move we need it here
 371   for my $i (1 .. $form->{paidaccounts}) {
 372     if ($form->{type} eq "credit_note") {
 373       $form->{"paid_$i"} = $form->parse_amount($myconfig, $form->{"paid_$i"}) * -1;
 374     } else {
 375       $form->{"paid_$i"} = $form->parse_amount($myconfig, $form->{"paid_$i"});
 376     }
 377     $form->{paid} += $form->{"paid_$i"};
 378     $form->{datepaid} = $form->{"datepaid_$i"} if ($form->{"datepaid_$i"});
 379   }
 380
 381   $form->{exchangerate} =
 382       $form->get_exchangerate($dbh, $form->{currency}, $form->{transdate},
 383                               "buy");
 384
 385   my $accno_ar = $form->{ARselected};
 386
 387   # record payments and offsetting AR
 388   for my $i (1 .. $form->{paidaccounts}) {
 389
 390     if ($form->{"paid_$i"} != 0) {
 391       my $project_id = conv_i($form->{"paid_project_id_$i"});
 392
 393       my ($accno) = split /--/, $form->{"AR_paid_$i"};
 394       $form->{"datepaid_$i"} = $form->{transdate}
 395         unless ($form->{"datepaid_$i"});
 396       $form->{datepaid} = $form->{"datepaid_$i"};
 397
 398       $exchangerate = 0;
 399       if (($form->{currency} eq $form->{defaultcurrency}) || ($form->{defaultcurrency} eq "")) {
 400         $form->{"exchangerate_$i"} = 1;
 401       } else {
 402         $exchangerate =
 403           $form->check_exchangerate($myconfig, $form->{currency},
 404                                     $form->{"datepaid_$i"}, 'buy');
 405
 406         $form->{"exchangerate_$i"} =
 407           ($exchangerate)
 408           ? $exchangerate
 409           : $form->parse_amount($myconfig, $form->{"exchangerate_$i"});
 410       }
 411
 412       # record AR
 413       $amount =
 414         $form->round_amount($form->{"paid_$i"} * $form->{"exchangerate"},
 415                             2);
 416
 417
 418       $query =
 419         qq|DELETE FROM acc_trans | .
 420         qq|WHERE trans_id = ? AND amount = ? AND transdate = ? AND | .
 421         qq|  chart_id = (SELECT c.id FROM chart c WHERE c.accno = ?)|;
 422       @values = (conv_i($form->{id}), $amount,
 423                  conv_date($form->{"datepaid_$i"}), $accno_ar);
 424       do_query($form, $dbh, $query, @values);
 425
 426       $query =
 427         qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, project_id) | .
 428         qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?)|;
 429       @values = (conv_i($form->{id}), $accno_ar, conv_i($amount),
 430                  conv_date($form->{"datepaid_$i"}), $project_id);
 431       do_query($form, $dbh, $query, @values);
 432
 433       # record payment
 434       $form->{"paid_$i"} *= -1;
 435
 436       $query =
 437         qq|DELETE FROM acc_trans | .
 438         qq|WHERE trans_id = ? AND | .
 439         qq|  chart_id = (SELECT c.id FROM chart c WHERE c.accno = ?) AND | .
 440         qq|  amount = ? AND transdate = ? AND source = ? AND memo = ?|;
 441       @values = (conv_i($form->{id}), $accno, conv_i($form->{"paid_$i"}),
 442                  conv_date($form->{"datepaid_$i"}),
 443                  $form->{"source_$i"}, $form->{"memo_$i"});
 444       do_query($form, $dbh, $query, @values);
 445
 446       $query =
 447         qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, source, memo, project_id) | .
 448         qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, ?, ?, ?)|;
 449       @values = (conv_i($form->{id}), $accno, conv_i($form->{"paid_$i"}),
 450                  conv_date($form->{"datepaid_$i"}),
 451                  $form->{"source_$i"}, $form->{"memo_$i"}, $project_id);
 452       do_query($form, $dbh, $query, @values);
 453
 454       # gain/loss
 455       $amount =
 456         $form->{"paid_$i"} * $form->{exchangerate} - $form->{"paid_$i"} *
 457         $form->{"exchangerate_$i"};
 458       if ($amount > 0) {
 459         $form->{fx}{ $form->{fxgain_accno} }{ $form->{"datepaid_$i"} } +=
 460           $amount;
 461       } else {
 462         $form->{fx}{ $form->{fxloss_accno} }{ $form->{"datepaid_$i"} } +=
 463           $amount;
 464       }
 465
 466       $diff = 0;
 467
 468       # update exchange rate
 469       if (($form->{currency} ne $form->{defaultcurrency}) && !$exchangerate) {
 470         $form->update_exchangerate($dbh, $form->{currency},
 471                                    $form->{"datepaid_$i"},
 472                                    $form->{"exchangerate_$i"}, 0);
 473       }
 474     }
 475   }
 476
 477   # record exchange rate differences and gains/losses
 478   foreach my $accno (keys %{ $form->{fx} }) {
 479     foreach my $transdate (keys %{ $form->{fx}{$accno} }) {
 480       if (
 481           ($form->{fx}{$accno}{$transdate} =
 482            $form->round_amount($form->{fx}{$accno}{$transdate}, 2)
 483           ) != 0
 484         ) {
 485         $query =
 486           qq|DELETE FROM acc_trans | .
 487           qq|WHERE trans_id = ? AND | .
 488           qq|  chart_id = (SELECT c.id FROM chart c WHERE c.accno = ?) AND | .
 489           qq|  amount = ? AND transdate = ? AND cleared = 'f' AND fx_transaction = 't'|;
 490         @values = (conv_i($form->{id}), $accno,
 491                    conv_i($form->{fx}{$accno}{$transdate}),
 492                    conv_date($transdate));
 493         do_query($form, $dbh, $query, @values);
 494
 495         $query =
 496           qq|INSERT INTO acc_trans (trans_id, chart_id, amount, transdate, cleared, fx_transaction, project_id) | .
 497           qq|VALUES (?, (SELECT c.id FROM chart c WHERE c.accno = ?), ?, ?, 'f', 't', ?)|;
 498         @values = (conv_i($form->{id}), $accno,
 499                    conv_i($form->{fx}{$accno}{$transdate}),
 500                    conv_date($transdate), $project_id);
 501         do_query($form, $dbh, $query, @values);
 502       }
 503     }
 504   }
 505   my $datepaid = ($form->{paid}) ? $form->{datepaid} : "NULL";
 506
 507   # save AR record
 508   my $query =
 509     qq|UPDATE ar set paid = ?, datepaid = ? WHERE id = ?|;
 510   @values = (conv_i($form->{paid}), conv_date($datepaid), conv_i($form->{id}));
 511   do_query($form, $dbh, $query, @values);
 512
 513   my $rc = $dbh->commit;
 514   $dbh->disconnect;
 515
 516   $main::lxdebug->leave_sub();
 517
 518   return $rc;
 519 }
 520
 521 sub delete_transaction {
 522   $main::lxdebug->enter_sub();
 523
 524   my ($self, $myconfig, $form) = @_;
 525
 526   # connect to database, turn AutoCommit off
 527   my $dbh = $form->dbconnect_noauto($myconfig);
 528
 529   my $query = qq|DELETE FROM ar WHERE id = ?|;
 530   do_query($form, $dbh, $query, $form->{id});
 531
 532   $query = qq|DELETE FROM acc_trans WHERE trans_id = ?|;
 533   do_query($form, $dbh, $query, $form->{id});
 534
 535   # commit
 536   my $rc = $dbh->commit;
 537   $dbh->disconnect;
 538
 539   $main::lxdebug->leave_sub();
 540
 541   return $rc;
 542 }
 543
 544 sub ar_transactions {
 545   $main::lxdebug->enter_sub();
 546
 547   my ($self, $myconfig, $form) = @_;
 548
 549   # connect to database
 550   my $dbh = $form->dbconnect($myconfig);
 551
 552   my @values;
 553
 554   my $query =
 555     qq|SELECT a.id, a.invnumber, a.ordnumber, a.transdate, | .
 556     qq|  a.duedate, a.netamount, a.amount, a.paid, | .
 557     qq|  a.invoice, a.datepaid, a.terms, a.notes, a.shipvia, | .
 558     qq|  a.shippingpoint, a.storno, a.globalproject_id, | .
 559     qq|  pr.projectnumber AS globalprojectnumber, | .
 560     qq|  c.name, | .
 561     qq|  e.name AS employee | .
 562     qq|FROM ar a | .
 563     qq|JOIN customer c ON (a.customer_id = c.id) | .
 564     qq|LEFT JOIN employee e ON (a.employee_id = e.id) | .
 565     qq|LEFT JOIN project pr ON (a.globalproject_id = pr.id)|;
 566
 567   my $where = "1 = 1";
 568   if ($form->{customer_id}) {
 569     $where .= " AND a.customer_id = ?";
 570     push(@values, $form->{customer_id});
 571   } elsif ($form->{customer}) {
 572     $where .= " AND c.name ILIKE ?";
 573     push(@values, $form->like($form->{customer}));
 574   }
 575   if ($form->{department}) {
 576     my ($null, $department_id) = split /--/, $form->{department};
 577     $where .= " AND a.department_id = ?";
 578     push(@values, $department_id);
 579   }
 580   foreach my $column (qw(invnumber ordnumber notes)) {
 581     if ($form->{$column}) {
 582       $where .= " AND a.$column ILIKE ?";
 583       push(@values, $form->like($form->{$column}));
 584     }
 585   }
 586   if ($form->{"project_id"}) {
 587     $where .=
 588       qq|AND ((a.globalproject_id = ?) OR EXISTS | .
 589       qq|  (SELECT * FROM invoice i | .
 590       qq|   WHERE i.project_id = ? AND i.trans_id = a.id))|;
 591     push(@values, $form->{"project_id"}, $form->{"project_id"});
 592   }
 593
 594   if ($form->{transdatefrom}) {
 595     $where .= " AND a.transdate >= ?";
 596     push(@values, $form->{transdatefrom});
 597   }
 598   if ($form->{transdateto}) {
 599     $where .= " AND a.transdate <= ?";
 600     push(@values, $form->{transdateto});
 601   }
 602   if ($form->{open} || $form->{closed}) {
 603     unless ($form->{open} && $form->{closed}) {
 604       $where .= " AND a.amount <> a.paid" if ($form->{open});
 605       $where .= " AND a.amount = a.paid"  if ($form->{closed});
 606     }
 607   }
 608
 609   my @a = (transdate, invnumber, name);
 610   push @a, "employee" if $form->{l_employee};
 611   my $sortorder = join(', ', @a);
 612
 613   if (grep({ $_ eq $form->{sort} }
 614            qw(id transdate duedate invnumber ordnumber name
 615               datepaid employee shippingpoint shipvia))) {
 616     $sortorder = $form->{sort};
 617   }
 618
 619   $query .= " WHERE $where ORDER by $sortorder";
 620
 621   my $sth = $dbh->prepare($query);
 622   $sth->execute(@values) ||
 623     $form->dberror($query . " (" . join(", ", @values) . ")");
 624
 625   $form->{AR} = [];
 626   while (my $ar = $sth->fetchrow_hashref(NAME_lc)) {
 627     push @{ $form->{AR} }, $ar;
 628   }
 629
 630   $sth->finish;
 631   $dbh->disconnect;
 632
 633   $main::lxdebug->leave_sub();
 634 }
 635
 636 sub get_transdate {
 637   $main::lxdebug->enter_sub();
 638
 639   my ($self, $myconfig, $form) = @_;
 640
 641   # connect to database
 642   my $dbh = $form->dbconnect($myconfig);
 643
 644   my $query =
 645     "SELECT COALESCE(" .
 646     "  (SELECT transdate FROM ar WHERE id = " .
 647     "    (SELECT MAX(id) FROM ar) LIMIT 1), " .
 648     "  current_date)";
 649   ($form->{transdate}) = $dbh->selectrow_array($query);
 650
 651   $dbh->disconnect;
 652
 653   $main::lxdebug->leave_sub();
 654 }
 655
 656 1;
 657