SL/Controller/CsvImport/CustomerVendor.pm

   1 package SL::Controller::CsvImport::CustomerVendor;
   2
   3 use strict;
   4
   5 use SL::Helper::Csv;
   6 use SL::Controller::CsvImport::Helper::Consistency;
   7 use SL::DB::Business;
   8 use SL::DB::CustomVariable;
   9 use SL::DB::CustomVariableConfig;
  10 use SL::DB::Employee;
  11 use SL::DB::PaymentTerm;
  12 use SL::TransNumber;
  13
  14 use parent qw(SL::Controller::CsvImport::Base);
  15
  16 use Rose::Object::MakeMethods::Generic
  17 (
  18  'scalar --get_set_init' => [ qw(table languages_by businesses_by salesmen_by) ],
  19 );
  20
  21 sub set_profile_defaults {
  22   my ($self) = @_;
  23   $self->controller->profile->_set_defaults(table => 'customer');
  24 };
  25
  26 sub init_table {
  27   my ($self) = @_;
  28   $self->table($self->controller->profile->get('table') eq 'customer' ? 'customer' : 'vendor');
  29 }
  30
  31 sub init_class {
  32   my ($self) = @_;
  33   $self->class('SL::DB::' . ucfirst($self->table));
  34 }
  35
  36 sub init_all_cvar_configs {
  37   my ($self) = @_;
  38
  39   return SL::DB::Manager::CustomVariableConfig->get_all(where => [ module => 'CT' ]);
  40 }
  41
  42 sub init_businesses_by {
  43   my ($self) = @_;
  44
  45   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ SL::DB::Manager::Business->get_all } } ) } qw(id description) };
  46 }
  47
  48 sub init_languages_by {
  49   my ($self) = @_;
  50
  51   return { map { my $col = $_; ( $col => { map { ( $_->$col => $_ ) } @{ $self->all_languages } } ) } qw(id description article_code) };
  52 }
  53
  54 sub init_salesmen_by {
  55   my ($self) = @_;
  56
  57   return { map { my $col = $_; ( $col => { map { ( lc($_->$col) => $_ ) } @{ SL::DB::Manager::Employee->get_all } } ) } qw(id name login) };
  58 }
  59
  60 sub check_objects {
  61   my ($self) = @_;
  62
  63   $self->controller->track_progress(phase => 'building data', progress => 0);
  64
  65   my $vc            = $self->controller->profile->get('table');
  66   my $update_policy = $self->controller->profile->get('update_policy') || 'update_existing';
  67   my $numbercolumn  = "${vc}number";
  68   my %vcs_by_number = map { ( $_->$numbercolumn => $_ ) } @{ $self->existing_objects };
  69   my $methods       = $self->controller->headers->{methods};
  70
  71   my $i = 0;
  72   my $num_data = scalar @{ $self->controller->data };
  73   foreach my $entry (@{ $self->controller->data }) {
  74     $self->controller->track_progress(progress => $i/$num_data * 100) if $i % 100 == 0;
  75     my $object = $entry->{object};
  76
  77     $self->check_name($entry);
  78     $self->check_language($entry);
  79     $self->check_business($entry);
  80     $self->check_payment($entry);
  81     $self->check_delivery_term($entry);
  82     $self->check_taxzone($entry,  take_default => 1);
  83     $self->check_currency($entry, take_default => 1);
  84     $self->check_salesman($entry);
  85
  86     next if @{ $entry->{errors} };
  87
  88     my @cleaned_fields = $self->clean_fields(qr{[\r\n]}, $object, qw(name department_1 department_2 street zipcode city country gln contact phone fax homepage email cc bcc
  89                                                                      taxnumber account_number bank_code bank username greeting taxzone));
  90
  91     push @{ $entry->{information} }, $::locale->text('Illegal characters have been removed from the following fields: #1', join(', ', @cleaned_fields))
  92       if @cleaned_fields;
  93
  94     my $existing_vc = $object->$numbercolumn ? $vcs_by_number{ $object->$numbercolumn } : undef;
  95     if (!$existing_vc) {
  96       $vcs_by_number{ $object->$numbercolumn } = $object if $object->$numbercolumn;
  97
  98     } elsif ($update_policy eq 'skip') {
  99       push(@{$entry->{errors}}, $::locale->text('Skipping due to existing entry in database'));
 100
 101     } elsif ($update_policy eq 'update_existing') {
 102       # Update existing customer/vendor records.
 103       $entry->{object_to_save} = $existing_vc;
 104
 105       $existing_vc->$_( $entry->{object}->$_ ) for @{ $methods }, keys %{ $self->clone_methods };
 106
 107       push @{ $entry->{information} }, $::locale->text('Updating existing entry in database');
 108
 109     } else {
 110       $object->$numbercolumn('####');
 111     }
 112
 113     $self->handle_cvars($entry);
 114
 115   } continue {
 116     $i++;
 117   }
 118
 119   $self->add_columns(map { "${_}_id" } grep { exists $self->controller->data->[0]->{raw_data}->{$_} } qw(language business payment delivery_term taxzone));
 120   $self->add_cvar_raw_data_columns;
 121 }
 122
 123 sub get_duplicate_check_fields {
 124   return {
 125     name => {
 126       label     => $::locale->text('Customer Name'),
 127       default   => 1,
 128       maker     => sub {
 129         my $name = shift->name;
 130         $name =~ s/[\s,\.\-]//g;
 131         return $name;
 132       }
 133     },
 134   };
 135 }
 136
 137 sub check_name {
 138   my ($self, $entry) = @_;
 139
 140   my $name =  $entry->{object}->name;
 141   $name    =~ s/^\s+//;
 142   $name    =~ s/\s+$//;
 143
 144   return 1 if $name;
 145
 146   push @{ $entry->{errors} }, $::locale->text('Error: Name missing');
 147   return 0;
 148 }
 149
 150 sub check_language {
 151   my ($self, $entry) = @_;
 152
 153   my $object = $entry->{object};
 154
 155   # Check whether or not language ID is valid.
 156   if ($object->language_id && !$self->languages_by->{id}->{ $object->language_id }) {
 157     push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 158     return 0;
 159   }
 160
 161   # Map name to ID if given.
 162   if (!$object->language_id && $entry->{raw_data}->{language}) {
 163     my $language = $self->languages_by->{description}->{  $entry->{raw_data}->{language} }
 164                 || $self->languages_by->{article_code}->{ $entry->{raw_data}->{language} };
 165
 166     if (!$language) {
 167       push @{ $entry->{errors} }, $::locale->text('Error: Invalid language');
 168       return 0;
 169     }
 170
 171     $object->language_id($language->id);
 172
 173     # register language_id for method copying later
 174     $self->clone_methods->{language_id} = 1;
 175   }
 176
 177   return 1;
 178 }
 179
 180 sub check_business {
 181   my ($self, $entry) = @_;
 182
 183   my $object = $entry->{object};
 184
 185   # Check whether or not business ID is valid.
 186   if ($object->business_id && !$self->businesses_by->{id}->{ $object->business_id }) {
 187     push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 188     return 0;
 189   }
 190
 191   # Map name to ID if given.
 192   if (!$object->business_id && $entry->{raw_data}->{business}) {
 193     my $business = $self->businesses_by->{description}->{ $entry->{raw_data}->{business} };
 194
 195     if (!$business) {
 196       push @{ $entry->{errors} }, $::locale->text('Error: Invalid business');
 197       return 0;
 198     }
 199
 200     $object->business_id($business->id);
 201
 202     # register business_id for method copying later
 203     $self->clone_methods->{business_id} = 1;
 204   }
 205
 206   return 1;
 207 }
 208
 209 sub check_salesman {
 210   my ($self, $entry) = @_;
 211
 212   my $object = $entry->{object};
 213
 214   # Check whether or not salesman ID is valid.
 215   if ($object->salesman_id && !$self->salesmen_by->{id}->{ $object->salesman_id }) {
 216     push @{ $entry->{errors} }, $::locale->text('Error: Invalid salesman');
 217     return 0;
 218   }
 219
 220   # Map name to ID if given.
 221   if (!$object->salesman_id && ($entry->{raw_data}->{salesman} || $entry->{raw_data}->{salesman_login})) {
 222     my $salesman = $self->salesmen_by->{name} ->{ lc($entry->{raw_data}->{salesman}) }
 223                 // $self->salesmen_by->{login}->{ lc($entry->{raw_data}->{salesman_login}) };
 224
 225     if (!$salesman) {
 226       push @{ $entry->{errors} }, $::locale->text('Error: Invalid salesman');
 227       return 0;
 228     }
 229
 230     $object->salesman_id($salesman->id);
 231
 232     # register salesman_id for method copying later
 233     $self->clone_methods->{salesman_id} = 1;
 234   }
 235
 236   return 1;
 237 }
 238
 239 sub save_objects {
 240   my ($self, %params) = @_;
 241
 242   my $numbercolumn   = $self->table . 'number';
 243   my $with_number    = [ grep { ($_->{object}->$numbercolumn || '') ne '####' } @{ $self->controller->data } ];
 244   my $without_number = [ grep { ($_->{object}->$numbercolumn || '') eq '####' } @{ $self->controller->data } ];
 245
 246   $_->{object}->$numbercolumn('') for @{ $without_number };
 247
 248   $self->SUPER::save_objects(data => $with_number);
 249   $self->SUPER::save_objects(data => $without_number);
 250 }
 251
 252 sub init_profile {
 253   my ($self) = @_;
 254
 255   my $profile = $self->SUPER::init_profile;
 256   delete @{$profile}{qw(business datevexport language payment delivery_term taxincluded terms)};
 257   delete @{$profile}{qw(salesman salesman_id salesman_login)} if $::instance_conf->get_vertreter;
 258
 259   return $profile;
 260 }
 261
 262 sub setup_displayable_columns {
 263   my ($self) = @_;
 264
 265   $self->SUPER::setup_displayable_columns;
 266   $self->add_cvar_columns_to_displayable_columns;
 267
 268   $self->add_displayable_columns({ name => 'account_number',    description => $::locale->text('Account Number')                  },
 269                                  { name => 'bank',              description => $::locale->text('Bank')                            },
 270                                  { name => 'bank_code',         description => $::locale->text('Bank Code')                       },
 271                                  { name => 'bcc',               description => $::locale->text('Bcc')                             },
 272                                  { name => 'bic',               description => $::locale->text('BIC')                             },
 273                                  { name => 'business_id',       description => $::locale->text('Business type (database ID)')     },
 274                                  { name => 'business',          description => $::locale->text('Business type (name)')            },
 275                                  { name => 'c_vendor_id',       description => $::locale->text('our vendor number at customer')   },
 276                                  { name => 'cc',                description => $::locale->text('Cc')                              },
 277                                  { name => 'city',              description => $::locale->text('City')                            },
 278                                  { name => 'contact',           description => $::locale->text('Contact')                         },
 279                                  { name => 'country',           description => $::locale->text('Country')                         },
 280                                  { name => 'creditlimit',       description => $::locale->text('Credit Limit')                    },
 281                                  { name => 'currency',          description => $::locale->text('Currency')                        },
 282                                  { name => 'currency_id',       description => $::locale->text('Currency (database ID)')          },
 283                                  { name => 'customernumber',    description => $::locale->text('Customer Number')                 },
 284                                  { name => 'department_1',      description => $::locale->text('Department 1')                    },
 285                                  { name => 'department_2',      description => $::locale->text('Department 2')                    },
 286                                  { name => 'delivery_term_id',  description => $::locale->text('Delivery terms (database ID)')    },
 287                                  { name => 'delivery_term',     description => $::locale->text('Delivery terms (name)')           },
 288                                  { name => 'direct_debit',      description => $::locale->text('direct debit')                    },
 289                                  { name => 'discount',          description => $::locale->text('Discount')                        },
 290                                  { name => 'email',             description => $::locale->text('E-mail')                          },
 291                                  { name => 'fax',               description => $::locale->text('Fax')                             },
 292                                  { name => 'gln',               description => $::locale->text('GLN')                             },
 293                                  { name => 'greeting',          description => $::locale->text('Greeting')                        },
 294                                  { name => 'homepage',          description => $::locale->text('Homepage')                        },
 295                                  { name => 'iban',              description => $::locale->text('IBAN')                            },
 296                                  { name => 'pricegroup_id',     description => $::locale->text('Price group (database ID)')       },
 297                                  { name => 'language_id',       description => $::locale->text('Language (database ID)')          },
 298                                  { name => 'language',          description => $::locale->text('Language (name)')                 },
 299                                  { name => 'name',              description => $::locale->text('Name')                            },
 300                                  { name => 'notes',             description => $::locale->text('Notes')                           },
 301                                  { name => 'obsolete',          description => $::locale->text('Obsolete')                        },
 302                                  { name => 'payment_id',        description => $::locale->text('Payment terms (database ID)')     },
 303                                  { name => 'payment',           description => $::locale->text('Payment terms (name)')            },
 304                                  { name => 'phone',             description => $::locale->text('Phone')                           },
 305                                  { name => 'street',            description => $::locale->text('Street')                          },
 306                                  { name => 'taxnumber',         description => $::locale->text('Tax Number / SSN')                },
 307                                  { name => 'taxzone',           description => $::locale->text('Tax zone (description)')          },
 308                                  { name => 'taxzone_id',        description => $::locale->text('Tax zone (database ID)')          },
 309                                  { name => 'user_password',     description => $::locale->text('Password')                        },
 310                                  { name => 'username',          description => $::locale->text('Username')                        },
 311                                  { name => 'ustid',             description => $::locale->text('sales tax identification number') },
 312                                  { name => 'zipcode',           description => $::locale->text('Zipcode')                         },
 313                                 );
 314
 315   if (!$::instance_conf->get_vertreter) {
 316     $self->add_displayable_columns({ name => 'salesman',       description => $::locale->text('Salesman') },
 317                                    { name => 'salesman_id',    description => $::locale->text('Salesman (database ID)') },
 318                                    { name => 'salesman_login', description => $::locale->text('Salesman (login)') });
 319   }
 320 }
 321
 322 # TODO:
 323 # salesman_id -- Kunden mit Typ 'Verkäufer', falls Vertreter-Modus an ist, ansonsten Employees
 324
 325 1;