SL/Controller/CustomDataExport.pm

   1 package SL::Controller::CustomDataExport;
   2
   3 use strict;
   4 use utf8;
   5
   6 use parent qw(SL::Controller::Base);
   7
   8 use DBI qw(:sql_types);
   9 use File::Temp ();
  10 use List::UtilsBy qw(sort_by);
  11 use POSIX qw(strftime);
  12 use Text::CSV_XS;
  13
  14 use SL::DB::CustomDataExportQuery;
  15 use SL::Locale::String qw(t8);
  16
  17 use Rose::Object::MakeMethods::Generic
  18 (
  19   scalar                  => [ qw(rows) ],
  20   'scalar --get_set_init' => [ qw(query queries parameters) ],
  21 );
  22
  23 __PACKAGE__->run_before('check_auth');
  24 __PACKAGE__->run_before('setup_javascripts');
  25
  26 #
  27 # actions
  28 #
  29
  30 sub action_list {
  31   my ($self) = @_;
  32
  33   $self->render('custom_data_export/list', title => $::locale->text('Execute a custom data export query'));
  34 }
  35
  36 sub action_export {
  37   my ($self) = @_;
  38
  39   if (!$::form->{format}) {
  40     $self->setup_export_action_bar;
  41     return $self->render('custom_data_export/export', title => t8("Execute custom data export '#1'", $self->query->name));
  42   }
  43
  44   $self->execute_query;
  45
  46   if (scalar(@{ $self->rows // [] }) == 1) {
  47     $self->setup_empty_result_set_action_bar;
  48     return $self->render('custom_data_export/empty_result_set', title => t8("Execute custom data export '#1'", $self->query->name));
  49   }
  50
  51
  52   my $method = "export_as_" . $::form->{format};
  53   $self->$method;
  54 }
  55
  56 #
  57 # filters
  58 #
  59
  60 sub check_auth {
  61   my ($self) = @_;
  62   $::auth->assert($self->query->access_right) if $self->query->access_right;
  63 }
  64
  65 sub setup_javascripts {
  66   $::request->layout->add_javascripts('kivi.Validator.js');
  67 }
  68
  69 #
  70 # helpers
  71 #
  72
  73 sub init_query      { $::form->{id} ? SL::DB::CustomDataExportQuery->new(id => $::form->{id})->load : SL::DB::CustomDataExportQuery->new }
  74 sub init_parameters { [ sort_by { lc $_->name } @{ $_[0]->query->parameters // [] } ] }
  75
  76 sub init_queries {
  77   my %rights_map     = %{ $::auth->load_rights_for_user($::form->{login}) };
  78   my @granted_rights = grep { $rights_map{$_} } keys %rights_map;
  79
  80   return scalar SL::DB::Manager::CustomDataExportQuery->get_all_sorted(
  81     where => [
  82       or => [
  83         access_right => undef,
  84         access_right => '',
  85         (access_right => \@granted_rights) x !!@granted_rights,
  86       ],
  87     ],
  88   )
  89 }
  90
  91 sub setup_export_action_bar {
  92   my ($self) = @_;
  93
  94   for my $bar ($::request->layout->get('actionbar')) {
  95     $bar->add(
  96       action => [
  97         t8('Export'),
  98         submit    => [ '#form', { action => 'CustomDataExport/export' } ],
  99         checks    => [ 'kivi.validate_form' ],
 100         accesskey => 'enter',
 101       ],
 102       action => [
 103         t8('Back'),
 104         call => [ 'kivi.history_back' ],
 105       ],
 106     );
 107   }
 108 }
 109
 110 sub setup_empty_result_set_action_bar {
 111   my ($self) = @_;
 112
 113   for my $bar ($::request->layout->get('actionbar')) {
 114     $bar->add(
 115       action => [
 116         t8('Back'),
 117         call => [ 'kivi.history_back' ],
 118       ],
 119     );
 120   }
 121 }
 122
 123 sub prepare_query {
 124   my ($self) = @_;
 125
 126   my $sql_query = $self->query->sql_query;
 127   my @values;
 128
 129   my %values_by_name;
 130
 131   foreach my $parameter (@{ $self->query->parameters // [] }) {
 132     my $value                           = ($::form->{parameters} // {})->{ $parameter->name };
 133     $values_by_name{ $parameter->name } = $parameter->parameter_type eq 'number' ? $::form->parse_amount(\%::myconfig, $value) : $value;
 134   }
 135
 136   while ($sql_query =~ m{<\%(.+?)\%>}) {
 137     push @values, $values_by_name{$1};
 138     substr($sql_query, $-[0], $+[0] - $-[0], '?');
 139   }
 140
 141   return ($sql_query, @values);
 142 }
 143
 144 sub execute_query {
 145   my ($self) = @_;
 146
 147   my ($sql_query, @values) = $self->prepare_query;
 148   my $sth                  = $self->query->db->dbh->prepare($sql_query) || $::form->dberror;
 149   $sth->execute(@values)                                                || $::form->dberror;
 150
 151   my @names = @{ $sth->{NAME} };
 152   my @types = @{ $sth->{TYPE} };
 153   my @data  = @{ $sth->fetchall_arrayref };
 154
 155   $sth->finish;
 156
 157   foreach my $row (@data) {
 158     foreach my $col (0..$#types) {
 159       my $type = $types[$col];
 160
 161       if ($type == SQL_NUMERIC) {
 162         $row->[$col] = $::form->format_amount(\%::myconfig, $row->[$col]);
 163       }
 164     }
 165   }
 166
 167   $self->rows([
 168     \@names,
 169     @data,
 170   ]);
 171 }
 172
 173 sub export_as_csv {
 174   my ($self) = @_;
 175
 176   my $csv = Text::CSV_XS->new({
 177     binary   => 1,
 178     sep_char => ';',
 179     eol      => "\n",
 180   });
 181
 182   my ($file_handle, $file_name) = File::Temp::tempfile;
 183
 184   binmode $file_handle, ":encoding(utf8)";
 185
 186   $csv->print($file_handle, $_) for @{ $self->rows };
 187
 188   $file_handle->close;
 189
 190   my $report_name =  $self->query->name;
 191   $report_name    =~ s{[^[:word:]]+}{_}ig;
 192   $report_name   .=  strftime('_%Y-%m-%d_%H-%M-%S.csv', localtime());
 193
 194   $self->send_file(
 195     $file_name,
 196     content_type => 'text/csv',
 197     name         => $report_name,
 198   );
 199 }
 200
 201 1;