SL/Controller/CsvImport/Part.pm

   1 package SL::Controller::CsvImport::Part;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6
   7 use SL::DBUtils;
   8 use SL::DB::Buchungsgruppe;
   9 use SL::DB::CustomVariable;
  10 use SL::DB::CustomVariableConfig;
  11 use SL::DB::PartsGroup;
  12 use SL::DB::PaymentTerm;
  13 use SL::DB::PriceFactor;
  14 use SL::DB::Pricegroup;
  15 use SL::DB::Price;
  16 use SL::DB::Translation;
  17 use SL::DB::Unit;
  18
  19 use List::MoreUtils qw(none);
  20
  21 use parent qw(SL::Controller::CsvImport::Base);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25  scalar                  => [ qw(table makemodel_columns) ],
  26  'scalar --get_set_init' => [ qw(bg_by settings parts_by price_factors_by units_by partsgroups_by
  27                                  warehouses_by bins_by
  28                                  translation_columns all_pricegroups) ],
  29 );
  30
  31 sub set_profile_defaults {
  32   my ($self) = @_;
  33
  34   my $bugru = SL::DB::Manager::Buchungsgruppe->find_by(description => { like => 'Standard%19%' });
  35
  36   $self->controller->profile->_set_defaults(
  37                        sellprice_places          => 2,
  38                        sellprice_adjustment      => 0,
  39                        sellprice_adjustment_type => 'percent',
  40                        article_number_policy     => 'update_prices',
  41                        shoparticle_if_missing    => '0',
  42                        part_type                 => 'part',
  43                        default_buchungsgruppe    => ($bugru ? $bugru->id : undef),
  44                        apply_buchungsgruppe      => 'all',
  45                       );
  46 };
  47
  48
  49 sub init_class {
  50   my ($self) = @_;
  51   $self->class('SL::DB::Part');
  52 }
  53
  54 sub init_bg_by {
  55   my ($self) = @_;
  56
  57   my $all_bg = SL::DB::Manager::Buchungsgruppe->get_all;
  58   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_bg } } ) } qw(id description) };
  59 }
  60
  61 sub init_price_factors_by {
  62   my ($self) = @_;
  63
  64   my $all_price_factors = SL::DB::Manager::PriceFactor->get_all;
  65   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_price_factors } } ) } qw(id description) };
  66 }
  67
  68 sub init_partsgroups_by {
  69   my ($self) = @_;
  70
  71   my $all_partsgroups = SL::DB::Manager::PartsGroup->get_all;
  72   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_partsgroups } } ) } qw(id partsgroup) };
  73 }
  74
  75 sub init_units_by {
  76   my ($self) = @_;
  77
  78   my $all_units = SL::DB::Manager::Unit->get_all;
  79   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_units } } ) } qw(name) };
  80 }
  81
  82 sub init_bins_by {
  83   my ($self) = @_;
  84
  85   my $all_bins = SL::DB::Manager::Bin->get_all;
  86   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_bins } } ) } qw(id description) };
  87 }
  88
  89 sub init_warehouses_by {
  90   my ($self) = @_;
  91
  92   my $all_warehouses = SL::DB::Manager::Warehouse->get_all;
  93   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $all_warehouses } } ) } qw(id description) };
  94 }
  95
  96
  97 sub init_parts_by {
  98   my ($self) = @_;
  99
 100 #  my $parts_by = { id         => { map { ( $_->id => $_ ) } grep { !$_->part_type = 'assembly' } @{ $self->existing_objects } },
 101 #                   partnumber => { part    => { },
 102 #                                   service => { } } };
 103 #
 104 #  foreach my $part (@{ $self->existing_objects }) {
 105 #    next if $part->part_type eq 'assembly';
 106 #    $parts_by->{partnumber}->{ $part->type }->{ $part->partnumber } = $part;
 107 #  }
 108
 109   my $parts_by = {};
 110   my $sth = prepare_execute_query($::form, SL::DB::Object->new->db->dbh, 'SELECT partnumber FROM parts');
 111   while (my ($partnumber) = $sth->fetchrow_array()) {
 112     $parts_by->{partnumber}{$partnumber} = 1;
 113   }
 114
 115   return $parts_by;
 116 }
 117
 118 sub init_all_pricegroups {
 119   my ($self) = @_;
 120
 121   return SL::DB::Manager::Pricegroup->get_all_sorted;
 122 }
 123
 124 sub init_settings {
 125   my ($self) = @_;
 126
 127   return { map { ( $_ => $self->controller->profile->get($_) ) } qw(apply_buchungsgruppe default_buchungsgruppe article_number_policy
 128                                                                     sellprice_places sellprice_adjustment sellprice_adjustment_type
 129                                                                     shoparticle_if_missing part_type default_unit) };
 130 }
 131
 132 sub init_all_cvar_configs {
 133   my ($self) = @_;
 134
 135   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'IC' ]);
 136 }
 137
 138 sub init_translation_columns {
 139   my ($self) = @_;
 140
 141   return [ map { ("description_" . $_->article_code, "notes_" . $_->article_code) } (@{ $self->all_languages }) ];
 142 }
 143
 144 sub check_objects {
 145   my ($self) = @_;
 146
 147   return unless @{ $self->controller->data };
 148
 149   $self->controller->track_progress(phase => 'building data', progress => 0);
 150
 151   $self->makemodel_columns({});
 152
 153   my $i = 0;
 154   my $num_data = scalar @{ $self->controller->data };
 155   foreach my $entry (@{ $self->controller->data }) {
 156     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
 157
 158     $self->check_buchungsgruppe($entry);
 159     $self->check_part_type($entry);
 160     $self->check_unit($entry);
 161     $self->check_price_factor($entry);
 162     $self->check_payment($entry);
 163     $self->check_partsgroup($entry);
 164     $self->check_warehouse_and_bin($entry);
 165     $self->handle_pricegroups($entry);
 166     $self->check_existing($entry) unless @{ $entry->{errors} };
 167     $self->handle_prices($entry) if $self->settings->{sellprice_adjustment};
 168     $self->handle_shoparticle($entry);
 169     $self->handle_translations($entry);
 170     $self->handle_cvars($entry);
 171     $self->handle_makemodel($entry);
 172     $self->set_various_fields($entry);
 173   } continue {
 174     $i++;
 175   }
 176
 177   $self->add_columns(qw(part_type)) if $self->settings->{part_type} eq 'mixed';
 178   $self->add_columns(qw(buchungsgruppen_id unit));
 179   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw (price_factor payment partsgroup warehouse bin));
 180   $self->add_columns(qw(shop)) if $self->settings->{shoparticle_if_missing};
 181   $self->add_cvar_raw_data_columns;
 182   map { $self->add_raw_data_columns("pricegroup_${_}") if exists $self->controller->data->[0]->{raw_data}->{"pricegroup_$_"} } (1..scalar(@{ $self->all_pricegroups }));
 183   map { $self->add_raw_data_columns($_) if exists $self->controller->data->[0]->{raw_data}->{$_} } @{ $self->translation_columns };
 184   map { $self->add_raw_data_columns("make_${_}", "model_${_}", "lastcost_${_}") } sort { $a <=> $b } keys %{ $self->makemodel_columns };
 185 }
 186
 187 sub get_duplicate_check_fields {
 188   return {
 189     partnumber => {
 190       label     => $::locale->text('Part Number'),
 191       default   => 0
 192     },
 193
 194     description => {
 195       label     => $::locale->text('Description'),
 196       default   => 1,
 197       maker     => sub {
 198         my $desc = shift->description;
 199         $desc =~ s/[\s,\.\-]//g;
 200         return $desc;
 201       }
 202     },
 203   };
 204 }
 205
 206 sub check_buchungsgruppe {
 207   my ($self, $entry) = @_;
 208
 209   my $object = $entry->{object};
 210
 211   # Check Buchungsgruppe
 212
 213   # Store and verify default ID.
 214   my $default_id = $self->settings->{default_buchungsgruppe};
 215   $default_id    = undef unless $self->bg_by->{id}->{ $default_id };
 216
 217   # 1. Use default ID if enforced.
 218   if ($default_id && ($self->settings->{apply_buchungsgruppe} eq 'all')) {
 219     $object->buchungsgruppen_id($default_id);
 220     push @{ $entry->{information} }, $::locale->text('Use default booking group because setting is \'all\'');
 221   }
 222
 223   # 2. Use supplied ID if valid
 224   $object->buchungsgruppen_id(undef) if $object->buchungsgruppen_id && !$self->bg_by->{id}->{ $object->buchungsgruppen_id };
 225
 226   # 3. Look up name if supplied.
 227   if (!$object->buchungsgruppen_id && $entry->{raw_data}->{buchungsgruppe}) {
 228     my $bg = $self->bg_by->{description}->{ $entry->{raw_data}->{buchungsgruppe} };
 229     $object->buchungsgruppen_id($bg->id) if $bg;
 230   }
 231
 232   # 4. Use default ID if not valid.
 233   if (!$object->buchungsgruppen_id && $default_id && ($self->settings->{apply_buchungsgruppe} eq 'missing')) {
 234     $object->buchungsgruppen_id($default_id) ;
 235     $entry->{buch_information} = $::locale->text('Use default booking group because wanted is missing');
 236   }
 237   return 1 if $object->buchungsgruppen_id;
 238   $entry->{buch_error} =  $::locale->text('Error: booking group missing or invalid');
 239   return 0;
 240 }
 241
 242 sub _part_is_used {
 243   my ($self, $part) = @_;
 244
 245   my $query =
 246       qq|SELECT COUNT(parts_id) FROM invoice where parts_id = ?
 247          UNION
 248          SELECT COUNT(parts_id) FROM assembly where parts_id = ?
 249          UNION
 250          SELECT COUNT(parts_id) FROM orderitems where parts_id = ?
 251         |;
 252   foreach my $ref (selectall_hashref_query($::form, $part->db->dbh, $query, $part->id, $part->id, $part->id)) {
 253     return 1 if $ref->{count} != 0;
 254   }
 255   return 0;
 256 }
 257
 258 sub check_existing {
 259   my ($self, $entry) = @_;
 260
 261   my $object = $entry->{object};
 262   my $raw = $entry->{raw_data};
 263
 264   if ($object->partnumber && $self->parts_by->{partnumber}{$object->partnumber}) {
 265     $entry->{part} = SL::DB::Manager::Part->get_first( query => [ partnumber => $object->partnumber ], limit => 1,
 266       with_objects => [ 'translations', 'custom_variables' ], multi_many_ok => 1
 267     );
 268     if ( !$entry->{part} ) {
 269         $entry->{part} = SL::DB::Manager::Part->get_first( query => [ partnumber => $object->partnumber ], limit => 1,
 270           with_objects => [ 'translations' ], multi_many_ok => 1
 271         );
 272     }
 273   }
 274
 275   if ($entry->{part}) {
 276     if ($entry->{part}->part_type ne $object->part_type ) {
 277       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database with different type'));
 278       return;
 279     }
 280     if ( $entry->{part}->unit ne $object->unit ) {
 281       if ( $entry->{part}->onhand != 0 || $self->_part_is_used($entry->{part})) {
 282         push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry with different unit'));
 283         return;
 284       }
 285     }
 286   }
 287
 288   if ($self->settings->{article_number_policy} eq 'update_prices_sn' || $self->settings->{article_number_policy} eq 'update_parts_sn') {
 289     if (!$entry->{part}) {
 290       push(@{$entry->{errors}}, $::locale->text('Skipping non-existent article'));
 291       return;
 292     }
 293   }
 294
 295   ## checking also doubles in csv !!
 296   foreach my $csventry (@{ $self->controller->data }) {
 297     if ( $entry != $csventry && $object->partnumber eq $csventry->{object}->partnumber ) {
 298       if ( $csventry->{doublechecked} ) {
 299         push(@{$entry->{errors}}, $::locale->text('Skipping due to same partnumber in csv file'));
 300         return;
 301       }
 302     }
 303   }
 304   $entry->{doublechecked} = 1;
 305
 306   if ($entry->{part}) {
 307     if ($self->settings->{article_number_policy} eq 'update_prices' || $self->settings->{article_number_policy} eq 'update_prices_sn') {
 308       map { $entry->{part}->$_( $object->$_ ) if defined $object->$_ } qw(sellprice listprice lastcost);
 309
 310       # merge prices
 311       my %prices_by_pricegroup_id = map { $_->pricegroup->id => $_ } $entry->{part}->prices, $object->prices;
 312       $entry->{part}->prices(grep { $_ } map { $prices_by_pricegroup_id{$_->id} } @{ $self->all_pricegroups });
 313
 314       push @{ $entry->{information} }, $::locale->text('Updating prices of existing entry in database');
 315       $entry->{object_to_save} = $entry->{part};
 316     } elsif ( $self->settings->{article_number_policy} eq 'update_parts' || $self->settings->{article_number_policy} eq 'update_parts_sn') {
 317
 318       # Update parts table
 319       # copy only the data which is not explicit copied by  "methods"
 320
 321       map { $entry->{part}->$_( $object->$_ ) if defined $object->$_ }  qw(description notes weight ean rop image
 322                                                                            drawing ve gv
 323                                                                            unit
 324                                                                            has_sernumber not_discountable obsolete
 325                                                                            payment_id
 326                                                                            sellprice listprice lastcost);
 327
 328       if (defined $raw->{"sellprice"} || defined $raw->{"listprice"} || defined $raw->{"lastcost"}) {
 329         # merge prices
 330         my %prices_by_pricegroup_id = map { $_->pricegroup->id => $_ } $entry->{part}->prices, $object->prices;
 331         $entry->{part}->prices(grep { $_ } map { $prices_by_pricegroup_id{$_->id} } @{ $self->all_pricegroups });
 332       }
 333
 334       # Update translation
 335       my @translations;
 336       push @translations, $entry->{part}->translations;
 337       foreach my $language (@{ $self->all_languages }) {
 338         my $desc;
 339         $desc = $raw->{"description_". $language->article_code}  if defined $raw->{"description_". $language->article_code};
 340         my $notes;
 341         $notes = $raw->{"notes_". $language->article_code}  if defined $raw->{"notes_". $language->article_code};
 342         next unless $desc || $notes;
 343
 344         push @translations, SL::DB::Translation->new(language_id     => $language->id,
 345                                                      translation     => $desc,
 346                                                      longdescription => $notes);
 347       }
 348       $entry->{part}->translations(\@translations) if @translations;
 349
 350       # Update cvars
 351       my %type_to_column = ( text      => 'text_value',
 352                              textfield => 'text_value',
 353                              select    => 'text_value',
 354                              date      => 'timestamp_value_as_date',
 355                              timestamp => 'timestamp_value_as_date',
 356                              number    => 'number_value_as_number',
 357                              bool      => 'bool_value' );
 358       my @cvars;
 359       push @cvars, $entry->{part}->custom_variables;
 360       foreach my $config (@{ $self->all_cvar_configs }) {
 361         next unless exists $raw->{ "cvar_" . $config->name };
 362         my $value  = $raw->{ "cvar_" . $config->name };
 363         my $column = $type_to_column{ $config->type } || die "Program logic error: unknown custom variable storage type";
 364         push @cvars, SL::DB::CustomVariable->new(config_id => $config->id, $column => $value, sub_module => '');
 365       }
 366       $entry->{part}->custom_variables(\@cvars) if @cvars;
 367
 368       # save Part Update
 369       push @{ $entry->{information} }, $::locale->text('Updating data of existing entry in database');
 370
 371       $entry->{object_to_save} = $entry->{part};
 372       # copy all other data via "methods"
 373       my $methods        = $self->controller->headers->{methods};
 374       $entry->{object_to_save}->$_( $entry->{object}->$_ ) for @{ $methods }, keys %{ $self->clone_methods };
 375
 376     } elsif ( $self->settings->{article_number_policy} eq 'skip' ) {
 377       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database')) if ( $entry->{part} );
 378     } else {
 379       #$object->partnumber('####');
 380     }
 381   } else {
 382     # set error or info from buch if part not exists
 383     push @{ $entry->{information} }, $entry->{buch_information} if $entry->{buch_information};
 384     push @{ $entry->{errors} }, $entry->{buch_error} if $entry->{buch_error};
 385   }
 386 }
 387
 388 sub handle_prices {
 389   my ($self, $entry) = @_;
 390
 391   foreach my $column (qw(sellprice)) {
 392     my $object     = $entry->{object_to_save} || $entry->{object};
 393     my $adjustment = $self->settings->{sellprice_adjustment};
 394     my $value      = $object->$column;
 395
 396     $value = $self->settings->{sellprice_adjustment_type} eq 'percent' ? $value * (100 + $adjustment) / 100 : $value + $adjustment;
 397     $object->$column($::form->round_amount($value, $self->settings->{sellprice_places}));
 398   }
 399 }
 400
 401 sub handle_shoparticle {
 402   my ($self, $entry) = @_;
 403
 404   $entry->{object}->shop(1) if $self->settings->{shoparticle_if_missing} && !$self->controller->headers->{used}->{shop};
 405 }
 406
 407 sub check_part_type {
 408   my ($self, $entry) = @_;
 409
 410   # TODO: assemblies or assortments can't be imported
 411
 412   # my $bg = $self->bg_by->{id}->{ $entry->{object}->buchungsgruppen_id };
 413   # $bg  ||= SL::DB::Buchungsgruppe->new(inventory_accno_id => 1); # does this case ever occur?
 414
 415   my $part_type = $self->settings->{part_type};
 416   if ($part_type eq 'mixed') {
 417     $part_type = $entry->{raw_data}->{part_type} =~ m/^p/i ? 'part'
 418                : $entry->{raw_data}->{part_type} =~ m/^s/i ? 'service'
 419                : $entry->{raw_data}->{part_type} =~ m/^assem/i ? 'assembly'
 420                : $entry->{raw_data}->{part_type} =~ m/^assor/i ? 'assortment'
 421                : undef;
 422   }
 423
 424   # when saving income_accno_id or expense_accno_id use ids from the selected
 425   # $bg according to the default tax_zone (the one with the highest sort
 426   # order).  Alternatively one could use the ids from defaults, but they might
 427   # not all be set.
 428   # Only use existing bg
 429
 430   # $entry->{object}->income_accno_id( $bg->income_accno_id( SL::DB::Manager::TaxZone->get_default->id ) );
 431
 432   # if ($part_type eq 'part' || $part_type eq 'service') {
 433   #   $entry->{object}->expense_accno_id( $bg->expense_accno_id( SL::DB::Manager::TaxZone->get_default->id ) );
 434   # }
 435
 436   # if ($part_type eq 'part') {
 437   #   $entry->{object}->inventory_accno_id( $bg->inventory_accno_id );
 438   # }
 439
 440   if (none { $_ eq $part_type } qw(part service assembly assortment)) {
 441     push @{ $entry->{errors} }, $::locale->text('Error: Invalid part type');
 442     return 0;
 443   }
 444
 445   $entry->{object}->part_type($part_type);
 446
 447   return 1;
 448 }
 449
 450 sub check_price_factor {
 451   my ($self, $entry) = @_;
 452
 453   my $object = $entry->{object};
 454
 455   # Check whether or not price factor ID is valid.
 456   if ($object->price_factor_id && !$self->price_factors_by->{id}->{ $object->price_factor_id }) {
 457     push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 458     return 0;
 459   }
 460
 461   # Map name to ID if given.
 462   if (!$object->price_factor_id && $entry->{raw_data}->{price_factor}) {
 463     my $pf = $self->price_factors_by->{description}->{ $entry->{raw_data}->{price_factor} };
 464
 465     if (!$pf) {
 466       push @{ $entry->{errors} }, $::locale->text('Error: Invalid price factor');
 467       return 0;
 468     }
 469
 470     $object->price_factor_id($pf->id);
 471     $self->clone_methods->{price_factor_id} = 1;
 472   }
 473
 474   return 1;
 475 }
 476
 477 sub check_warehouse_and_bin {
 478   my ($self, $entry) = @_;
 479
 480   my $object = $entry->{object};
 481
 482   # Check whether or not warehouse id is valid.
 483   if ($object->warehouse_id && !$self->warehouses_by->{id}->{ $object->warehouse_id }) {
 484     push @{ $entry->{errors} }, $::locale->text('Error: Invalid warehouse id');
 485     return 0;
 486   }
 487   # Map name to ID if given.
 488   if (!$object->warehouse_id && $entry->{raw_data}->{warehouse}) {
 489     my $wh = $self->warehouses_by->{description}->{ $entry->{raw_data}->{warehouse} };
 490
 491     if (!$wh) {
 492       push @{ $entry->{errors} }, $::locale->text('Error: Invalid warehouse name #1',$entry->{raw_data}->{warehouse});
 493       return 0;
 494     }
 495
 496     $object->warehouse_id($wh->id);
 497   }
 498   $self->clone_methods->{warehouse_id} = 1;
 499
 500   # Check whether or not bin id is valid.
 501   if ($object->bin_id && !$self->bins_by->{id}->{ $object->bin_id }) {
 502     push @{ $entry->{errors} }, $::locale->text('Error: Invalid bin id');
 503     return 0;
 504   }
 505   # Map name to ID if given.
 506   if ($object->warehouse_id && !$object->bin_id && $entry->{raw_data}->{bin}) {
 507     my $bin = $self->bins_by->{description}->{ $entry->{raw_data}->{bin} };
 508
 509     if (!$bin) {
 510       push @{ $entry->{errors} }, $::locale->text('Error: Invalid bin name #1',$entry->{raw_data}->{bin});
 511       return 0;
 512     }
 513
 514     $object->bin_id($bin->id);
 515   }
 516   $self->clone_methods->{bin_id} = 1;
 517
 518   if ($object->warehouse_id && $object->bin_id ) {
 519     my $bin = $self->bins_by->{id}->{ $object->bin_id };
 520     if ( $bin->warehouse_id != $object->warehouse_id ) {
 521       push @{ $entry->{errors} }, $::locale->text('Error: Bin #1 is not from warehouse #2',
 522                                                   $self->bins_by->{id}->{$object->bin_id}->description,
 523                                                   $self->warehouses_by->{id}->{ $object->warehouse_id }->description);
 524       return 0;
 525     }
 526   }
 527   return 1;
 528 }
 529
 530 sub check_partsgroup {
 531   my ($self, $entry) = @_;
 532
 533   my $object = $entry->{object};
 534
 535   # Check whether or not part group ID is valid.
 536   if ($object->partsgroup_id && !$self->partsgroups_by->{id}->{ $object->partsgroup_id }) {
 537     push @{ $entry->{errors} }, $::locale->text('Error: Invalid parts group');
 538     return 0;
 539   }
 540
 541   # Map name to ID if given.
 542   if (!$object->partsgroup_id && $entry->{raw_data}->{partsgroup}) {
 543     my $pg = $self->partsgroups_by->{partsgroup}->{ $entry->{raw_data}->{partsgroup} };
 544
 545     if (!$pg) {
 546       push @{ $entry->{errors} }, $::locale->text('Error: Invalid parts group');
 547       return 0;
 548     }
 549
 550     $object->partsgroup_id($pg->id);
 551   }
 552   # register payment_id for method copying later
 553   $self->clone_methods->{partsgroup_id} = 1;
 554
 555   return 1;
 556 }
 557
 558 sub check_unit {
 559   my ($self, $entry) = @_;
 560
 561   my $object = $entry->{object};
 562
 563   $object->unit($self->settings->{default_unit}) unless $object->unit;
 564
 565   # Check whether or unit is valid.
 566   if (!$self->units_by->{name}->{ $object->unit }) {
 567     push @{ $entry->{errors} }, $::locale->text('Error: Unit missing or invalid');
 568     return 0;
 569   }
 570
 571   return 1;
 572 }
 573
 574 sub handle_translations {
 575   my ($self, $entry) = @_;
 576
 577   my @translations;
 578   foreach my $language (@{ $self->all_languages }) {
 579     my ($desc, $notes) = @{ $entry->{raw_data} }{ "description_" . $language->article_code, "notes_" . $language->article_code };
 580     next unless $desc || $notes;
 581
 582     push @translations, SL::DB::Translation->new(language_id     => $language->id,
 583                                                  translation     => $desc,
 584                                                  longdescription => $notes);
 585   }
 586
 587   $entry->{object}->translations(\@translations);
 588 }
 589
 590 sub handle_pricegroups {
 591   my ($self, $entry) = @_;
 592
 593   my @prices;
 594   my $idx = 0;
 595   foreach my $pricegroup (@{ $self->all_pricegroups }) {
 596     $idx++;
 597     my $sellprice = $entry->{raw_data}->{"pricegroup_${idx}"};
 598     next if $sellprice eq '';
 599
 600     push @prices, SL::DB::Price->new(pricegroup_id => $pricegroup->id,
 601                                      price         => $::form->parse_amount(\%::myconfig, $sellprice));
 602   }
 603
 604   $entry->{object}->prices(\@prices);
 605 }
 606
 607 sub handle_makemodel {
 608   my ($self, $entry) = @_;
 609   my $object = $entry->{object};
 610   my $found_any;
 611
 612   my @makemodels;
 613   foreach my $idx (sort map { substr $_, 5 } grep { m/^make_\d+$/ && $entry->{raw_data}->{$_} } keys %{ $entry->{raw_data} }) {
 614     my $vendor = $entry->{raw_data}->{"make_${idx}"};
 615     $vendor    = $self->vc_by->{id}->               { $vendor }
 616               || $self->vc_by->{number}->{vendors}->{ $vendor }
 617               || $self->vc_by->{name}->  {vendors}->{ $vendor };
 618
 619     if (ref($vendor) ne 'SL::DB::Vendor') {
 620       push @{ $entry->{errors} }, $::locale->text('Error: Invalid vendor in column make_#1', $idx);
 621
 622     } else {
 623       $found_any = 1;
 624       push @makemodels, SL::DB::MakeModel->new(make               => $vendor->id,
 625                                                model              => $entry->{raw_data}->{"model_${idx}"},
 626                                                lastcost_as_number => $entry->{raw_data}->{"lastcost_${idx}"});
 627
 628       $self->makemodel_columns->{$idx}    = 1;
 629       $entry->{raw_data}->{"make_${idx}"} = $vendor->name;
 630     }
 631   }
 632
 633   $object->makemodels(\@makemodels);
 634   $object->makemodel(scalar(@makemodels) ? 1 : 0);
 635
 636   if ( !$entry->{part} || $self->settings->{article_number_policy} ne 'update_prices' ) {
 637     return;
 638   }
 639
 640   my %old_makemodels_by_mm = map { $_->make . $; . $_->model => $_ } $entry->{part}->makemodels;
 641   my @new_makemodels;
 642
 643   foreach my $makemodel ($object->makemodels()) {
 644     my $makemodel_orig = $old_makemodels_by_mm{$makemodel->make,$makemodel->model};
 645     $found_any = 1;
 646
 647     if ($makemodel_orig) {
 648       $makemodel_orig->model($makemodel->model);
 649       $makemodel_orig->lastcost($makemodel->lastcost);
 650
 651     } else {
 652       push @new_makemodels, $makemodel;
 653     }
 654   }
 655
 656   $entry->{part}->makemodels([ $entry->{part}->makemodels, @new_makemodels ]) if @new_makemodels;
 657
 658   # reindex makemodels
 659   my $i = 0;
 660   $_->sortorder(++$i) for @{ $entry->{part}->makemodels };
 661
 662   $self->save_with_cascade(1) if $found_any;
 663 }
 664
 665 sub set_various_fields {
 666   my ($self, $entry) = @_;
 667
 668   $entry->{object}->priceupdate(DateTime->now_local);
 669 }
 670
 671 sub init_profile {
 672   my ($self) = @_;
 673
 674   my $profile = $self->SUPER::init_profile;
 675   delete @{$profile}{qw(bom makemodel priceupdate stockable type)};
 676
 677   $profile->{"pricegroup_$_"} = '' for 1 .. scalar @{ $_[0]->all_pricegroups };
 678
 679   return $profile;
 680 }
 681
 682 sub save_objects {
 683   my ($self, %params) = @_;
 684
 685   my $with_number    = [ grep { $_->{object}->partnumber ne '####' } @{ $self->controller->data } ];
 686   my $without_number = [ grep { $_->{object}->partnumber eq '####' } @{ $self->controller->data } ];
 687
 688   map { $_->{object}->partnumber('') } @{ $without_number };
 689
 690   $self->SUPER::save_objects(data => $with_number);
 691   $self->SUPER::save_objects(data => $without_number);
 692 }
 693
 694 sub setup_displayable_columns {
 695   my ($self) = @_;
 696
 697   $self->SUPER::setup_displayable_columns;
 698   $self->add_cvar_columns_to_displayable_columns;
 699
 700   $self->add_displayable_columns({ name => 'bin_id',             description => $::locale->text('Bin (database ID)')                                    },
 701                                  { name => 'bin',                description => $::locale->text('Bin (name)')                                           },
 702                                  { name => 'buchungsgruppen_id', description => $::locale->text('Booking group (database ID)')                         },
 703                                  { name => 'buchungsgruppe',     description => $::locale->text('Booking group (name)')                                },
 704                                  { name => 'description',        description => $::locale->text('Description')                                          },
 705                                  { name => 'drawing',            description => $::locale->text('Drawing')                                              },
 706                                  { name => 'ean',                description => $::locale->text('EAN')                                                  },
 707                                  { name => 'formel',             description => $::locale->text('Formula')                                              },
 708                                  { name => 'gv',                 description => $::locale->text('Business Volume')                                      },
 709                                  { name => 'has_sernumber',      description => $::locale->text('Has serial number')                                    },
 710                                  { name => 'image',              description => $::locale->text('Image')                                                },
 711                                  { name => 'lastcost',           description => $::locale->text('Last Cost')                                            },
 712                                  { name => 'listprice',          description => $::locale->text('List Price')                                           },
 713                                  { name => 'make_X',             description => $::locale->text('Make (vendor\'s database ID, number or name; with X being a number)') . ' [1]' },
 714                                  { name => 'microfiche',         description => $::locale->text('Microfiche')                                           },
 715                                  { name => 'model_X',            description => $::locale->text('Model (with X being a number)') . ' [1]'               },
 716                                  { name => 'lastcost_X',         description => $::locale->text('Lastcost (with X being a number)') . ' [1]'            },
 717                                  { name => 'not_discountable',   description => $::locale->text('Not Discountable')                                     },
 718                                  { name => 'notes',              description => $::locale->text('Notes')                                                },
 719                                  { name => 'obsolete',           description => $::locale->text('Obsolete')                                             },
 720                                  { name => 'onhand',             description => $::locale->text('On Hand') . ' [2]'                                     },
 721                                  { name => 'partnumber',         description => $::locale->text('Part Number')                                          },
 722                                  { name => 'partsgroup_id',      description => $::locale->text('Partsgroup (database ID)')                             },
 723                                  { name => 'partsgroup',         description => $::locale->text('Partsgroup (name)')                                    },
 724                                  { name => 'payment_id',         description => $::locale->text('Payment terms (database ID)')                          },
 725                                  { name => 'payment',            description => $::locale->text('Payment terms (name)')                                 },
 726                                  { name => 'price_factor_id',    description => $::locale->text('Price factor (database ID)')                           },
 727                                  { name => 'price_factor',       description => $::locale->text('Price factor (name)')                                  },
 728                                  { name => 'rop',                description => $::locale->text('ROP')                                                  },
 729                                  { name => 'sellprice',          description => $::locale->text('Sellprice')                                            },
 730                                  { name => 'shop',               description => $::locale->text('Shop article')                                          },
 731                                  { name => 'type',               description => $::locale->text('Article type')  . ' [3]'                             },
 732                                  { name => 'unit',               description => $::locale->text('Unit (if missing or empty default unit will be used)') },
 733                                  { name => 've',                 description => $::locale->text('Verrechnungseinheit')                                  },
 734                                  { name => 'warehouse_id',       description => $::locale->text('Warehouse (database ID)')                              },
 735                                  { name => 'warehouse',          description => $::locale->text('Warehouse (name)')                              },
 736                                  { name => 'weight',             description => $::locale->text('Weight')                                               },
 737                                 );
 738
 739   foreach my $language (@{ $self->all_languages }) {
 740     $self->add_displayable_columns({ name        => 'description_' . $language->article_code,
 741                                      description => $::locale->text('Description (translation for #1)', $language->description) },
 742                                    { name        => 'notes_' . $language->article_code,
 743                                      description => $::locale->text('Notes (translation for #1)', $language->description) });
 744   }
 745
 746   my $idx = 0;
 747   foreach my $pricegroup (@{ $self->all_pricegroups }) {
 748     $idx++;
 749     $self->add_displayable_columns({ name        => 'pricegroup_' . $idx,
 750                                      description => $::locale->text("Sellprice for price group '#1'", $pricegroup->pricegroup) });
 751   }
 752 }
 753
 754 1;