SL/DB/Part.pm

   1 package SL::DB::Part;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::MoreUtils qw(any);
   7
   8 use SL::DBUtils;
   9 use SL::DB::MetaSetup::Part;
  10 use SL::DB::Manager::Part;
  11 use SL::DB::Chart;
  12 use SL::DB::Helper::TransNumberGenerator;
  13 use SL::DB::Helper::CustomVariables (
  14   module      => 'IC',
  15   cvars_alias => 1,
  16 );
  17
  18 __PACKAGE__->meta->add_relationships(
  19   assemblies                     => {
  20     type         => 'one to many',
  21     class        => 'SL::DB::Assembly',
  22     column_map   => { id => 'id' },
  23   },
  24   prices         => {
  25     type         => 'one to many',
  26     class        => 'SL::DB::Price',
  27     column_map   => { id => 'parts_id' },
  28   },
  29   makemodels     => {
  30     type         => 'one to many',
  31     class        => 'SL::DB::MakeModel',
  32     column_map   => { id => 'parts_id' },
  33   },
  34   translations   => {
  35     type         => 'one to many',
  36     class        => 'SL::DB::Translation',
  37     column_map   => { id => 'parts_id' },
  38   },
  39 );
  40
  41 __PACKAGE__->meta->initialize;
  42
  43 __PACKAGE__->before_save('_before_save_set_partnumber');
  44
  45 sub _before_save_set_partnumber {
  46   my ($self) = @_;
  47
  48   $self->create_trans_number if !$self->partnumber;
  49   return 1;
  50 }
  51
  52 sub is_type {
  53   my $self = shift;
  54   my $type  = lc(shift || '');
  55   die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  56
  57   return $self->type eq $type ? 1 : 0;
  58 }
  59
  60 sub is_part     { $_[0]->is_type('part') }
  61 sub is_assembly { $_[0]->is_type('assembly') }
  62 sub is_service  { $_[0]->is_type('service') }
  63
  64 sub type {
  65   my ($self, $type) = @_;
  66   if (@_ > 1) {
  67     die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  68     $self->assembly(          $type eq 'assembly' ? 1 : 0);
  69     $self->inventory_accno_id($type ne 'service'  ? 1 : undef);
  70   }
  71
  72   return 'assembly' if $self->assembly;
  73   return 'part'     if $self->inventory_accno_id;
  74   return 'service';
  75 }
  76
  77 sub new_part {
  78   my ($class, %params) = @_;
  79   $class->new(%params, type => 'part');
  80 }
  81
  82 sub new_assembly {
  83   my ($class, %params) = @_;
  84   $class->new(%params, type => 'assembly');
  85 }
  86
  87 sub new_service {
  88   my ($class, %params) = @_;
  89   $class->new(%params, type => 'service');
  90 }
  91
  92 sub orphaned {
  93   my ($self) = @_;
  94   die 'not an accessor' if @_ > 1;
  95
  96   my @relations = qw(
  97     SL::DB::InvoiceItem
  98     SL::DB::OrderItem
  99     SL::DB::Inventory
 100     SL::DB::RMAItem
 101   );
 102
 103   for my $class (@relations) {
 104     eval "require $class";
 105     return 0 if $class->_get_manager_class->get_all_count(query => [ parts_id => $self->id ]);
 106   }
 107   return 1;
 108 }
 109
 110 sub get_sellprice_info {
 111   my $self   = shift;
 112   my %params = @_;
 113
 114   confess "Missing part id" unless $self->id;
 115
 116   my $object = $self->load;
 117
 118   return { sellprice       => $object->sellprice,
 119            price_factor_id => $object->price_factor_id };
 120 }
 121
 122 sub get_ordered_qty {
 123   my $self   = shift;
 124   my %result = SL::DB::Manager::Part->get_ordered_qty($self->id);
 125
 126   return $result{ $self->id };
 127 }
 128
 129 sub available_units {
 130   shift->unit_obj->convertible_units;
 131 }
 132
 133 # autogenerated accessor is slightly off...
 134 sub buchungsgruppe {
 135   shift->buchungsgruppen(@_);
 136 }
 137
 138 sub get_taxkey {
 139   my ($self, %params) = @_;
 140
 141   my $date     = $params{date} || DateTime->today_local;
 142   my $is_sales = !!$params{is_sales};
 143   my $taxzone  = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 144
 145   $self->{__partpriv_taxkey_information} ||= { };
 146   my $tk_info = $self->{__partpriv_taxkey_information};
 147
 148   $tk_info->{$taxzone}              ||= { };
 149   $tk_info->{$taxzone}->{$is_sales} ||= { };
 150
 151   if (!exists $tk_info->{$taxzone}->{$is_sales}->{$date}) {
 152     $tk_info->{$taxzone}->{$is_sales}->{$date} =
 153       $self->get_chart(type => $is_sales ? 'income' : 'expense', taxzone => $taxzone)
 154       ->load
 155       ->get_active_taxkey($date);
 156   }
 157
 158   return $tk_info->{$taxzone}->{$is_sales}->{$date};
 159 }
 160
 161 sub get_chart {
 162   my ($self, %params) = @_;
 163
 164   my $type    = (any { $_ eq $params{type} } qw(income expense inventory)) ? $params{type} : croak("Invalid 'type' parameter '$params{type}'");
 165   my $taxzone = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 166
 167   $self->{__partpriv_get_chart_id} ||= { };
 168   my $charts = $self->{__partpriv_get_chart_id};
 169
 170   $charts->{$taxzone} ||= { };
 171
 172   if (!exists $charts->{$taxzone}->{$type}) {
 173     my $bugru    = $self->buchungsgruppe;
 174     my $chart_id = ($type eq 'inventory') ? ($self->inventory_accno_id ? $bugru->inventory_accno_id : undef)
 175                  :                          $bugru->call_sub("${type}_accno_id_${taxzone}");
 176
 177     $charts->{$taxzone}->{$type} = $chart_id ? SL::DB::Chart->new(id => $chart_id)->load : undef;
 178   }
 179
 180   return $charts->{$taxzone}->{$type};
 181 }
 182
 183 1;
 184
 185 __END__
 186
 187 =pod
 188
 189 =encoding utf-8
 190
 191 =head1 NAME
 192
 193 SL::DB::Part: Model for the 'parts' table
 194
 195 =head1 SYNOPSIS
 196
 197 This is a standard Rose::DB::Object based model and can be used as one.
 198
 199 =head1 TYPES
 200
 201 Although the base class is called C<Part> we usually talk about C<Articles> if
 202 we mean instances of this class. This is because articles come in three
 203 flavours called:
 204
 205 =over 4
 206
 207 =item Part     - a single part
 208
 209 =item Service  - a part without onhand, and without inventory accounting
 210
 211 =item Assembly - a collection of both parts and services
 212
 213 =back
 214
 215 These types are sadly represented by data inside the class and cannot be
 216 migrated into a flag. To work around this, each C<Part> object knows what type
 217 it currently is. Since the type ist data driven, there ist no explicit setting
 218 method for it, but you can construct them explicitly with C<new_part>,
 219 C<new_service>, and C<new_assembly>. A Buchungsgruppe should be supplied in this
 220 case, but it will use the default Buchungsgruppe if you don't.
 221
 222 Matching these there are assorted helper methods dealing with types,
 223 e.g.  L</new_part>, L</new_service>, L</new_assembly>, L</type>,
 224 L</is_type> and others.
 225
 226 =head1 FUNCTIONS
 227
 228 =over 4
 229
 230 =item C<new_part %PARAMS>
 231
 232 =item C<new_service %PARAMS>
 233
 234 =item C<new_assembly %PARAMS>
 235
 236 Will set the appropriate data fields so that the resulting instance will be of
 237 tthe requested type. Since part of the distinction are accounting targets,
 238 providing a C<Buchungsgruppe> is recommended. If none is given the constructor
 239 will load a default one and set the accounting targets from it.
 240
 241 =item C<type>
 242
 243 Returns the type as a string. Can be one of C<part>, C<service>, C<assembly>.
 244
 245 =item C<is_type $TYPE>
 246
 247 Tests if the current object is a part, a service or an
 248 assembly. C<$type> must be one of the words 'part', 'service' or
 249 'assembly' (their plurals are ok, too).
 250
 251 Returns 1 if the requested type matches, 0 if it doesn't and
 252 C<confess>es if an unknown C<$type> parameter is encountered.
 253
 254 =item C<is_part>
 255
 256 =item C<is_service>
 257
 258 =item C<is_assembly>
 259
 260 Shorthand for C<is_type('part')> etc.
 261
 262 =item C<get_sellprice_info %params>
 263
 264 Retrieves the C<sellprice> and C<price_factor_id> for a part under
 265 different conditions and returns a hash reference with those two keys.
 266
 267 If C<%params> contains a key C<project_id> then a project price list
 268 will be consulted if one exists for that project. In this case the
 269 parameter C<country_id> is evaluated as well: if a price list entry
 270 has been created for this country then it will be used. Otherwise an
 271 entry without a country set will be used.
 272
 273 If none of the above conditions is met then the information from
 274 C<$self> is used.
 275
 276 =item C<get_ordered_qty %params>
 277
 278 Retrieves the quantity that has been ordered from a vendor but that
 279 has not been delivered yet. Only open purchase orders are considered.
 280
 281 =item C<get_taxkey %params>
 282
 283 Retrieves and returns a taxkey object valid for the given date
 284 C<$params{date}> and tax zone C<$params{taxzone}>
 285 (C<$params{taxzone_id}> is also recognized). The date defaults to the
 286 current date if undefined.
 287
 288 This function looks up the income (for trueish values of
 289 C<$params{is_sales}>) or expense (for falsish values of
 290 C<$params{is_sales}>) account for the current part. It uses the part's
 291 associated buchungsgruppe and uses the fields belonging to the tax
 292 zone given by C<$params{taxzone}> (range 0..3).
 293
 294 The information retrieved by the function is cached.
 295
 296 =item C<get_chart %params>
 297
 298 Retrieves and returns a chart object valid for the given type
 299 C<$params{type}> and tax zone C<$params{taxzone}>
 300 (C<$params{taxzone_id}> is also recognized). The type must be one of
 301 the three key words C<income>, C<expense> and C<inventory>.
 302
 303 This function uses the part's associated buchungsgruppe and uses the
 304 fields belonging to the tax zone given by C<$params{taxzone}> (range
 305 0..3).
 306
 307 The information retrieved by the function is cached.
 308
 309 =item C<orphaned>
 310
 311 Checks if this articke is used in orders, invoices, delivery orders or
 312 assemblies.
 313
 314 =item C<buchungsgruppe BUCHUNGSGRUPPE>
 315
 316 Used to set the accounting informations from a L<SL:DB::Buchungsgruppe> object.
 317 Please note, that this is a write only accessor, the original Buchungsgruppe can
 318 not be retrieved from an article once set.
 319
 320 =back
 321
 322 =head1 AUTHORS
 323
 324 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>,
 325 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 326
 327 =cut