SL/Dispatcher.pm

   1 package SL::Dispatcher;
   2
   3 use strict;
   4
   5 BEGIN {
   6   unshift @INC, "modules/override"; # Use our own versions of various modules (e.g. YAML).
   7   push    @INC, "modules/fallback"; # Only use our own versions of modules if there's no system version.
   8   push    @INC, "SL";               # FCGI won't find modules that are not properly named. Help it by inclduging SL
   9 }
  10
  11 use CGI qw( -no_xhtml);
  12 use English qw(-no_match_vars);
  13 use SL::Auth;
  14 use SL::LXDebug;
  15 use SL::Locale;
  16 use SL::Common;
  17 use Form;
  18 use List::Util qw(first);
  19 use Moose;
  20 use Rose::DB;
  21 use Rose::DB::Object;
  22 use File::Basename;
  23
  24 # Trailing new line is added so that Perl will not add the line
  25 # number 'die' was called in.
  26 use constant END_OF_REQUEST => "END-OF-REQUEST\n";
  27
  28 sub pre_request_checks {
  29   show_error('login/auth_db_unreachable') unless $::auth->session_tables_present;
  30   $::auth->expire_sessions;
  31 }
  32
  33 sub show_error {
  34   $::lxdebug->enter_sub;
  35   my $template             = shift;
  36   my $error_type           = shift || '';
  37
  38   $::locale                = Locale->new($::language);
  39   $::form->{error}         = $::locale->text('The session is invalid or has expired.') if ($error_type eq 'session');
  40   $::form->{error}         = $::locale->text('Incorrect password!.')                   if ($error_type eq 'password');
  41   $::myconfig{countrycode} = $::language;
  42   $::form->{stylesheet}    = 'css/lx-office-erp.css';
  43
  44   $::form->header;
  45   print $::form->parse_html_template($template);
  46   $::lxdebug->leave_sub;
  47
  48   ::end_of_request();
  49 }
  50
  51 sub pre_startup_setup {
  52   eval {
  53     package main;
  54     require "config/lx-erp.conf";
  55   };
  56   eval {
  57     package main;
  58     require "config/lx-erp-local.conf";
  59   } if -f "config/lx-erp-local.conf";
  60
  61   eval {
  62     package main;
  63     require "bin/mozilla/common.pl";
  64     require "bin/mozilla/installationcheck.pl";
  65   } or die $EVAL_ERROR;
  66
  67   # canonial globals. if it's not here, chances are it will get refactored someday.
  68   {
  69     no warnings 'once';
  70     $::userspath   = "users";
  71     $::templates   = "templates";
  72     $::memberfile  = "users/members";
  73     $::menufile    = "menu.ini";
  74     $::sendmail    = "| /usr/sbin/sendmail -t";
  75     $::lxdebug     = LXDebug->new;
  76     $::auth        = SL::Auth->new;
  77     $::form        = undef;
  78     %::myconfig    = ();
  79     %::called_subs = (); # currently used for recursion detection
  80   }
  81 }
  82
  83 sub pre_startup_checks {
  84   ::verify_installation();
  85 }
  86
  87 sub pre_startup {
  88   pre_startup_setup();
  89   pre_startup_checks();
  90 }
  91
  92 sub require_main_code {
  93   my ($script, $suffix) = @_;
  94
  95   eval {
  96     package main;
  97     require "bin/mozilla/$script$suffix";
  98   } or die $EVAL_ERROR;
  99
 100   if (-f "bin/mozilla/custom_$script$suffix") {
 101     eval {
 102       package main;
 103       require "bin/mozilla/custom_$script$suffix";
 104     };
 105     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 106   }
 107   if ($::form->{login} && -f "bin/mozilla/$::form->{login}_$script") {
 108     eval {
 109       package main;
 110       require "bin/mozilla/$::form->{login}_$script";
 111     };
 112     $::form->error($EVAL_ERROR) if ($EVAL_ERROR);
 113   }
 114 }
 115
 116 sub handle_request {
 117   $::lxdebug->enter_sub;
 118   $::lxdebug->begin_request;
 119
 120   my $interface = lc(shift || 'cgi');
 121   my ($script_name, $action);
 122
 123   if ($interface =~ m/^(?:fastcgi|fcgid|fcgi)$/) {
 124     $script_name = $ENV{SCRIPT_NAME};
 125     unrequire_bin_mozilla();
 126
 127   } else {
 128     $script_name = $0;
 129   }
 130
 131   $::cgi         = CGI->new('');
 132   $::locale      = Locale->new($::language);
 133   $::form        = Form->new;
 134   %::called_subs = ();
 135
 136   eval { ($script_name, $action) = _route_request($script_name); 1; } or return;
 137
 138   my ($script, $path, $suffix) = fileparse($script_name, ".pl");
 139   require_main_code($script, $suffix);
 140
 141   $::form->{script} = $script . $suffix;
 142
 143   pre_request_checks();
 144
 145   eval {
 146     if ($script eq 'login' or $script eq 'admin' or $script eq 'kopf') {
 147       $::form->{titlebar} = "Lx-Office " . $::locale->text('Version') . " $::form->{version}";
 148       ::run($::auth->restore_session);
 149
 150     } elsif ($action) {
 151       # copy from am.pl routines
 152       $::form->error($::locale->text('System currently down for maintenance!')) if -e "$main::userspath/nologin" && $script ne 'admin';
 153
 154       my $session_result = $::auth->restore_session;
 155
 156       show_error('login/password_error', 'session') if SL::Auth::SESSION_EXPIRED == $session_result;
 157       %::myconfig = $::auth->read_user($::form->{login});
 158
 159       show_error('login/password_error', 'password') unless $::myconfig{login};
 160
 161       $::locale = Locale->new($::myconfig{countrycode});
 162
 163       show_error('login/password_error', 'password') if SL::Auth::OK != $::auth->authenticate($::form->{login}, $::form->{password}, 0);
 164
 165       $::auth->set_session_value('login', $::form->{login}, 'password', $::form->{password});
 166       $::auth->create_or_refresh_session;
 167       delete $::form->{password};
 168
 169       map { $::form->{$_} = $::myconfig{$_} } qw(stylesheet charset)
 170         unless $action eq 'save' && $::form->{type} eq 'preferences';
 171
 172       $::form->set_standard_title;
 173       ::call_sub('::' . $::locale->findsub($action));
 174
 175     } else {
 176       $::form->error($::locale->text('action= not defined!'));
 177     }
 178
 179     1;
 180   } or do {
 181     if ($EVAL_ERROR ne END_OF_REQUEST) {
 182       $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 183       eval { show_error('generic/error') };
 184     }
 185   };
 186
 187   # cleanup
 188   $::locale   = undef;
 189   $::form     = undef;
 190   $::myconfig = ();
 191   Form::disconnect_standard_dbh();
 192
 193   $::lxdebug->end_request;
 194   $::lxdebug->leave_sub;
 195 }
 196
 197 sub unrequire_bin_mozilla {
 198   for (keys %INC) {
 199     next unless m#^bin/mozilla/#;
 200     next if /\bcommon.pl$/;
 201     next if /\binstallationcheck.pl$/;
 202     delete $INC{$_};
 203   }
 204 }
 205
 206 sub _route_request {
 207   my $script_name = shift;
 208
 209   return $script_name =~ m/dispatcher\.pl$/ ? _route_dispatcher_request() : ($script_name, $::form->{action});
 210 }
 211
 212 sub _route_dispatcher_request {
 213   my $name_re = qr{[a-z]\w*};
 214   my ($script_name, $action);
 215
 216   eval {
 217     die "Unroutable request -- inavlid module name.\n" if !$::form->{M} || ($::form->{M} !~ m/^${name_re}$/);
 218     $script_name = $::form->{M} . '.pl';
 219
 220     if ($::form->{A}) {
 221       $action = $::form->{A};
 222
 223     } else {
 224       $action = first { m/^A_${name_re}$/ } keys %{ $::form };
 225       die "Unroutable request -- inavlid action name.\n" if !$action;
 226
 227       delete $::form->{$action};
 228       $action = substr $action, 2;
 229     }
 230
 231     delete @{$::form}{qw(M A)};
 232
 233     1;
 234   } or do {
 235     $::form->{label_error} = $::cgi->pre($EVAL_ERROR);
 236     show_error('generic/error');
 237   };
 238
 239   return ($script_name, $action);
 240 }
 241
 242 package main;
 243
 244 use strict;
 245
 246 sub end_of_request {
 247   die SL::Dispatcher->END_OF_REQUEST;
 248 }
 249
 250 1;