SL/Controller/RecordLinks.pm

   1 package SL::Controller::RecordLinks;
   2
   3 use strict;
   4
   5 use parent qw(SL::Controller::Base);
   6
   7 use List::Util qw(first);
   8
   9 use SL::DB::Helper::Mappings;
  10 use SL::DB::Order;
  11 use SL::DB::DeliveryOrder;
  12 use SL::DB::Invoice;
  13 use SL::DB::Letter;
  14 use SL::DB::PurchaseInvoice;
  15 use SL::DB::RecordLink;
  16 use SL::DB::RequirementSpec;
  17 use SL::DBUtils qw(like);
  18 use SL::DB::ShopOrder;
  19 use SL::JSON;
  20 use SL::Locale::String;
  21 use SL::Presenter::Record qw(grouped_record_list);
  22
  23 use Rose::Object::MakeMethods::Generic
  24 (
  25   scalar => [ qw(object object_model object_id link_type link_direction link_type_desc) ],
  26 );
  27
  28 __PACKAGE__->run_before('check_auth');
  29 __PACKAGE__->run_before('check_object_params', only => [ qw(ajax_list ajax_delete ajax_add_select_type ajax_add_filter ajax_add_list ajax_add_do) ]);
  30 __PACKAGE__->run_before('check_link_params',   only => [ qw(                                                           ajax_add_list ajax_add_do) ]);
  31
  32 my %link_type_defaults = (
  33   filter            => 'type_filter',
  34   project           => 'globalproject',
  35   description       => 'transaction_description',
  36   description_title => t8('Transaction description'),
  37   date              => 'transdate',
  38 );
  39
  40 my @link_type_specifics = (
  41   { title => t8('Requirement spec'),        type => 'requirement_spec',        model => 'RequirementSpec', number => 'id', project => 'project', description => 'title', date => undef, filter => 'working_copy_filter', },
  42   { title => t8('Shop Order'),              type => 'shop_order',              model => 'ShopOrder',       number => 'shop_ordernumber', date => 'order_date', project => undef, },
  43   { title => t8('Sales quotation'),         type => 'sales_quotation',         model => 'Order',           number => 'quonumber', },
  44   { title => t8('Sales Order'),             type => 'sales_order',             model => 'Order',           number => 'ordnumber', },
  45   { title => t8('Sales delivery order'),    type => 'sales_delivery_order',    model => 'DeliveryOrder',   number => 'donumber',  },
  46   { title => t8('RMA delivery order'),      type => 'rma_delivery_order',      model => 'DeliveryOrder',   number => 'rdonumber', },
  47   { title => t8('Sales Invoice'),           type => 'invoice',                 model => 'Invoice',         number => 'invnumber', },
  48   { title => t8('Request for Quotation'),   type => 'request_quotation',       model => 'Order',           number => 'quonumber', },
  49   { title => t8('Purchase Order'),          type => 'purchase_order',          model => 'Order',           number => 'ordnumber', },
  50   { title => t8('Purchase delivery order'), type => 'purchase_delivery_order', model => 'DeliveryOrder',   number => 'donumber',  },
  51   { title => t8('Supplier delivery order'), type => 'supplier_delivery_order', model => 'DeliveryOrder',   number => 'sdonumber', },
  52   { title => t8('Purchase Invoice'),        type => 'purchase_invoice',        model => 'PurchaseInvoice', number => 'invnumber', },
  53   { title => t8('Letter'),                  type => 'letter',                  model => 'Letter',          number => 'letternumber', description => 'subject', description_title => t8('Subject'), date => 'date', project => undef },
  54   { title => t8('Email'),                   type => 'email_journal',           model => 'EmailJournal',    number => 'id', description => 'subject', description_title => t8('Subject'), },
  55   { title => t8('AR Transaction'),          type => 'ar_transaction',          model => 'Invoice',         number => 'invnumber', },
  56   { title => t8('AP Transaction'),          type => 'ap_transaction',          model => 'PurchaseInvoice', number => 'invnumber', },
  57   { title => t8('Dunning'),                 type => 'dunning',                 model => 'Dunning',         number => 'dunning_id', },
  58   { title => t8('GL Transaction'),          type => 'gl_transaction',          model => 'GLTransaction',   number => 'reference', },
  59 );
  60
  61 my @link_types = map { +{ %link_type_defaults, %{ $_ } } } @link_type_specifics;
  62
  63 #
  64 # actions
  65 #
  66
  67 sub action_ajax_list {
  68   my ($self) = @_;
  69
  70   eval {
  71     my $linked_records = ($::instance_conf->get_always_record_links_from_order && ref $self->object ne 'SL::DB::Order')
  72                        ?  $self->get_order_centric_linked_records
  73                        :  $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1);
  74
  75     push @{ $linked_records }, $self->object->sepa_export_items if $self->object->can('sepa_export_items');
  76
  77     my $output         = grouped_record_list(
  78       $linked_records,
  79       with_columns      => [ qw(record_link_direction) ],
  80       edit_record_links => 1,
  81       object_model      => $self->object_model,
  82       object_id         => $self->object_id,
  83     );
  84     $self->render(\$output, { layout => 0, process => 0 });
  85
  86     1;
  87   } or do {
  88     $self->render('generic/error', { layout => 0 }, label_error => $@);
  89   };
  90 }
  91
  92 sub action_ajax_delete {
  93   my ($self) = @_;
  94
  95   foreach my $str (@{ $::form->{record_links_delete} || [] }) {
  96     my ($from_table, $from_id, $to_table, $to_id) = split m/__/, $str, 4;
  97     $from_id *= 1;
  98     $to_id   *= 1;
  99
 100     next if !$from_table || !$from_id || !$to_table || !$to_id;
 101
 102     SL::DB::Manager::RecordLink->delete_all(where => [
 103       from_table => $from_table,
 104       from_id    => $from_id,
 105       to_table   => $to_table,
 106       to_id      => $to_id,
 107     ]);
 108   }
 109
 110   $self->action_ajax_list;
 111 }
 112
 113 sub action_ajax_add_filter {
 114   my ($self) = @_;
 115
 116   my $presenter = $self->presenter;
 117
 118   my @link_type_select = map { [ $_->{type}, $_->{title} ] } @link_types;
 119   my @projects         = map { [ $_->id, $_->presenter->project(display => 'inline', style => 'both', no_link => 1) ] } @{ SL::DB::Manager::Project->get_all_sorted };
 120   my $is_sales         = $self->object->can('customer_id') && $self->object->customer_id;
 121
 122   $self->render(
 123     'record_links/add_filter',
 124     { layout          => 0 },
 125     is_sales          => $is_sales,
 126     DEFAULT_LINK_TYPE => $is_sales ? 'sales_quotation' : 'request_quotation',
 127     LINK_TYPES        => \@link_type_select,
 128     PROJECTS          => \@projects,
 129   );
 130 }
 131
 132 sub action_ajax_add_list {
 133   my ($self) = @_;
 134
 135   my $manager     = 'SL::DB::Manager::' . $self->link_type_desc->{model};
 136   my $vc          = $self->link_type =~ m/shop|sales_|^invoice|requirement_spec|letter|^ar_/ ? 'customer' : 'vendor';
 137   my $project     = $self->link_type_desc->{project};
 138   my $project_id  = "${project}_id";
 139   my $description = $self->link_type_desc->{description};
 140   my $filter      = $self->link_type_desc->{filter};
 141   my $number      = $self->link_type_desc->{number};
 142
 143   my @where = $filter && $manager->can($filter) ? $manager->$filter($self->link_type) : ();
 144   push @where, ("${vc}.${vc}number"     => { ilike => like($::form->{vc_number}) })               if $::form->{vc_number};
 145   push @where, ("${vc}.name"            => { ilike => like($::form->{vc_name}) })                 if $::form->{vc_name};
 146   push @where, ($description            => { ilike => like($::form->{transaction_description}) }) if $::form->{transaction_description};
 147   push @where, ($project_id             => $::form->{globalproject_id})                           if $::form->{globalproject_id} && $manager->can($project_id);
 148
 149   if ($::form->{number}) {
 150     my $class    = 'SL::DB::' . $self->link_type_desc->{model};
 151     my $col_type = ref $class->meta->column($number);
 152     if ($col_type =~ /^Rose::DB::Object::Metadata::Column::(?:Integer|Serial)$/) {
 153       push @where, ($number => $::form->{number});
 154     } elsif ($col_type =~ /^Rose::DB::Object::Metadata::Column::Text$/) {
 155       push @where, ($number => { ilike => like($::form->{number}) });
 156     }
 157   }
 158
 159   my @with_objects = ($vc);
 160   push @with_objects, $project if $manager->can($project_id);
 161
 162   # show the newest records first (should be better for 80% of the cases TODO sortable click
 163   my $objects = $manager->get_all_sorted(where => \@where, with_objects => \@with_objects, sort_by => 'itime',  sort_dir => 'ASC');
 164   my $output  = $self->render(
 165     'record_links/add_list',
 166     { output => 0 },
 167     OBJECTS            => $objects,
 168     vc                 => $vc,
 169     number_column      => $self->link_type_desc->{number},
 170     description_column => $description,
 171     description_title  => $self->link_type_desc->{description_title},
 172     project_column     => $project,
 173     date_column        => $self->link_type_desc->{date},
 174   );
 175
 176   my %result = ( count => scalar(@{ $objects }), html => $output );
 177
 178   $self->render(\to_json(\%result), { type => 'json', process => 0 });
 179 }
 180
 181 sub action_ajax_add_do {
 182   my ($self, %params) = @_;
 183
 184   my $object_side = $self->link_direction eq 'from' ? 'from' : 'to';
 185   my $link_side   = $object_side          eq 'from' ? 'to'   : 'from';
 186   my $link_table  = SL::DB::Helper::Mappings::get_table_for_package($self->link_type_desc->{model});
 187
 188   foreach my $link_id (@{ $::form->{link_id} || [] }) {
 189     # Check for existing reverse connections in order to avoid loops.
 190     my @props = (
 191       "${link_side}_table"   => $self->object->meta->table,
 192       "${link_side}_id"      => $self->object_id,
 193       "${object_side}_table" => $link_table,
 194       "${object_side}_id"    => $link_id,
 195     );
 196
 197     my $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 198     next if $existing;
 199
 200     # Check for existing connections in order to avoid duplicates.
 201     @props = (
 202       "${object_side}_table" => $self->object->meta->table,
 203       "${object_side}_id"    => $self->object_id,
 204       "${link_side}_table"   => $link_table,
 205       "${link_side}_id"      => $link_id,
 206     );
 207
 208     $existing = SL::DB::Manager::RecordLink->get_all(where => \@props, limit => 1)->[0];
 209
 210     SL::DB::RecordLink->new(@props)->save if !$existing;
 211   }
 212
 213   $self->action_ajax_list;
 214 }
 215
 216
 217 #
 218 # filters
 219 #
 220
 221 sub check_object_params {
 222   my ($self) = @_;
 223
 224   my %models = map { ($_->{model} => 1 ) } @link_types;
 225
 226   $self->object_id(   $::form->{object_id});
 227   $self->object_model($::form->{object_model});
 228
 229   die "Invalid object_model or object_id" if !$self->object_id || !$models{$self->object_model};
 230
 231   my $model = 'SL::DB::' . $self->object_model;
 232   $self->object($model->new(id => $self->object_id)->load || die "Record not found");
 233
 234   return 1;
 235 }
 236
 237 sub check_link_params {
 238   my ($self) = @_;
 239
 240   $self->link_type(     $::form->{link_type});
 241   $self->link_type_desc((first { $_->{type} eq $::form->{link_type} } @link_types)                || die "Invalid link_type");
 242   $self->link_direction($::form->{link_direction} =~ m/^(?:from|to)$/ ? $::form->{link_direction} :  die "Invalid link_direction");
 243
 244   return 1;
 245 }
 246
 247 sub check_auth {
 248   $::auth->assert('record_links');
 249 }
 250
 251 # internal
 252
 253 sub get_order_centric_linked_records {
 254   my ($self) = @_;
 255
 256   my $all_linked_records = $self->object->linked_records(direction => 'from', recursive => 1);
 257   my $filtered_orders = [ grep { 'SL::DB::Order' eq ref $_ && $_->is_type('sales_order') } @$all_linked_records ];
 258
 259   # no orders no call to linked_records via batch mode
 260   # but instead return default list
 261   return $self->object->linked_records(direction => 'both', recursive => 1, save_path => 1)
 262     unless scalar @$filtered_orders;
 263
 264   # we have a order, therefore get the tree view from the top (order)
 265   my $id_ref = [ map { $_->id } @$filtered_orders ];
 266   my $linked_records = SL::DB::Order->new->linked_records(direction => 'to', recursive => 1, batch => $id_ref);
 267   push @{ $linked_records }, @$filtered_orders;
 268
 269   return $linked_records;
 270 }
 271 1;