SL/Controller/CsvImport.pm

   1 package SL::Controller::CsvImport;
   2
   3 use strict;
   4
   5 use SL::DB::Buchungsgruppe;
   6 use SL::DB::CsvImportProfile;
   7 use SL::DB::CsvImportReport;
   8 use SL::DB::Unit;
   9 use SL::DB::Helper::Paginated ();
  10 use SL::Helper::Flash;
  11 use SL::SessionFile;
  12 use SL::Controller::CsvImport::Contact;
  13 use SL::Controller::CsvImport::CustomerVendor;
  14 use SL::Controller::CsvImport::Part;
  15 use SL::Controller::CsvImport::Shipto;
  16 use SL::Controller::CsvImport::Project;
  17 use SL::BackgroundJob::CsvImport;
  18 use SL::System::TaskServer;
  19
  20 use List::MoreUtils qw(none);
  21 use List::Util qw(min);
  22
  23 use parent qw(SL::Controller::Base);
  24
  25 use Rose::Object::MakeMethods::Generic
  26 (
  27  scalar                  => [ qw(type profile file all_profiles all_charsets sep_char all_sep_chars quote_char all_quote_chars escape_char all_escape_chars all_buchungsgruppen all_units
  28                                  import_status errors headers raw_data_headers info_headers data num_imported num_importable displayable_columns file) ],
  29  'scalar --get_set_init' => [ qw(worker) ],
  30  'array'                 => [
  31    progress_tracker     => { },
  32    add_progress_tracker => {  interface => 'add', hash_key => 'progress_tracker' },
  33  ],
  34 );
  35
  36 __PACKAGE__->run_before('check_auth');
  37 __PACKAGE__->run_before('ensure_form_structure');
  38 __PACKAGE__->run_before('check_type', except => [ qw(report) ]);
  39 __PACKAGE__->run_before('load_all_profiles');
  40
  41 #
  42 # actions
  43 #
  44
  45 sub action_new {
  46   my ($self) = @_;
  47
  48   $self->load_default_profile unless $self->profile;
  49   $self->render_inputs;
  50 }
  51
  52 sub action_test {
  53   my ($self) = @_;
  54   $self->test_and_import_deferred(test => 1);
  55 }
  56
  57 sub action_import {
  58   my $self = shift;
  59   $self->test_and_import_deferred(test => 0);
  60 }
  61
  62 sub action_save {
  63   my ($self) = @_;
  64
  65   $self->profile_from_form(SL::DB::Manager::CsvImportProfile->find_by(name => $::form->{profile}->{name}, login => $::myconfig{login}));
  66   $self->profile->save;
  67
  68   flash_later('info', $::locale->text("The profile has been saved under the name '#1'.", $self->profile->name));
  69   $self->redirect_to(action => 'new', 'profile.type' => $self->type, 'profile.id' => $self->profile->id);
  70 }
  71
  72 sub action_destroy {
  73   my $self = shift;
  74
  75   my $profile = SL::DB::CsvImportProfile->new(id => $::form->{profile}->{id}, login => $::myconfig{login});
  76   $profile->delete(cascade => 1);
  77
  78   flash_later('info', $::locale->text('The profile \'#1\' has been deleted.', $profile->name));
  79   $self->redirect_to(action => 'new', 'profile.type' => $self->type);
  80 }
  81
  82 sub action_result {
  83   my $self = shift;
  84
  85   # load resultobject
  86   $self->{background_job} = SL::DB::Manager::BackgroundJob->find_by(id => $::form->{job});
  87
  88   my $data = $self->{background_job}->data_as_hash;
  89
  90   my $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $data->{profile_id});
  91
  92   $self->profile($profile);
  93
  94   if ($data->{errors} and my $first_error =  $data->{errors}->[0]) {
  95     flash('error', $::locale->text('There was an error parsing the csv file: #1 in line #2.', $first_error->[2], $first_error->[0]));
  96   }
  97
  98   if ($data->{progress}{finished} || $data->{errors}) {
  99     $self->action_report(report_id => $data->{report_id}, no_layout => 1);
 100   } else {
 101     $self->render('csv_import/_deferred_results', { no_layout => 1 });
 102   }
 103 }
 104
 105 sub action_download_sample {
 106   my $self = shift;
 107
 108   $self->profile_from_form;
 109   $self->setup_help;
 110
 111   my $file_name = 'csv_import_sample_' . $self->type . '.csv';
 112   my $file      = SL::SessionFile->new($file_name, mode => '>', encoding => $self->profile->get('charset'));
 113   my $csv       = Text::CSV_XS->new({ binary => 1, map { ( $_ => $self->profile->get($_) ) } qw(sep_char escape_char quote_char),});
 114
 115   $csv->print($file->fh, [ map { $_->{name}        } @{ $self->displayable_columns } ]);
 116   $file->fh->print("\r\n");
 117   $csv->print($file->fh, [ map { $_->{description} } @{ $self->displayable_columns } ]);
 118   $file->fh->print("\r\n");
 119
 120   $file->fh->close;
 121
 122   $self->send_file($file->file_name, name => $file_name);
 123 }
 124
 125 sub action_report {
 126   my ($self, %params) = @_;
 127
 128   my $report_id = $params{report_id} || $::form->{id};
 129
 130   $self->{report}      = SL::DB::Manager::CsvImportReport->find_by(id => $report_id);
 131   my $num_rows         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id ]);
 132   my $num_cols         = SL::DB::Manager::CsvImportReportRow->get_all_count(query => [ csv_import_report_id => $report_id, row => 0 ]);
 133
 134   # manual paginating, yuck
 135   my $page = $::form->{page} || 1;
 136   my $pages = {};
 137   $pages->{per_page}        = $::form->{per_page} || 20;
 138   $pages->{max}             = SL::DB::Helper::Paginated::ceil($num_rows / ($num_cols || 1), $pages->{per_page}) || 1;
 139   $pages->{cur}             = $page < 1 ? 1
 140                             : $page > $pages->{max} ? $pages->{max}
 141                             : $page;
 142   $pages->{common}          = SL::DB::Helper::Paginated::make_common_pages($pages->{cur}, $pages->{max});
 143
 144   $self->{display_rows} = [
 145     0,
 146     $pages->{per_page} * ($pages->{cur}-1) + 1
 147       ..
 148     min($pages->{per_page} * $pages->{cur}, $num_rows / ($num_cols || 1) - 1)
 149   ];
 150
 151   my @query = (
 152     csv_import_report_id => $report_id,
 153     or => [
 154       row => 0,
 155       and => [
 156         row => { gt => $pages->{per_page} * ($pages->{cur}-1) },
 157         row => { le => $pages->{per_page} * $pages->{cur} },
 158       ]
 159     ]
 160   );
 161
 162   my $rows             = SL::DB::Manager::CsvImportReportRow->get_all(query => \@query);
 163   my $status           = SL::DB::Manager::CsvImportReportStatus->get_all(query => \@query);
 164
 165   $self->{report_rows}   = $self->{report}->folded_rows(rows => $rows);
 166   $self->{report_status} = $self->{report}->folded_status(status => $status);
 167   $self->{pages} = $pages;
 168
 169   my $base_url = $self->url_for(action => 'report', id => $report_id);
 170
 171   $self->render('csv_import/report', { no_layout => $params{no_layout} }, base_url => $base_url);
 172 }
 173
 174
 175 #
 176 # filters
 177 #
 178
 179 sub check_auth {
 180   $::auth->assert('config');
 181 }
 182
 183 sub check_type {
 184   my ($self) = @_;
 185
 186   die "Invalid CSV import type" if none { $_ eq $::form->{profile}->{type} } qw(parts customers_vendors addresses contacts projects);
 187   $self->type($::form->{profile}->{type});
 188 }
 189
 190 sub ensure_form_structure {
 191   my ($self, %params) = @_;
 192
 193   $::form->{profile}  = {} unless ref $::form->{profile}  eq 'HASH';
 194   $::form->{settings} = {} unless ref $::form->{settings} eq 'HASH';
 195 }
 196
 197 #
 198 # helpers
 199 #
 200
 201 sub render_inputs {
 202   my ($self, %params) = @_;
 203
 204   $self->all_charsets([ [ 'UTF-8',       'UTF-8'                 ],
 205                         [ 'ISO-8859-1',  'ISO-8859-1 (Latin 1)'  ],
 206                         [ 'ISO-8859-15', 'ISO-8859-15 (Latin 9)' ],
 207                         [ 'CP850',       'CP850 (DOS/ANSI)'      ],
 208                         [ 'CP1252',      'CP1252 (Windows)'      ],
 209                       ]);
 210
 211   my %char_map = $self->char_map;
 212
 213   foreach my $type (qw(sep quote escape)) {
 214     my $sub = "all_${type}_chars";
 215     $self->$sub([ sort { $a->[0] cmp $b->[0] } values %{ $char_map{$type} } ]);
 216
 217     my $char = $self->profile->get($type . '_char');
 218     $sub     = "${type}_char";
 219     $self->$sub(($char_map{$type}->{$char} || [])->[0] || $char);
 220   }
 221
 222   $self->file(SL::SessionFile->new($self->csv_file_name));
 223
 224   my $title = $self->type eq 'customers_vendors' ? $::locale->text('CSV import: customers and vendors')
 225             : $self->type eq 'addresses'         ? $::locale->text('CSV import: shipping addresses')
 226             : $self->type eq 'contacts'          ? $::locale->text('CSV import: contacts')
 227             : $self->type eq 'parts'             ? $::locale->text('CSV import: parts and services')
 228             : $self->type eq 'projects'          ? $::locale->text('CSV import: projects')
 229             : die;
 230
 231   if ($self->{type} eq 'parts') {
 232     $self->all_buchungsgruppen(SL::DB::Manager::Buchungsgruppe->get_all_sorted);
 233     $self->all_units(SL::DB::Manager::Unit->get_all_sorted);
 234   }
 235
 236   $self->setup_help;
 237
 238   $self->render('csv_import/form', title => $title);
 239 }
 240
 241 sub test_and_import_deferred {
 242   my ($self, %params) = @_;
 243
 244   $self->profile_from_form;
 245
 246   if ($::form->{file}) {
 247     my $file = SL::SessionFile->new($self->csv_file_name, mode => '>');
 248     $file->fh->print($::form->{file});
 249     $file->fh->close;
 250   }
 251
 252   $self->{background_job} = SL::BackgroundJob::CsvImport->create_job(
 253     file    => $self->csv_file_name,
 254     profile => $self->profile,
 255     type    => $self->profile->type,
 256     test    => $params{test},
 257   )->save;
 258
 259   SL::System::TaskServer->start_if_not_running;
 260   SL::System::TaskServer->wake_up;
 261
 262   flash('info', $::locale->text('Your import is beig processed.'));
 263
 264   $self->{deferred} = 1;
 265
 266   $self->render_inputs;
 267 }
 268
 269 sub test_and_import {
 270   my ($self, %params) = @_;
 271
 272   my $file = SL::SessionFile->new(
 273     $self->csv_file_name,
 274     mode       => '<',
 275     encoding   => $self->profile->get('charset'),
 276     session_id => $params{session_id}
 277   );
 278
 279   $self->file($file);
 280
 281   my $worker = $self->worker();
 282
 283   $worker->run;
 284
 285   return if $self->errors;
 286
 287   $self->num_imported(0);
 288   $worker->save_objects if !$params{test};
 289
 290   $self->num_importable(scalar grep { !$_ } map { scalar @{ $_->{errors} } } @{ $self->data || [] });
 291   $self->import_status($params{test} ? 'tested' : 'imported');
 292
 293 #  flash('info', $::locale->text('Objects have been imported.')) if !$params{test};
 294 }
 295
 296 sub load_default_profile {
 297   my ($self) = @_;
 298
 299   my $profile;
 300   if ($::form->{profile}->{id}) {
 301     $profile = SL::DB::Manager::CsvImportProfile->find_by(id => $::form->{profile}->{id}, login => $::myconfig{login});
 302   }
 303   $profile ||= SL::DB::Manager::CsvImportProfile->find_by(type => $self->{type}, is_default => 1, login => $::myconfig{login});
 304   $profile ||= SL::DB::CsvImportProfile->new(type => $self->{type}, login => $::myconfig{login});
 305
 306   $self->profile($profile);
 307   $self->profile->set_defaults;
 308 }
 309
 310 sub load_all_profiles {
 311   my ($self, %params) = @_;
 312
 313   $self->all_profiles(SL::DB::Manager::CsvImportProfile->get_all(
 314     where => [
 315       type  => $self->type,
 316       login => $::myconfig{login},
 317     ],
 318   sort_by => 'name'));
 319 }
 320
 321 sub profile_from_form {
 322   my ($self, $existing_profile) = @_;
 323
 324   delete $::form->{profile}->{id};
 325
 326   my %char_map = $self->char_map;
 327   my @settings;
 328
 329   foreach my $type (qw(sep quote escape)) {
 330     my %rev_chars = map { $char_map{$type}->{$_}->[0] => $_ } keys %{ $char_map{$type} };
 331     my $char      = $::form->{"${type}_char"} eq 'custom' ? $::form->{"custom_${type}_char"} : $rev_chars{ $::form->{"${type}_char"} };
 332
 333     push @settings, { key => "${type}_char", value => $char };
 334   }
 335
 336   if ($self->type eq 'parts') {
 337     $::form->{settings}->{sellprice_adjustment} = $::form->parse_amount(\%::myconfig, $::form->{settings}->{sellprice_adjustment});
 338   }
 339
 340   delete $::form->{profile}->{id};
 341   $self->profile($existing_profile || SL::DB::CsvImportProfile->new(login => $::myconfig{login}));
 342   $self->profile->assign_attributes(%{ $::form->{profile} });
 343   $self->profile->settings(map({ { key => $_, value => $::form->{settings}->{$_} } } keys %{ $::form->{settings} }),
 344                            @settings);
 345   $self->profile->set_defaults;
 346 }
 347
 348 sub char_map {
 349   return ( sep    => { ','  => [ 'comma',     $::locale->text('Comma')     ],
 350                        ';'  => [ 'semicolon', $::locale->text('Semicolon') ],
 351                        "\t" => [ 'tab',       $::locale->text('Tab')       ],
 352                        ' '  => [ 'space',     $::locale->text('Space')     ],
 353                      },
 354            quote  => { '"' => [ 'quote', $::locale->text('Quotes') ],
 355                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 356                      },
 357            escape => { '"' => [ 'quote', $::locale->text('Quotes') ],
 358                        "'" => [ 'singlequote', $::locale->text('Single quotes') ],
 359                      },
 360          );
 361 }
 362
 363 sub save_report {
 364   my ($self, $report_id) = @_;
 365
 366   $self->track_progress(phase => 'building report', progress => 0);
 367
 368   my $clone_profile = $self->profile->clone_and_reset_deep;
 369   $clone_profile->save; # weird bug. if this isn't saved before adding it to the report, it will default back to the last profile.
 370
 371   my $report = SL::DB::CsvImportReport->new(
 372     session_id => $::auth->create_or_refresh_session,
 373     profile    => $clone_profile,
 374     type       => $self->type,
 375     file       => '',
 376   )->save(cascade => 1);
 377
 378   my $dbh = $::form->get_standard_dbh;
 379   $dbh->begin_work;
 380
 381   my $query  = 'INSERT INTO csv_import_report_rows (csv_import_report_id, col, row, value) VALUES (?, ?, ?, ?)';
 382   my $query2 = 'INSERT INTO csv_import_report_status (csv_import_report_id, row, type, value) VALUES (?, ?, ?, ?)';
 383
 384   my $sth = $dbh->prepare($query);
 385   my $sth2 = $dbh->prepare($query2);
 386
 387   # save headers
 388   my (@headers, @info_methods, @raw_methods, @methods);
 389
 390   for my $i (0 .. $#{ $self->info_headers->{headers} }) {
 391     next unless         $self->info_headers->{used}->{ $self->info_headers->{headers}->[$i] };
 392     push @headers,      $self->info_headers->{headers}->[$i];
 393     push @info_methods, $self->info_headers->{methods}->[$i];
 394   }
 395   for my $i (0 .. $#{ $self->headers->{headers} }) {
 396     next unless         $self->headers->{used}->{ $self->headers->{headers}->[$i] };
 397     push @headers,      $self->headers->{headers}->[$i];
 398     push @methods,      $self->headers->{methods}->[$i];
 399   }
 400   for my $i (0 .. $#{ $self->raw_data_headers->{headers} }) {
 401     next unless         $self->raw_data_headers->{used}->{ $self->raw_data_headers->{headers}->[$i] };
 402     push @headers,      $self->raw_data_headers->{headers}->[$i];
 403     push @raw_methods,  $self->raw_data_headers->{headers}->[$i];
 404   }
 405
 406   $::lxdebug->dump(0,  "methods",
 407     [ \@info_methods,
 408      \@methods,
 409      \@raw_methods  ]
 410   );
 411
 412   $sth->execute($report->id, $_, 0, $headers[$_]) for 0 .. $#headers;
 413
 414   # col offsets
 415   my $o1 =       @info_methods;
 416   my $o2 = $o1 + @methods;
 417
 418   for my $row (0 .. $#{ $self->data }) {
 419     $self->track_progress(progress => $row / @{ $self->data } * 100) if $row % 100 == 0;
 420     my $data_row = $self->{data}[$row];
 421
 422     $sth->execute($report->id,       $_, $row + 1, $data_row->{info_data}{ $info_methods[$_] }) for 0 .. $#info_methods;
 423     $sth->execute($report->id, $o1 + $_, $row + 1, $data_row->{object}->${ \ $methods[$_] })    for 0 .. $#methods;
 424     $sth->execute($report->id, $o2 + $_, $row + 1, $data_row->{raw_data}{ $raw_methods[$_] })   for 0 .. $#raw_methods;
 425
 426     $sth2->execute($report->id, $row + 1, 'information', $_) for @{ $data_row->{information} || [] };
 427     $sth2->execute($report->id, $row + 1, 'errors', $_)      for @{ $data_row->{errors}      || [] };
 428   }
 429
 430   $dbh->commit;
 431
 432   return $report->id;
 433 }
 434
 435 sub csv_file_name {
 436   my ($self) = @_;
 437   return "csv-import-" . $self->type . ".csv";
 438 }
 439
 440 sub init_worker {
 441   my $self = shift;
 442
 443   my @args = (controller => $self);
 444
 445   if ( $self->file() ) {
 446     push(@args, file => $self->file());
 447   }
 448
 449   return $self->{type} eq 'customers_vendors' ? SL::Controller::CsvImport::CustomerVendor->new(@args)
 450        : $self->{type} eq 'contacts'          ? SL::Controller::CsvImport::Contact->new(@args)
 451        : $self->{type} eq 'addresses'         ? SL::Controller::CsvImport::Shipto->new(@args)
 452        : $self->{type} eq 'parts'             ? SL::Controller::CsvImport::Part->new(@args)
 453        : $self->{type} eq 'projects'          ? SL::Controller::CsvImport::Project->new(@args)
 454        :                                        die "Program logic error";
 455 }
 456
 457 sub setup_help {
 458   my ($self) = @_;
 459
 460   $self->worker->setup_displayable_columns;
 461 }
 462
 463 sub track_progress {
 464   my ($self, %params) = @_;
 465
 466   for my $tracker ($self->progress_tracker) {
 467     $tracker->track_progress(%params);
 468   }
 469 }
 470
 471
 472 1;