SL/DB/Part.pm

   1 package SL::DB::Part;
   2
   3 use strict;
   4
   5 use Carp;
   6 use List::MoreUtils qw(any);
   7 use Rose::DB::Object::Helpers qw(as_tree);
   8
   9 use SL::DBUtils;
  10 use SL::DB::MetaSetup::Part;
  11 use SL::DB::Manager::Part;
  12 use SL::DB::Chart;
  13 use SL::DB::Helper::AttrHTML;
  14 use SL::DB::Helper::TransNumberGenerator;
  15 use SL::DB::Helper::CustomVariables (
  16   module      => 'IC',
  17   cvars_alias => 1,
  18 );
  19
  20 __PACKAGE__->meta->add_relationships(
  21   assemblies                     => {
  22     type         => 'one to many',
  23     class        => 'SL::DB::Assembly',
  24     column_map   => { id => 'id' },
  25   },
  26   prices         => {
  27     type         => 'one to many',
  28     class        => 'SL::DB::Price',
  29     column_map   => { id => 'parts_id' },
  30   },
  31   makemodels     => {
  32     type         => 'one to many',
  33     class        => 'SL::DB::MakeModel',
  34     column_map   => { id => 'parts_id' },
  35   },
  36   translations   => {
  37     type         => 'one to many',
  38     class        => 'SL::DB::Translation',
  39     column_map   => { id => 'parts_id' },
  40   },
  41 );
  42
  43 __PACKAGE__->meta->initialize;
  44
  45 __PACKAGE__->attr_html('notes');
  46
  47 __PACKAGE__->before_save('_before_save_set_partnumber');
  48
  49 sub _before_save_set_partnumber {
  50   my ($self) = @_;
  51
  52   $self->create_trans_number if !$self->partnumber;
  53   return 1;
  54 }
  55
  56 sub is_type {
  57   my $self = shift;
  58   my $type  = lc(shift || '');
  59   die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  60
  61   return $self->type eq $type ? 1 : 0;
  62 }
  63
  64 sub is_part     { $_[0]->is_type('part') }
  65 sub is_assembly { $_[0]->is_type('assembly') }
  66 sub is_service  { $_[0]->is_type('service') }
  67
  68 sub type {
  69   my ($self, $type) = @_;
  70   if (@_ > 1) {
  71     die 'invalid type' unless $type =~ /^(?:part|service|assembly)$/;
  72     $self->assembly(          $type eq 'assembly' ? 1 : 0);
  73     $self->inventory_accno_id($type ne 'service'  ? 1 : undef);
  74   }
  75
  76   return 'assembly' if $self->assembly;
  77   return 'part'     if $self->inventory_accno_id;
  78   return 'service';
  79 }
  80
  81 sub new_part {
  82   my ($class, %params) = @_;
  83   $class->new(%params, type => 'part');
  84 }
  85
  86 sub new_assembly {
  87   my ($class, %params) = @_;
  88   $class->new(%params, type => 'assembly');
  89 }
  90
  91 sub new_service {
  92   my ($class, %params) = @_;
  93   $class->new(%params, type => 'service');
  94 }
  95
  96 sub orphaned {
  97   my ($self) = @_;
  98   die 'not an accessor' if @_ > 1;
  99
 100   my @relations = qw(
 101     SL::DB::InvoiceItem
 102     SL::DB::OrderItem
 103     SL::DB::Inventory
 104   );
 105
 106   for my $class (@relations) {
 107     eval "require $class";
 108     return 0 if $class->_get_manager_class->get_all_count(query => [ parts_id => $self->id ]);
 109   }
 110   return 1;
 111 }
 112
 113 sub get_sellprice_info {
 114   my $self   = shift;
 115   my %params = @_;
 116
 117   confess "Missing part id" unless $self->id;
 118
 119   my $object = $self->load;
 120
 121   return { sellprice       => $object->sellprice,
 122            price_factor_id => $object->price_factor_id };
 123 }
 124
 125 sub get_ordered_qty {
 126   my $self   = shift;
 127   my %result = SL::DB::Manager::Part->get_ordered_qty($self->id);
 128
 129   return $result{ $self->id };
 130 }
 131
 132 sub available_units {
 133   shift->unit_obj->convertible_units;
 134 }
 135
 136 # autogenerated accessor is slightly off...
 137 sub buchungsgruppe {
 138   shift->buchungsgruppen(@_);
 139 }
 140
 141 sub get_taxkey {
 142   my ($self, %params) = @_;
 143
 144   my $date     = $params{date} || DateTime->today_local;
 145   my $is_sales = !!$params{is_sales};
 146   my $taxzone  = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 147   my $tk_info  = $::request->cache('get_taxkey');
 148
 149   $tk_info->{$self->id}                                      //= {};
 150   $tk_info->{$self->id}->{$taxzone}                          //= { };
 151   my $cache = $tk_info->{$self->id}->{$taxzone}->{$is_sales} //= { };
 152
 153   if (!exists $cache->{$date}) {
 154     $cache->{$date} =
 155       $self->get_chart(type => $is_sales ? 'income' : 'expense', taxzone => $taxzone)
 156       ->get_active_taxkey($date);
 157   }
 158
 159   return $cache->{$date};
 160 }
 161
 162 sub get_chart {
 163   my ($self, %params) = @_;
 164
 165   my $type    = (any { $_ eq $params{type} } qw(income expense inventory)) ? $params{type} : croak("Invalid 'type' parameter '$params{type}'");
 166   my $taxzone = $params{ defined($params{taxzone}) ? 'taxzone' : 'taxzone_id' } * 1;
 167
 168   my $charts     = $::request->cache('get_chart_id/by_part_id_and_taxzone')->{$self->id} //= {};
 169   my $all_charts = $::request->cache('get_chart_id/by_id');
 170
 171   $charts->{$taxzone} ||= { };
 172
 173   if (!exists $charts->{$taxzone}->{$type}) {
 174     require SL::DB::Buchungsgruppe;
 175     my $bugru    = SL::DB::Buchungsgruppe->load_cached($self->buchungsgruppen_id);
 176     my $chart_id = ($type eq 'inventory') ? ($self->inventory_accno_id ? $bugru->inventory_accno_id : undef)
 177                  :                          $bugru->call_sub("${type}_accno_id", $taxzone);
 178
 179     if ($chart_id) {
 180       my $chart                    = $all_charts->{$chart_id} // SL::DB::Chart->load_cached($chart_id)->load;
 181       $all_charts->{$chart_id}     = $chart;
 182       $charts->{$taxzone}->{$type} = $chart;
 183     }
 184   }
 185
 186   return $charts->{$taxzone}->{$type};
 187 }
 188
 189 # this is designed to ignore chargenumbers, expiration dates and just give a list of how much <-> where
 190 sub get_simple_stock {
 191   my ($self, %params) = @_;
 192
 193   return [] unless $self->id;
 194
 195   my $query = <<'';
 196     SELECT sum(qty), warehouse_id, bin_id FROM inventory WHERE parts_id = ?
 197     GROUP BY warehouse_id, bin_id
 198
 199   my $stock_info = selectall_hashref_query($::form, $::form->get_standard_dbh, $query, $self->id);
 200   [ map { bless $_, 'SL::DB::Part::SimpleStock'} @$stock_info ];
 201 }
 202 # helper class to have bin/warehouse accessors in stock result
 203 { package SL::DB::Part::SimpleStock;
 204   sub warehouse { require SL::DB::Warehouse; SL::DB::Manager::Warehouse->find_by_or_create(id => $_[0]->{warehouse_id}) }
 205   sub bin       { require SL::DB::Bin;       SL::DB::Manager::Bin      ->find_by_or_create(id => $_[0]->{bin_id}) }
 206 }
 207
 208 sub displayable_name {
 209   join ' ', grep $_, map $_[0]->$_, qw(partnumber description);
 210 }
 211
 212 sub displayable_name { goto &long_description; }
 213
 214 1;
 215
 216 __END__
 217
 218 =pod
 219
 220 =encoding utf-8
 221
 222 =head1 NAME
 223
 224 SL::DB::Part: Model for the 'parts' table
 225
 226 =head1 SYNOPSIS
 227
 228 This is a standard Rose::DB::Object based model and can be used as one.
 229
 230 =head1 TYPES
 231
 232 Although the base class is called C<Part> we usually talk about C<Articles> if
 233 we mean instances of this class. This is because articles come in three
 234 flavours called:
 235
 236 =over 4
 237
 238 =item Part     - a single part
 239
 240 =item Service  - a part without onhand, and without inventory accounting
 241
 242 =item Assembly - a collection of both parts and services
 243
 244 =back
 245
 246 These types are sadly represented by data inside the class and cannot be
 247 migrated into a flag. To work around this, each C<Part> object knows what type
 248 it currently is. Since the type ist data driven, there ist no explicit setting
 249 method for it, but you can construct them explicitly with C<new_part>,
 250 C<new_service>, and C<new_assembly>. A Buchungsgruppe should be supplied in this
 251 case, but it will use the default Buchungsgruppe if you don't.
 252
 253 Matching these there are assorted helper methods dealing with types,
 254 e.g.  L</new_part>, L</new_service>, L</new_assembly>, L</type>,
 255 L</is_type> and others.
 256
 257 =head1 FUNCTIONS
 258
 259 =over 4
 260
 261 =item C<new_part %PARAMS>
 262
 263 =item C<new_service %PARAMS>
 264
 265 =item C<new_assembly %PARAMS>
 266
 267 Will set the appropriate data fields so that the resulting instance will be of
 268 tthe requested type. Since part of the distinction are accounting targets,
 269 providing a C<Buchungsgruppe> is recommended. If none is given the constructor
 270 will load a default one and set the accounting targets from it.
 271
 272 =item C<type>
 273
 274 Returns the type as a string. Can be one of C<part>, C<service>, C<assembly>.
 275
 276 =item C<is_type $TYPE>
 277
 278 Tests if the current object is a part, a service or an
 279 assembly. C<$type> must be one of the words 'part', 'service' or
 280 'assembly' (their plurals are ok, too).
 281
 282 Returns 1 if the requested type matches, 0 if it doesn't and
 283 C<confess>es if an unknown C<$type> parameter is encountered.
 284
 285 =item C<is_part>
 286
 287 =item C<is_service>
 288
 289 =item C<is_assembly>
 290
 291 Shorthand for C<is_type('part')> etc.
 292
 293 =item C<get_sellprice_info %params>
 294
 295 Retrieves the C<sellprice> and C<price_factor_id> for a part under
 296 different conditions and returns a hash reference with those two keys.
 297
 298 If C<%params> contains a key C<project_id> then a project price list
 299 will be consulted if one exists for that project. In this case the
 300 parameter C<country_id> is evaluated as well: if a price list entry
 301 has been created for this country then it will be used. Otherwise an
 302 entry without a country set will be used.
 303
 304 If none of the above conditions is met then the information from
 305 C<$self> is used.
 306
 307 =item C<get_ordered_qty %params>
 308
 309 Retrieves the quantity that has been ordered from a vendor but that
 310 has not been delivered yet. Only open purchase orders are considered.
 311
 312 =item C<get_taxkey %params>
 313
 314 Retrieves and returns a taxkey object valid for the given date
 315 C<$params{date}> and tax zone C<$params{taxzone}>
 316 (C<$params{taxzone_id}> is also recognized). The date defaults to the
 317 current date if undefined.
 318
 319 This function looks up the income (for trueish values of
 320 C<$params{is_sales}>) or expense (for falsish values of
 321 C<$params{is_sales}>) account for the current part. It uses the part's
 322 associated buchungsgruppe and uses the fields belonging to the tax
 323 zone given by C<$params{taxzone}>.
 324
 325 The information retrieved by the function is cached.
 326
 327 =item C<get_chart %params>
 328
 329 Retrieves and returns a chart object valid for the given type
 330 C<$params{type}> and tax zone C<$params{taxzone}>
 331 (C<$params{taxzone_id}> is also recognized). The type must be one of
 332 the three key words C<income>, C<expense> and C<inventory>.
 333
 334 This function uses the part's associated buchungsgruppe and uses the
 335 fields belonging to the tax zone given by C<$params{taxzone}>.
 336
 337 The information retrieved by the function is cached.
 338
 339 =item C<orphaned>
 340
 341 Checks if this articke is used in orders, invoices, delivery orders or
 342 assemblies.
 343
 344 =item C<buchungsgruppe BUCHUNGSGRUPPE>
 345
 346 Used to set the accounting informations from a L<SL:DB::Buchungsgruppe> object.
 347 Please note, that this is a write only accessor, the original Buchungsgruppe can
 348 not be retrieved from an article once set.
 349
 350 =back
 351
 352 =head1 AUTHORS
 353
 354 Moritz Bunkus E<lt>m.bunkus@linet-services.deE<gt>,
 355 Sven Schöling E<lt>s.schoeling@linet-services.deE<gt>
 356
 357 =cut