SL/Controller/PriceRule.pm

   1 package SL::Controller::PriceRule;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use SL::Controller::Helper::GetModels;
   8 use SL::Controller::Helper::ParseFilter;
   9 use SL::Controller::Helper::ReportGenerator;
  10 use SL::DB::PriceRule;
  11 use SL::DB::PriceRuleItem;
  12 use SL::DB::Pricegroup;
  13 use SL::DB::PartsGroup;
  14 use SL::DB::Business;
  15 use SL::Helper::Flash;
  16 use SL::ClientJS;
  17 use SL::Locale::String;
  18
  19 use Rose::Object::MakeMethods::Generic
  20 (
  21  'scalar --get_set_init' => [ qw(models price_rule vc js pricegroups partsgroups businesses) ],
  22 );
  23
  24 # __PACKAGE__->run_before('check_auth');
  25 __PACKAGE__->run_before('add_javascripts');
  26
  27 #
  28 # actions
  29 #
  30
  31 sub action_list {
  32   my ($self) = @_;
  33
  34   $self->make_filter_summary;
  35
  36   my $price_rules = $self->models->get;
  37
  38   $self->prepare_report;
  39
  40   $self->report_generator_list_objects(report => $self->{report}, objects => $price_rules, $::form->{inline} ? (layout => 0, header => 0) : ());
  41 }
  42
  43 sub action_new {
  44   my ($self) = @_;
  45
  46   $self->price_rule(SL::DB::PriceRule->new);
  47   $self->price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
  48   $self->display_form;
  49 }
  50
  51 sub action_edit {
  52   my ($self) = @_;
  53
  54   $self->display_form;
  55 }
  56
  57 sub action_create {
  58   my ($self) = @_;
  59
  60   $self->price_rule($self->price_rule->clone_and_reset_deep);
  61   $self->create_or_update;
  62 }
  63
  64 sub action_update {
  65   my ($self) = @_;
  66   $self->create_or_update;
  67 }
  68
  69  #TODO
  70 sub action_destroy {
  71   my ($self) = @_;
  72
  73   $self->price_rule->delete;
  74   flash_later('info',  $::locale->text('The price rule has been deleted.'));
  75
  76   $self->redirect_to($::form->{callback} || (action => 'list'));
  77 }
  78
  79 sub action_add_item_row {
  80   my ($self, %params) = @_;
  81
  82   my $item = SL::DB::PriceRuleItem->new(type => $::form->{type});
  83
  84   my $html = $self->render('price_rule/item', { output => 0 }, item => $item);
  85
  86   $self
  87     ->js
  88     ->before('#price_rule_new_items', $html)
  89     ->reinit_widgets
  90     ->render($self);
  91 }
  92
  93 #
  94 # filters
  95 #
  96
  97 sub check_auth {
  98   $::auth->assert('price_rule_edit');
  99 }
 100
 101 #
 102 # helpers
 103 #
 104
 105 sub display_form {
 106   my ($self, %params) = @_;
 107   my $is_new  = !$self->price_rule->id;
 108   my $title   = $is_new ?
 109     ($self->price_rule->is_sales ? t8('Create a new sales price rule') : t8('Create a new purchase price rule')) :
 110     ($self->price_rule->is_sales ? t8('Edit sales price rule') : t8('Edit purchase price rule'));
 111   $self->render('price_rule/form',
 112     title => $title,
 113     %params
 114   );
 115 }
 116
 117 sub create_or_update {
 118   my $self   = shift;
 119   my $is_new = !$self->price_rule->id;
 120   my $params = delete($::form->{price_rule}) || { };
 121
 122   delete $params->{id};
 123   $self->price_rule->assign_attributes(%{ $params });
 124
 125   my @errors = $self->price_rule->validate;
 126
 127   if (@errors) {
 128     flash('error', @errors);
 129     $self->display_form(callback => $::form->{callback});
 130     return;
 131   }
 132
 133   $self->price_rule->save;
 134
 135   flash_later('info', $is_new ? $::locale->text('The price rule has been created.') : $::locale->text('The price rule has been saved.'));
 136
 137   $self->redirect_to($::form->{callback} || (action => 'list', 'filter.type' => $self->price_rule->type));
 138 }
 139
 140 sub prepare_report {
 141   my ($self)      = @_;
 142
 143   my $callback    = $self->models->get_callback;
 144
 145   my $report      = SL::ReportGenerator->new(\%::myconfig, $::form);
 146   $self->{report} = $report;
 147
 148   my @columns     = qw(name type priority price discount items);
 149   my @sortable    = qw(name type priority price discount      );
 150
 151   my %column_defs = (
 152     name          => { obj_link => sub { $self->url_for(action => 'edit', 'price_rule.id' => $_[0]->id, callback => $callback) } },
 153     priority      => { sub  => sub { $_[0]->priority_as_text } },
 154     price         => { sub  => sub { $_[0]->price_as_number } },
 155     discount      => { sub  => sub { $_[0]->discount_as_number } },
 156     obsolete      => { sub  => sub { $_[0]->obsolete_as_bool_yn } },
 157     items         => { sub  => sub { $_[0]->item_summary } },
 158   );
 159
 160   map { $column_defs{$_}->{text} ||= $::locale->text( $self->models->get_sort_spec->{$_}->{title} ) } keys %column_defs;
 161
 162   if ( $report->{options}{output_format} =~ /^(pdf|csv)$/i ) {
 163     $self->models->disable_plugin('paginated');
 164   }
 165   $report->set_options(
 166     std_column_visibility => 1,
 167     controller_class      => 'PriceRule',
 168     output_format         => 'HTML',
 169     title                 => ($self->vc eq 'customer' ? t8('Sales Price Rules') : t8('Purchase Price Rules')) ,
 170     allow_pdf_export      => !$::form->{inline},
 171     allow_csv_export      => !$::form->{inline},
 172   );
 173   $report->set_columns(%column_defs);
 174   $report->set_column_order(@columns);
 175   $report->set_export_options(qw(list filter));
 176   $report->set_options_from_form;
 177   $self->models->get_models_url_params(sub{ map { $_ => $::form->{$_} } qw(inline) });
 178   $self->models->set_report_generator_sort_options(report => $report, sortable_columns => \@sortable);
 179   $report->set_options(
 180     raw_bottom_info_text  => $self->render('price_rule/report_bottom', { output => 0 }),
 181     raw_top_info_text     => $self->render('price_rule/report_top', { output => 0 }),
 182   );
 183 }
 184
 185 sub make_filter_summary {
 186   my ($self) = @_;
 187
 188   my $filter = $::form->{filter} || {};
 189   my @filter_strings;
 190
 191   my @filters = (
 192     [ $filter->{"name:substr::ilike"}, t8('Name')  ],
 193     [ $filter->{"price:number"},       t8('Price') ],
 194     [ $filter->{"discount:number"},    t8('Discount') ],
 195   );
 196
 197   for (@filters) {
 198     push @filter_strings, "$_->[1]: $_->[0]" if $_->[0];
 199   }
 200
 201   if ($filter->{has_item_type}) {
 202     push @filter_strings, sprintf "%s: %s", t8('Has item type'), join ', ', map {
 203       SL::DB::Manager::PriceRuleItem->get_type($_)->{description}
 204     } @{ $filter->{has_item_type} || [] };
 205   }
 206
 207   $self->{filter_summary} = join ', ', @filter_strings;
 208 }
 209
 210 sub all_price_rule_item_types {
 211   SL::DB::Manager::PriceRuleItem->get_all_types($_[0]->vc || $_[0]->price_rule->type);
 212 }
 213
 214 sub add_javascripts  {
 215   $::request->{layout}->add_javascripts(qw(kivi.PriceRule.js autocomplete_customer.js autocomplete_vendor.js autocomplete_part.js));
 216 }
 217
 218 sub init_price_rule {
 219   my ($self) = @_;
 220
 221   my $price_rule = $::form->{price_rule}{id} ? SL::DB::PriceRule->new(id => $::form->{price_rule}{id})->load : SL::DB::PriceRule->new;
 222
 223   my $items = delete $::form->{price_rule}{items};
 224
 225   $price_rule->assign_attributes(%{ $::form->{price_rule} || {} });
 226
 227   my %old_items = map { $_->id => $_ } $price_rule->items;
 228
 229   my @items;
 230   for my $raw_item (@$items) {
 231     my $item = $raw_item->{id} ? $old_items{ $raw_item->{id} } || SL::DB::PriceRuleItem->new(id => $raw_item->{id})->load : SL::DB::PriceRuleItem->new;
 232     $item->assign_attributes(%$raw_item);
 233     push @items, $item;
 234   }
 235
 236   $price_rule->items(@items) if @items;
 237
 238   $self->price_rule($price_rule);
 239 }
 240
 241 sub init_vc {
 242   $::form->{filter}{type};
 243 }
 244
 245 sub init_js {
 246   SL::ClientJS->new;
 247 }
 248
 249 sub init_businesses {
 250   SL::DB::Manager::Business->get_all;
 251 }
 252
 253 sub init_pricegroups {
 254   SL::DB::Manager::Pricegroup->get_all;
 255 }
 256
 257 sub init_partsgroups {
 258   SL::DB::Manager::PartsGroup->get_all;
 259 }
 260
 261 sub init_models {
 262   my ($self) = @_;
 263
 264   SL::Controller::Helper::GetModels->new(
 265     controller => $self,
 266     sorted => {
 267       name     => t8('Name'),
 268       type     => t8('Type'),
 269       priority => t8('Priority'),
 270       price    => t8('Price'),
 271       discount => t8('Discount'),
 272       obsolete => t8('Obsolete'),
 273       items    => t8('Rule Details'),
 274     },
 275   );
 276 }
 277
 278 1;