SL/Dev/Part.pm

   1 package SL::Dev::Part;
   2
   3 use strict;
   4 use base qw(Exporter);
   5 our @EXPORT = qw(create_part create_service create_assembly create_assortment);
   6
   7 use SL::DB::Part;
   8 use SL::DB::Unit;
   9 use SL::DB::Buchungsgruppe;
  10
  11 sub create_part {
  12   my (%params) = @_;
  13
  14   my $part = SL::DB::Part->new_part(
  15     description        => 'Test part',
  16     sellprice          => '10',
  17     lastcost           => '5',
  18     buchungsgruppen_id => _default_buchungsgruppe()->id,
  19     unit               => _default_unit()->name
  20   );
  21   $part->assign_attributes( %params );
  22   return $part;
  23 }
  24
  25 sub create_service {
  26   my (%params) = @_;
  27
  28   my $part = SL::DB::Part->new_service(
  29     description        => 'Test service',
  30     sellprice          => '10',
  31     lastcost           => '5',
  32     buchungsgruppen_id => _default_buchungsgruppe()->id,
  33     unit               => _default_unit()->name
  34   );
  35   $part->assign_attributes( %params );
  36   return $part;
  37 }
  38
  39 sub create_assembly {
  40   my (%params) = @_;
  41
  42   my @parts;
  43   my $part1 = SL::Dev::Part::create_part(partnumber   => 'ap1',
  44                                          description  => 'Testpart',
  45                                         )->save;
  46   push(@parts, $part1);
  47
  48   my $number_of_parts = delete $params{number_of_parts} || 3;
  49
  50   for my $i ( 2 .. $number_of_parts ) {
  51     my $part = $parts[0]->clone_and_reset;
  52     $part->partnumber(  ($part->partnumber  // '') . " " . $i );
  53     $part->description( ($part->description // '') . " " . $i );
  54     $part->save;
  55     push(@parts, $part);
  56   }
  57
  58   my $assembly = SL::DB::Part->new_assembly(
  59     partnumber         => 'as1',
  60     description        => 'Test Assembly',
  61     sellprice          => '10',
  62     lastcost           => '5',
  63     buchungsgruppen_id => _default_buchungsgruppe()->id,
  64     unit               => _default_unit()->name
  65   );
  66
  67   foreach my $part ( @parts ) {
  68     $assembly->add_assemblies( SL::DB::Assembly->new(parts_id => $part->id, qty => 1, bom => 1) );
  69   }
  70   $assembly->assign_attributes( %params );
  71   return $assembly;
  72 }
  73
  74 sub create_assortment {
  75   my (%params) = @_;
  76
  77   my $assortment_items = [];
  78   if ( $params{assortment_items} ) {
  79     $assortment_items = $params{assortment_items};
  80   } else {
  81     # no assortment items were passed, create a part, clone it several times
  82     # and add to assortment as assortment_items
  83     my @parts;
  84     my $part1 = SL::Dev::Part::create_part(partnumber   => 'sp1',
  85                                            description  => 'Testpart assortment',
  86                                           )->save;
  87     push(@parts, $part1);
  88
  89     my $number_of_parts = delete $params{number_of_parts} || 3;
  90
  91     for my $i ( 2 .. $number_of_parts ) {
  92       my $part = $parts[0]->clone_and_reset;
  93       $part->partnumber(  ($part->partnumber  // '') . " " . $i );
  94       $part->description( ($part->description // '') . " " . $i );
  95       $part->save;
  96       push(@parts, $part);
  97     }
  98     my $position = 0;
  99     foreach my $part ( @parts ) {
 100       push( @{$assortment_items}, SL::DB::AssortmentItem->new(parts_id => $part->id,
 101                                                               qty      => 1,
 102                                                               position => $position++,
 103                                                               charge   => 1,
 104                                                               unit     => $part->unit,
 105                                                              ));
 106     }
 107   }
 108
 109   my $assortment = SL::DB::Part->new_assortment(
 110     partnumber         => 'as1',
 111     description        => 'Test Assortment',
 112     sellprice          => '10',
 113     lastcost           => '5',
 114     assortment_items   => $assortment_items,
 115     buchungsgruppen_id => _default_buchungsgruppe()->id,
 116     unit               => _default_unit()->name
 117   );
 118
 119   $assortment->assign_attributes( %params );
 120   return $assortment;
 121 }
 122
 123
 124 sub _default_buchungsgruppe {
 125   return SL::DB::Manager::Buchungsgruppe->find_by(description => 'Standard 19%') || die "No accounting group";
 126 }
 127
 128 sub _default_unit {
 129   return SL::DB::Manager::Unit->find_by(name => 'Stck') || die "No unit";
 130 }
 131
 132
 133 1;
 134
 135 __END__
 136
 137 =head1 NAME
 138
 139 SL::Dev::Part - create part objects for testing, with minimal defaults
 140
 141 =head1 FUNCTIONS
 142
 143 =head2 C<create_part %PARAMS>
 144
 145 Creates a new part (part_type = part).
 146
 147 Minimal usage, default values, without saving to database:
 148
 149   my $part = SL::Dev::Part::create_part();
 150
 151 Create a test part with a default warehouse and bin and save it:
 152
 153   my $wh    = SL::Dev::Inventory::create_warehouse_and_bins()->save;
 154   my $part1 = SL::Dev::Part::create_part(partnumber   => 'a123',
 155                                          description  => 'Testpart 1',
 156                                          warehouse_id => $wh->id,
 157                                          bin_id       => $wh->bins->[0]->id,
 158                                         )->save;
 159
 160 =head2 C<create_service %PARAMS>
 161
 162 Creates a new service (part_type = service).
 163
 164 Minimal usage, default values, without saving to database:
 165
 166   my $part = SL::Dev::Part::create_service();
 167
 168 =head2 C<create_assembly %PARAMS>
 169
 170 Create a new assembly (part_type = assembly).
 171
 172 By default 3 parts (p1, p2, p3) are created and saved as an assembly (as1).
 173
 174   my $assembly = SL::Dev::Part::create_assembly->save;
 175
 176 Create a new assembly with 10 parts:
 177
 178   my $assembly = SL::Dev::Part::create_assembly(number_of_parts => 10)->save;
 179
 180 =head2 C<create_assortment %PARAMS>
 181
 182 Create a new assortment (part_type = assortment).
 183
 184 By default 3 parts (p1, p2, p3) are created and saved as an assortment.
 185
 186   my $assortment = SL::Dev::Part::create_assortment->save;
 187
 188 Create a new assortment with 10 automatically created parts using the
 189 number_of_parts param:
 190
 191   my $assortment = SL::Dev::Part::create_assortment(number_of_parts => 10)->save;
 192
 193 Create an assortment with a certain name and pass some assortment_item Objects
 194 from newly created parts:
 195
 196   my $part1             = SL::Dev::Part::create_part( sellprice => '7.77')->save;
 197   my $part2             = SL::Dev::Part::create_part( sellprice => '6.66')->save;
 198   my $assortment_item_1 = SL::DB::AssortmentItem->new( parts_id => $part1->id, qty => 3, unit => $part1->unit, position => 1);
 199   my $assortment_item_2 = SL::DB::AssortmentItem->new( parts_id => $part2->id, qty => 3, unit => $part2->unit, position => 2);
 200   my $assortment_part   = SL::Dev::Part::create_assortment( partnumber  => 'Assortment 1',
 201                                                             description => 'assortment test',
 202                                                             sellprice   => '0',
 203                                                             part_type   => 'assortment',
 204                                                             assortment_items => [ $assortment_item_1, $assortment_item_2 ],
 205                                                           )->save;
 206
 207 =head1 TODO
 208
 209 Nothing here yet.
 210
 211 =head1 BUGS
 212
 213 Nothing here yet.
 214
 215 =head1 AUTHOR
 216
 217 G. Richardson E<lt>grichardson@kivitendo-premium.deE<gt>
 218
 219 =cut